module Surface bulk flux More...

Functions/Subroutines
subroutine, public	bulkflux_setup (dx)

real(dp) function	fmm_unstable (Z, IL)

Variables
procedure(bc), pointer, public	bulkflux => NULL()

Detailed Description

module Surface bulk flux

Description: calculation of surface bulk flux

Author: Team SCALE

NAMELIST

PARAM_BULKFLUX

name	type	default value	comment
BULKFLUX_TYPE	character(len=H_SHORT)	'B91W01' ! 'U95', 'B94', and 'B91W01'
BULKFLUX_USE_MEAN	logical	.true.
BULKFLUX_ITR_SA_MAX	integer	5	maximum iteration number for successive approximation
BULKFLUX_ITR_NR_MAX	integer	10	maximum iteration number for Newton-Raphson method
BULKFLUX_ERR_MIN	real(RP)	1.0E-3_RP	minimum value of error
BULKFLUX_WSCF	real(RP)		empirical scaling factor of Wstar (Beljaars 1994)
BULKFLUX_UABS_MIN	real(RP)	1.0E-2_RP	minimum of Uabs [m/s]
BULKFLUX_WSTAR_MIN	real(RP)	1.0E-4_RP	minimum of W* [m/s]

History Output: No history output

Function/Subroutine Documentation

◆ bulkflux_setup()

subroutine, public scale_bulkflux::bulkflux_setup ( real(rp), intent(in) dx )

Definition at line 125 of file scale_bulkflux.F90.

References bulkflux, scale_const::const_cpdry, scale_const::const_eps, scale_const::const_epstvap, scale_const::const_grav, scale_const::const_karman, scale_const::const_pi, scale_const::const_pre00, scale_const::const_rdry, fmm_unstable(), scale_io::io_fid_conf, and scale_prc::prc_abort().

Referenced by mod_rm_driver::rm_driver().

     use scale_prc, only: &
        prc_abort
     implicit none
     real(RP), intent(in) :: dx
 
     namelist / param_bulkflux / &
        bulkflux_type,       &
        bulkflux_use_mean,   &
        bulkflux_itr_sa_max, &
        bulkflux_itr_nr_max, &
        bulkflux_err_min,    &
        bulkflux_wscf,       &
        bulkflux_uabs_min,   &
        bulkflux_wstar_min
 
     integer :: ierr
     !---------------------------------------------------------------------------
 
     log_newline
     log_info("BULKFLUX_setup",*) 'Setup'
 
     ! WSCF = 1.2 for dx > 1 km (Beljaars 1994)
     ! lim_{dx->0} WSCF = 0  for LES (Fig. 6 Kitamura and Ito 2016 BLM)
     bulkflux_wscf = 1.2_rp * min(dx*1.e-3_rp, 1.0_rp)
 
 
     !--- read namelist
     rewind(io_fid_conf)
     read(io_fid_conf,nml=param_bulkflux,iostat=ierr)
 
     if( ierr < 0 ) then !--- missing
        log_info("BULKFLUX_setup",*) 'Not found namelist. Default used.'
     elseif( ierr > 0 ) then !--- fatal error
        log_error("BULKFLUX_setup",*) 'Not appropriate names in namelist PARAM_BULKFLUX. Check!'
        call prc_abort
     endif
     log_nml(param_bulkflux)
 
     log_newline
     log_info("BULKFLUX_setup",*) 'Scheme for surface bulk flux : ', trim(bulkflux_type)
     select case(bulkflux_type)
     case('U95')
        log_info_cont(*) '=> Uno et al.(1995)'
        bulkflux => bulkflux_u95
     case('B91W01')
        log_info_cont(*) '=> Beljaars (1991) and Wilson (2001)'
        flag_w01 = .true.
        bulkflux => bulkflux_b91w01
     case('B94')
        log_info_cont(*) '=> Beljaars (1994)'
        flag_w01 = .false.
        bulkflux => bulkflux_b91w01
     case default
        log_error("BULKFLUX_setup",*) 'Unsupported BULKFLUX_type. STOP'
        call prc_abort
     end select
 
     return

Here is the call graph for this function:

Here is the caller graph for this function:

◆ fmm_unstable()

real(dp) function scale_bulkflux::fmm_unstable	(	real(dp), intent(in)	Z,
		real(dp), intent(in)	IL
	)

Definition at line 931 of file scale_bulkflux.F90.

References scale_const::const_eps, and scale_const::const_pi.

Referenced by bulkflux_setup().

     use scale_const, only: &
       pi  => const_pi, &
       eps => const_eps
     implicit none
 
     ! argument
     real(DP), intent(in) :: z
     real(DP), intent(in) :: il
 
     ! function
     real(DP) :: fmm_unstable
 
     ! Wilson (2001)
     real(DP), parameter :: gamma = 3.6_dp
 
     ! works
     real(DP) :: r
     real(DP) :: f, r3
     real(DP) :: r4r, r2r
     !---------------------------------------------------------------------------
 
     r = min( z * il, 0.0_dp )
 
     if ( flag_w01 ) then
        ! Wilson (2001)
        r3 = (-r)**(1.0_dp/3.0_dp)
        if ( r > -eps ) then
           fmm_unstable = 9.0_dp / 20.0_dp * gamma * r3**2
        else
           f = sqrt( 1.0_dp + gamma * r3**2 )
           fmm_unstable = 3.0_dp * log( ( 1.0_dp + f ) * 0.5_dp ) &
                        + 1.5_dp / ( sqrt(gamma)**3 * r) * asinh( sqrt(gamma) * r3 ) &
                        + 1.5_dp * f / ( gamma * r3**2 ) &
                        - 1.0_dp
        end if
     else
        ! Beljaars and Holtslag (1994), originally Paulson (1974) and Dyer (1974)
        if ( r > -eps ) then ! |R|<EPS, now R < 0
           fmm_unstable = - 2.0_dp * r
        else
           r2r = sqrt( 1.0_dp - 16.0_dp * r )
           r4r = sqrt( r2r )
           fmm_unstable = log( ( 1.0_dp + r4r )**2 * ( 1.0_dp + r2r ) * 0.125_dp ) &
                         - 2.0_dp * atan( r4r ) &
                         + ( 1.0_dp - r4r*r2r ) / ( 12.0_dp * r ) &
                         + pi * 0.5_dp - 1.0_dp
        end if
     end if
 
     return