mod_rm_driver.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module mod_rm_driver
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ included parameters
  !
#include "scale-rm.h"
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: rm_driver

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  character(len=H_MID), private, parameter :: modelname = "SCALE-RM ver. "//version

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine rm_driver( &
       comm_world,       &
       intercomm_parent, &
       intercomm_child,  &
       cnf_fname         )
    use scale_file, only: &
       file_close_all
    use scale_prc, only: &
       prc_abort,      &
       prc_local_setup
    use scale_fpm, only: &
       fpm_alive,       &
       fpm_polling,     &
       fpm_polling_freq
    use scale_prc_cartesc, only: &
       prc_cartesc_setup
    use scale_const, only: &
       const_setup
    use scale_calendar, only: &
       calendar_setup
    use scale_random, only: &
       random_setup
    use scale_atmos_hydrometeor, only: &
       atmos_hydrometeor_setup
    use scale_atmos_grid_cartesc_index, only: &
       atmos_grid_cartesc_index_setup
    use scale_atmos_grid_cartesc, only: &
       atmos_grid_cartesc_setup, &
       dx, &
       dy
    use scale_atmos_grid_cartesc_real, only: &
       atmos_grid_cartesc_real_setup
    use scale_atmos_grid_cartesc_metric, only: &
       atmos_grid_cartesc_metric_setup
    use scale_ocean_grid_cartesc_index, only: &
       ocean_grid_cartesc_index_setup
    use scale_ocean_grid_cartesc, only: &
       ocean_grid_cartesc_setup
    use scale_ocean_grid_cartesc_real, only: &
       ocean_grid_cartesc_real_setup
    use scale_land_grid_cartesc_index, only: &
       land_grid_cartesc_index_setup
    use scale_land_grid_cartesc, only: &
       land_grid_cartesc_setup
    use scale_land_grid_cartesc_real, only: &
       land_grid_cartesc_real_setup
    use scale_urban_grid_cartesc_index, only: &
       urban_grid_cartesc_index_setup
    use scale_urban_grid_cartesc, only: &
       urban_grid_cartesc_setup
    use scale_urban_grid_cartesc_real, only: &
       urban_grid_cartesc_real_setup
    use scale_file_cartesc, only: &
       file_cartesc_setup, &
       file_cartesc_cleanup
    use scale_comm_cartesc, only: &
       comm_setup , &
       comm_cleanup
    use scale_comm_cartesc_nest, only: &
       comm_cartesc_nest_setup
    use scale_topography, only: &
       topo_setup
    use scale_landuse, only: &
       landuse_setup
    use scale_statistics, only: &
       statistics_setup
    use scale_time, only: &
       time_nowdate, &
       time_nowms,   &
       time_nowstep, &
       time_dtsec
    use scale_atmos_hydrostatic, only: &
       atmos_hydrostatic_setup
    use scale_atmos_thermodyn, only: &
       atmos_thermodyn_setup
    use scale_atmos_saturation, only: &
       atmos_saturation_setup
    use scale_bulkflux, only: &
       bulkflux_setup
    use scale_file_external_input_cartesc, only: &
       file_external_input_cartesc_setup
    use scale_file_history, only: &
       file_history_write, &
       file_history_set_nowdate, &
       file_history_finalize
    use scale_file_history_cartesc, only: &
       file_history_cartesc_setup
    use scale_monitor_cartesc, only: &
       monitor_cartesc_setup
    use scale_monitor, only: &
       monitor_write, &
       monitor_finalize

    use mod_atmos_driver, only: &
       atmos_driver_tracer_setup
    use mod_admin_versioncheck, only: &
       admin_versioncheck
    use mod_admin_time, only: &
       admin_time_setup,      &
       admin_time_checkstate, &
       admin_time_advance,    &
       time_doatmos_step,     &
       time_doland_step,      &
       time_dourban_step,     &
       time_doocean_step,     &
       time_doresume,         &
       time_doend
    use mod_admin_restart, only: &
       admin_restart_setup, &
       admin_restart_write
    use mod_atmos_admin, only: &
       atmos_admin_setup, &
       atmos_do,          &
       atmos_phy_mp_type
    use mod_atmos_vars, only: &
       atmos_vars_setup,       &
       atmos_restart_check,    &
       atmos_vars_restart_check
    use mod_atmos_driver, only: &
       atmos_driver_setup,                    &
       atmos_driver_calc_tendency,            &
       atmos_driver_calc_tendency_from_sflux, &
       atmos_driver_update,                   &
       atmos_driver_finalize
    use mod_atmos_phy_mp_vars, only: &
       qa_mp
    use mod_ocean_admin, only: &
       ocean_admin_setup, &
       ocean_do
    use mod_ocean_vars, only: &
       ocean_vars_setup
    use mod_ocean_driver, only: &
       ocean_driver_setup,         &
       ocean_driver_calc_tendency, &
       ocean_driver_update
    use mod_land_admin, only: &
       land_admin_setup, &
       land_do
    use mod_land_vars, only: &
       land_vars_setup
    use mod_land_driver, only: &
       land_driver_setup,         &
       land_driver_calc_tendency, &
       land_driver_update
    use mod_urban_admin, only: &
       urban_admin_setup, &
       urban_do,          &
       urban_land
    use mod_urban_vars, only: &
       urban_vars_setup
    use mod_urban_driver, only: &
       urban_driver_setup,         &
       urban_driver_calc_tendency, &
       urban_driver_update
    use mod_lake_admin, only: &
       lake_admin_setup, &
       lake_do
    use mod_cpl_admin, only: &
       cpl_admin_setup, &
       cpl_sw
    use mod_cpl_vars, only: &
       cpl_vars_setup
    use mod_user, only: &
       user_tracer_setup,  &
       user_setup,         &
       user_calc_tendency, &
       user_update
    implicit none

    integer,          intent(in) :: comm_world
    integer,          intent(in) :: intercomm_parent
    integer,          intent(in) :: intercomm_child
    character(len=*), intent(in) :: cnf_fname

    integer :: myrank
    integer :: fpm_counter
    logical :: ismaster
    logical :: sign_exit
    !---------------------------------------------------------------------------

    !########## Initial setup ##########

    ! setup standard I/O
    call io_setup( modelname, cnf_fname )

    ! setup MPI
    call prc_local_setup( comm_world, & ! [IN]
                          myrank,     & ! [OUT]
                          ismaster    ) ! [OUT]

    ! setup Log
    call io_log_setup( myrank, ismaster )

    ! namelist compatibility check
    call admin_versioncheck

    ! setup process
    call prc_cartesc_setup

    ! setup PROF
    call prof_setup

    !###########################################################################
    ! profiler start
    call prof_setprefx('INIT')
    call prof_rapstart('Initialize', 0)

    ! setup constants
    call const_setup

    ! setup calendar
    call calendar_setup

    ! setup random number
    call random_setup

    ! setup submodel administrator
    call atmos_admin_setup
    call ocean_admin_setup
    call land_admin_setup
    call urban_admin_setup
    call lake_admin_setup
    call cpl_admin_setup

    ! setup horizontal/vertical grid coordinates (cartesian,idealized)
    if ( atmos_do ) then
       call atmos_grid_cartesc_index_setup
       call atmos_grid_cartesc_setup
    endif

    if ( ocean_do ) then
       call ocean_grid_cartesc_index_setup
       call ocean_grid_cartesc_setup
    endif

    if ( land_do ) then
       call land_grid_cartesc_index_setup
       call land_grid_cartesc_setup
    endif

    if ( urban_do ) then
       call urban_grid_cartesc_index_setup
       call urban_grid_cartesc_setup
    endif

    ! setup tracer index
    call atmos_hydrometeor_setup
    call atmos_driver_tracer_setup
    call user_tracer_setup

    ! setup file I/O
    call file_cartesc_setup

    ! setup mpi communication
    call comm_setup

    ! setup topography
    call topo_setup
    ! setup land use category index/fraction
    call landuse_setup( ocean_do, (.not. urban_land), lake_do )

    ! setup grid coordinates (real world)
    if ( atmos_do ) then
       call atmos_grid_cartesc_real_setup
       ! setup grid transfer metrics (uses in ATMOS_dynamics)
       call atmos_grid_cartesc_metric_setup
    endif
    if ( ocean_do ) call ocean_grid_cartesc_real_setup
    if ( land_do  ) call land_grid_cartesc_real_setup
    if ( urban_do ) call urban_grid_cartesc_real_setup

    ! setup restart
    call admin_restart_setup
    ! setup time
    call admin_time_setup( setup_timeintegration = .true. )
    ! setup statistics
    call statistics_setup
    ! setup history I/O
    call file_history_cartesc_setup
    ! setup monitor I/O
    call monitor_cartesc_setup( time_dtsec, atmos_do, ocean_do, land_do, urban_do )
    ! setup external in
    call file_external_input_cartesc_setup

    ! setup nesting grid
    call comm_cartesc_nest_setup ( qa_mp, atmos_phy_mp_type, intercomm_parent, intercomm_child )

    ! setup common tools
    call atmos_hydrostatic_setup
    call atmos_thermodyn_setup
    call atmos_saturation_setup

    call bulkflux_setup( sqrt(dx**2+dy**2) )

    ! setup variable container
    if ( atmos_do ) call atmos_vars_setup
    if ( ocean_do ) call ocean_vars_setup
    if ( land_do  ) call land_vars_setup
    if ( urban_do ) call urban_vars_setup
    if ( cpl_sw   ) call cpl_vars_setup

    ! setup driver
    if ( atmos_do ) call atmos_driver_setup
    if ( ocean_do ) call ocean_driver_setup
    if ( land_do  ) call land_driver_setup
    if ( urban_do ) call urban_driver_setup

    call user_setup

    call prof_rapend('Initialize', 0)

    !########## main ##########

#ifdef FIPP
    call fipp_start
#endif
#ifdef PAPI
    call prof_papi_rapstart
#endif

    log_newline
    log_progress(*) 'START TIMESTEP'
    call prof_setprefx('MAIN')
    call prof_rapstart('Main_Loop', 0)

    fpm_counter = 0
    do
      ! report current time
      call admin_time_checkstate

      if ( time_doresume ) then
         ! set state from restart files
         call restart_read

         ! history&monitor file output
         call monitor_write('MAIN', time_nowstep)
         call file_history_write ! if needed
      endif

      ! time advance
      call admin_time_advance
      call file_history_set_nowdate( time_nowdate, time_nowms, time_nowstep )

      ! change to next state
      if( ocean_do .AND. time_doocean_step ) call ocean_driver_update
      if( land_do  .AND. time_doland_step  ) call land_driver_update
      if( urban_do .AND. time_dourban_step ) call urban_driver_update
      if( atmos_do .AND. time_doatmos_step ) call atmos_driver_update
                                             call user_update
      ! restart output
      call admin_restart_write

      ! calc tendencies and diagnostices
      if( atmos_do .AND. time_doatmos_step ) call atmos_driver_calc_tendency( force = .false. )
      if( ocean_do .AND. time_doocean_step ) call ocean_driver_calc_tendency( force = .false. )
      if( land_do  .AND. time_doland_step  ) call land_driver_calc_tendency( force = .false. )
      if( urban_do .AND. time_dourban_step ) call urban_driver_calc_tendency( force = .false. )
      if( cpl_sw   .AND. time_doatmos_step ) call atmos_driver_calc_tendency_from_sflux( force = .false. )
                                             call user_calc_tendency

      ! history&monitor file output
      call monitor_write('MAIN', time_nowstep)
      call file_history_write

      if( time_doend ) exit

      if( io_l ) call flush(io_fid_log)

      ! FPM polling
      if ( fpm_alive .AND. fpm_polling_freq > 0 ) then
         if ( fpm_counter > fpm_polling_freq ) then
            sign_exit = .false.
            call fpm_polling( .true., sign_exit )
            if ( sign_exit ) then
               log_error("scalerm",*) 'receive stop signal'
               call prc_abort
            endif
            fpm_counter = 0
         endif

         fpm_counter = fpm_counter + 1
      endif

    enddo

    call prof_rapend('Main_Loop', 0)

    log_progress(*) 'END TIMESTEP'
    log_newline

#ifdef FIPP
    call fipp_stop
#endif
#ifdef PAPI
    call prof_papi_rapstop
#endif

    !########## Finalize ##########

    call prof_setprefx('FIN')

    call prof_rapstart('All', 1)

    if( atmos_do ) call atmos_driver_finalize

    ! check data
    if( atmos_restart_check ) call atmos_vars_restart_check

    call prof_rapstart('Monit', 2)
    call monitor_finalize
    call prof_rapend  ('Monit', 2)

    call prof_rapstart('File', 2)
    call file_history_finalize
    ! clean up resource allocated for I/O
    call file_cartesc_cleanup

    call comm_cleanup

    call file_close_all
    call prof_rapend  ('File', 2)

    call prof_rapend  ('All', 1)

    call prof_rapreport
#ifdef PAPI
    call prof_papi_rapreport
#endif

    return
  end subroutine rm_driver

  !-----------------------------------------------------------------------------
  subroutine restart_read
    use scale_atmos_grid_cartesc_index
    use scale_atmos_grid_cartesc, only: &
       cz   => atmos_grid_cartesc_cz,  &
       fz   => atmos_grid_cartesc_fz,  &
       fdz  => atmos_grid_cartesc_fdz, &
       rcdz => atmos_grid_cartesc_rcdz
    use scale_atmos_grid_cartesc_real, only: &
       real_cz  => atmos_grid_cartesc_real_cz,  &
       real_fz  => atmos_grid_cartesc_real_fz,  &
       real_phi => atmos_grid_cartesc_real_phi, &
       area     => atmos_grid_cartesc_real_area
    use scale_time, only: &
       time_nowdaysec
    use mod_admin_restart, only: &
       admin_restart_read
    use mod_atmos_admin, only: &
       atmos_do
    use mod_atmos_driver, only: &
       atmos_driver_calc_tendency, &
       atmos_driver_calc_tendency_from_sflux, &
       atmos_surface_set
    use mod_atmos_vars, only: &
       atmos_vars_calc_diagnostics, &
       atmos_vars_history_setpres,  &
       atmos_vars_history,          &
       atmos_vars_monitor,          &
       dens,                        &
       pott,                        &
       temp,                        &
       pres,                        &
       qv
    use mod_atmos_bnd_driver, only: &
       atmos_boundary_driver_set
    use scale_atmos_refstate, only: &
       atmos_refstate_update
    use mod_ocean_admin, only: &
       ocean_do
    use mod_ocean_driver, only: &
       ocean_driver_calc_tendency, &
       ocean_surface_set
    use mod_ocean_vars, only: &
       ocean_vars_history
    use mod_land_admin, only: &
       land_do
    use mod_land_driver, only: &
       land_driver_calc_tendency, &
       land_surface_set
    use mod_land_vars, only: &
       land_vars_history
    use mod_urban_admin, only: &
       urban_do
    use mod_urban_driver, only: &
       urban_driver_calc_tendency, &
       urban_surface_set
    use mod_urban_vars, only: &
       urban_vars_history
    use mod_cpl_admin, only: &
       cpl_sw
    use mod_user, only: &
       user_calc_tendency
    implicit none
    !---------------------------------------------------------------------------

    ! read restart data
    call admin_restart_read

    if ( atmos_do ) then
       ! calc diagnostics
       call atmos_vars_calc_diagnostics
       call atmos_refstate_update( ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                                   dens(:,:,:), pott(:,:,:), temp(:,:,:), pres(:,:,:), qv(:,:,:), & ! [IN]
                                   cz(:), fz(:), fdz(:), rcdz(:),                                 & ! [IN]
                                   real_cz(:,:,:), real_fz(:,:,:), real_phi(:,:,:), area(:,:),    & ! [IN]
                                   time_nowdaysec,                                                & ! [IN]
                                   force = .true.                                                 )
       call atmos_boundary_driver_set
       call atmos_vars_history_setpres
    endif

    ! setup surface condition
    if( atmos_do ) call atmos_surface_set( countup=.false. )
    if( ocean_do ) call ocean_surface_set( countup=.false. )
    if( land_do  ) call land_surface_set ( countup=.false. )
    if( urban_do ) call urban_surface_set( countup=.false. )

    ! calc tendencies
    if( atmos_do ) call atmos_driver_calc_tendency           ( force=.true. )
    if( ocean_do ) call ocean_driver_calc_tendency           ( force=.true. )
    if( land_do  ) call land_driver_calc_tendency            ( force=.true. )
    if( urban_do ) call urban_driver_calc_tendency           ( force=.true. )
    if( cpl_sw   ) call atmos_driver_calc_tendency_from_sflux( force=.true. )
                   call user_calc_tendency

    !########## History & Monitor ##########
    if( atmos_do ) call atmos_vars_history
    if( ocean_do ) call ocean_vars_history
    if( land_do  ) call land_vars_history
    if( urban_do ) call urban_vars_history

    call atmos_vars_monitor

    return
  end subroutine restart_read

end module mod_rm_driver