mod_atmos_phy_mp_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module mod_atmos_phy_mp_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_atmos_grid_cartesc_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_mp_vars_setup
  public :: atmos_phy_mp_vars_fillhalo
  public :: atmos_phy_mp_vars_restart_read
  public :: atmos_phy_mp_vars_restart_write

  public :: atmos_phy_mp_vars_restart_create
  public :: atmos_phy_mp_vars_restart_open
  public :: atmos_phy_mp_vars_restart_def_var
  public :: atmos_phy_mp_vars_restart_enddef
  public :: atmos_phy_mp_vars_restart_close

  public :: atmos_phy_mp_vars_history

  public :: atmos_phy_mp_vars_get_diagnostic
  public :: atmos_phy_mp_vars_reset_diagnostics

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,                public :: atmos_phy_mp_restart_output                = .false.                

  character(len=H_LONG),  public :: atmos_phy_mp_restart_in_basename           = ''
  logical,                public :: atmos_phy_mp_restart_in_aggregate
  logical,                public :: atmos_phy_mp_restart_in_postfix_timelabel  = .false.                
  character(len=H_LONG),  public :: atmos_phy_mp_restart_out_basename          = ''
  logical,                public :: atmos_phy_mp_restart_out_aggregate
  logical,                public :: atmos_phy_mp_restart_out_postfix_timelabel = .true.                 
  character(len=H_MID),   public :: atmos_phy_mp_restart_out_title             = 'ATMOS_PHY_MP restart'
  character(len=H_SHORT), public :: atmos_phy_mp_restart_out_dtype             = 'DEFAULT'

  real(RP), public :: atmos_phy_mp_cldfrac_thleshold

  real(RP), public, allocatable :: atmos_phy_mp_dens_t(:,:,:)    ! tendency DENS [kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_mp_momz_t(:,:,:)    ! tendency MOMZ [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_mp_rhou_t(:,:,:)    ! tendency dens*U [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_mp_rhov_t(:,:,:)    ! tendency dens*V [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_mp_rhot_t(:,:,:)    ! tendency RHOT [K*kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_mp_rhoq_t(:,:,:,:)  ! tendency rho*QTRC [kg/kg/s]
  real(RP), public, allocatable :: atmos_phy_mp_rhoh  (:,:,:)    ! diabatic heating rate [J/kg/s]

  real(RP), public, allocatable :: atmos_phy_mp_evaporate(:,:,:) ! number concentration of evaporated cloud [/m3]
  real(RP), public, allocatable :: atmos_phy_mp_sflx_rain(:,:)   ! precipitation flux (liquid) [kg/m2/s]
  real(RP), public, allocatable :: atmos_phy_mp_sflx_snow(:,:)   ! precipitation flux (solid)  [kg/m2/s]

  integer, public :: qa_mp = 0
  integer, public :: qs_mp = -1
  integer, public :: qe_mp = -2

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,                private, parameter :: vmax = 2
  integer,                private, parameter :: i_sflx_rain = 1
  integer,                private, parameter :: i_sflx_snow = 2

  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)
  integer,                private            :: var_id(vmax)
  integer,                private            :: restart_fid = -1  ! file ID

  data var_name / 'SFLX_rain', &
                  'SFLX_snow'  /
  data var_desc / 'precipitation flux (liquid)', &
                  'precipitation flux (solid)'   /
  data var_unit / 'kg/m2/s', &
                  'kg/m2/s' /


  ! for diagnostics
  real(RP), private, allocatable :: atmos_phy_mp_cldfrac(:,:,:)
  real(RP), private, allocatable :: atmos_phy_mp_re     (:,:,:,:)
  real(RP), private, allocatable :: atmos_phy_mp_qe     (:,:,:,:)
  real(RP), private, allocatable :: atmos_phy_mp_ne     (:,:,:,:)
  logical, private :: diag_cldfrac
  logical, private :: diag_re
  logical, private :: diag_qe
  logical, private :: diag_ne

  ! for history
  integer, private              :: hist_cldfrac_id
  logical, private              :: hist_re
  logical, private              :: hist_qe
  logical, private              :: hist_ne
  integer, private, allocatable :: hist_re_id(:)
  integer, private, allocatable :: hist_qe_id(:)
  integer, private, allocatable :: hist_ne_id(:)

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_setup
    use scale_prc, only: &
       prc_abort
    use scale_const, only: &
       undef => const_undef
    use scale_atmos_hydrometeor, only: &
       n_hyd,    &
       qha,      &
       hyd_name, &
       num_name, &
       hyd_desc
    use scale_file_history, only: &
       file_history_reg
    implicit none

    namelist / param_atmos_phy_mp_vars / &
       atmos_phy_mp_restart_in_basename,           &
       atmos_phy_mp_restart_in_aggregate,          &
       atmos_phy_mp_restart_in_postfix_timelabel,  &
       atmos_phy_mp_restart_output,                &
       atmos_phy_mp_restart_out_basename,          &
       atmos_phy_mp_restart_out_aggregate,         &
       atmos_phy_mp_restart_out_postfix_timelabel, &
       atmos_phy_mp_restart_out_title,             &
       atmos_phy_mp_restart_out_dtype

    integer :: ierr
    integer :: iv, ih
    !---------------------------------------------------------------------------

    log_newline
    log_info("ATMOS_PHY_MP_vars_setup",*) 'Setup'

    allocate( atmos_phy_mp_dens_t(ka,ia,ja)    )
    allocate( atmos_phy_mp_momz_t(ka,ia,ja)    )
    allocate( atmos_phy_mp_rhou_t(ka,ia,ja)    )
    allocate( atmos_phy_mp_rhov_t(ka,ia,ja)    )
    allocate( atmos_phy_mp_rhot_t(ka,ia,ja)    )
    allocate( atmos_phy_mp_rhoq_t(ka,ia,ja,qs_mp:qe_mp) )
    allocate( atmos_phy_mp_rhoh(ka,ia,ja)    )
    allocate( atmos_phy_mp_evaporate(ka,ia,ja)    )
    ! tentative approach
    atmos_phy_mp_dens_t(:,:,:)   = 0.0_rp
    atmos_phy_mp_momz_t(:,:,:)   = 0.0_rp
    atmos_phy_mp_rhou_t(:,:,:)   = 0.0_rp
    atmos_phy_mp_rhov_t(:,:,:)   = 0.0_rp
    atmos_phy_mp_rhot_t(:,:,:)   = 0.0_rp
    atmos_phy_mp_rhoq_t(:,:,:,:) = 0.0_rp
    atmos_phy_mp_rhoh(:,:,:)   = 0.0_rp
    atmos_phy_mp_evaporate(:,:,:)   = 0.0_rp

    allocate( atmos_phy_mp_sflx_rain(ia,ja) )
    allocate( atmos_phy_mp_sflx_snow(ia,ja) )
    atmos_phy_mp_sflx_rain(:,:) = undef
    atmos_phy_mp_sflx_snow(:,:) = undef

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_mp_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("ATMOS_PHY_MP_vars_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("ATMOS_PHY_MP_vars_setup",*) 'Not appropriate names in namelist PARAM_ATMOS_PHY_MP_VARS. Check!'
       call prc_abort
    endif
    log_nml(param_atmos_phy_mp_vars)

    log_newline
    log_info("ATMOS_PHY_MP_vars_setup",*) '[ATMOS_PHY_MP] prognostic/diagnostic variables'
    log_info_cont('(1x,A,A24,A,A48,A,A12,A)') &
               '      |', 'VARNAME                 ','|', &
               'DESCRIPTION                                     ', '[', 'UNIT        ', ']'
    do iv = 1, vmax
       log_info_cont('(1x,A,I3,A,A24,A,A48,A,A12,A)') &
                  'NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
    enddo

    log_newline
    if ( atmos_phy_mp_restart_in_basename /= '' ) then
       log_info("ATMOS_PHY_MP_vars_setup",*) 'Restart input?  : YES, file = ', trim(atmos_phy_mp_restart_in_basename)
       log_info("ATMOS_PHY_MP_vars_setup",*) 'Add timelabel?  : ', atmos_phy_mp_restart_in_postfix_timelabel
    else
       log_info("ATMOS_PHY_MP_vars_setup",*) 'Restart input?  : NO'
    endif
    if (       atmos_phy_mp_restart_output             &
         .AND. atmos_phy_mp_restart_out_basename /= '' ) then
       log_info("ATMOS_PHY_MP_vars_setup",*) 'Restart output? : YES, file = ', trim(atmos_phy_mp_restart_out_basename)
       log_info("ATMOS_PHY_MP_vars_setup",*) 'Add timelabel?  : ', atmos_phy_mp_restart_out_postfix_timelabel
    else
       log_info("ATMOS_PHY_MP_vars_setup",*) 'Restart output? : NO'
       atmos_phy_mp_restart_output = .false.
    endif


    ! diagnostices
    allocate( atmos_phy_mp_cldfrac(ka,ia,ja) )
    allocate( atmos_phy_mp_re(ka,ia,ja,n_hyd) )
    allocate( atmos_phy_mp_qe(ka,ia,ja,n_hyd) )
    allocate( atmos_phy_mp_ne(ka,ia,ja,n_hyd) )
!OCL XFILL
    atmos_phy_mp_cldfrac(:,:,:) = undef
!OCL XFILL
    atmos_phy_mp_re(:,:,:,:) = undef
!OCL XFILL
    atmos_phy_mp_qe(:,:,:,:) = undef
    atmos_phy_mp_ne(:,:,:,:) = undef
    diag_cldfrac = .false.
    diag_re      = .false.
    diag_qe      = .false.
    diag_ne      = .false.

    ! history
    allocate( hist_re_id(n_hyd) )
    allocate( hist_qe_id(n_hyd) )
    allocate( hist_ne_id(n_hyd) )

    call file_history_reg( 'CLDFRAC', 'cloud fraction', '1', hist_cldfrac_id, fill_halo=.true., dim_type='ZXY' )

    hist_re = .false.
    do ih = 1, n_hyd
       call file_history_reg( 'Re_'//trim(hyd_name(ih)), 'effective radius of '//trim(hyd_desc(ih)), 'cm', hist_re_id(ih), fill_halo=.true., dim_type='ZXY' )
       if( hist_re_id(ih) > 0 ) hist_re = .true.
    enddo

    hist_qe = .false.
    do ih = 1, n_hyd
       call file_history_reg( trim(hyd_name(ih))//'_hyd', 'mass ratio of '//trim(hyd_desc(ih)), 'kg/kg', hist_qe_id(ih), fill_halo=.true., dim_type='ZXY' )
       if( hist_qe_id(ih) > 0 ) hist_qe = .true.
    enddo

    hist_ne = .false.
    do ih = 1, n_hyd
       call file_history_reg( trim(num_name(ih))//'_hyd', 'number concentration of '//trim(hyd_desc(ih)), '1/m3', hist_ne_id(ih), fill_halo=.true., dim_type='ZXY' )
       if( hist_ne_id(ih) > 0 ) hist_ne = .true.
    enddo

    return
  end subroutine atmos_phy_mp_vars_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_fillhalo
    use scale_comm_cartesc, only: &
       comm_vars8, &
       comm_wait
    implicit none
    !---------------------------------------------------------------------------

    call comm_vars8( atmos_phy_mp_sflx_rain(:,:), 1 )
    call comm_vars8( atmos_phy_mp_sflx_snow(:,:), 2 )
    call comm_wait ( atmos_phy_mp_sflx_rain(:,:), 1 )
    call comm_wait ( atmos_phy_mp_sflx_snow(:,:), 2 )

    return
  end subroutine atmos_phy_mp_vars_fillhalo

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_open
    use scale_time, only: &
       time_gettimelabel
    use scale_file_cartesc, only: &
       file_cartesc_open
    implicit none

    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    log_newline
    log_info("ATMOS_PHY_MP_vars_restart_open",*) 'Open restart file (ATMOS_PHY_MP) '

    if ( atmos_phy_mp_restart_in_basename /= '' ) then

       if ( atmos_phy_mp_restart_in_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_mp_restart_in_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_mp_restart_in_basename)
       endif

       log_info("ATMOS_PHY_MP_vars_restart_open",*) 'basename: ', trim(basename)

       call file_cartesc_open( basename, restart_fid, aggregate=atmos_phy_mp_restart_in_aggregate )
    else
       log_info("ATMOS_PHY_MP_vars_restart_open",*) 'restart file for ATMOS_PHY_MP is not specified.'
    endif

    return
  end subroutine atmos_phy_mp_vars_restart_open

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_read
    use scale_statistics, only: &
       statistics_checktotal, &
       statistics_total
    use scale_atmos_grid_cartesc_real, only: &
       atmos_grid_cartesc_real_area, &
       atmos_grid_cartesc_real_totarea
    use scale_file, only: &
       file_get_aggregate
    use scale_file_cartesc, only: &
       file_cartesc_read, &
       file_cartesc_flush
    implicit none

    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       log_newline
       log_info("ATMOS_PHY_MP_vars_restart_read",*) 'Read from restart file (ATMOS_PHY_MP) '

       call file_cartesc_read( restart_fid, var_name(1), 'XY', & ! [IN]
                               atmos_phy_mp_sflx_rain(:,:)     ) ! [OUT]

       call file_cartesc_read( restart_fid, var_name(2), 'XY', & ! [IN]
                               atmos_phy_mp_sflx_snow(:,:)     ) ! [OUT]

       if ( file_get_aggregate(restart_fid) ) then
          call file_cartesc_flush( restart_fid ) ! X/Y halos have been read from file
       else
          call atmos_phy_mp_vars_fillhalo
       end if

       if ( statistics_checktotal ) then
          call statistics_total( ia, is, ie, ja, js, je, &
                                 atmos_phy_mp_sflx_rain(:,:), var_name(1), & ! (in)
                                 atmos_grid_cartesc_real_area(:,:),        & ! (in)
                                 atmos_grid_cartesc_real_totarea           ) ! (in)
          call statistics_total( ia, is, ie, ja, js, je, &
                                 atmos_phy_mp_sflx_snow(:,:), var_name(2), & ! (in)
                                 atmos_grid_cartesc_real_area(:,:),        & ! (in)
                                 atmos_grid_cartesc_real_totarea           ) ! (in)
       endif
    else
       log_info("ATMOS_PHY_MP_vars_restart_read",*) 'invalid restart file ID for ATMOS_PHY_MP.'
    endif

    return
  end subroutine atmos_phy_mp_vars_restart_read

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_create
    use scale_time, only: &
       time_gettimelabel
    use scale_file_cartesc, only: &
       file_cartesc_create
    implicit none

    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    if ( atmos_phy_mp_restart_out_basename /= '' ) then

       log_newline
       log_info("ATMOS_PHY_MP_vars_restart_create",*) 'Create restart file (ATMOS_PHY_AE) '

       if ( atmos_phy_mp_restart_out_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_mp_restart_out_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_mp_restart_out_basename)
       endif

       log_info("ATMOS_PHY_MP_vars_restart_create",*) 'basename: ', trim(basename)

       call file_cartesc_create( &
            basename, atmos_phy_mp_restart_out_title, atmos_phy_mp_restart_out_dtype, & ! [IN]
            restart_fid,                                                              & ! [OUT]
            aggregate=atmos_phy_mp_restart_out_aggregate                              ) ! [IN]

    endif

    return
  end subroutine atmos_phy_mp_vars_restart_create

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_enddef
    use scale_file_cartesc, only: &
       file_cartesc_enddef
    implicit none

    if ( restart_fid /= -1 ) then
       call file_cartesc_enddef( restart_fid ) ! [IN]
    endif

    return
  end subroutine atmos_phy_mp_vars_restart_enddef

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_close
    use scale_file_cartesc, only: &
       file_cartesc_close
    implicit none
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       log_newline
       log_info("ATMOS_PHY_MP_vars_restart_close",*) 'Close restart file (ATMOS_PHY_MP) '

       call file_cartesc_close( restart_fid ) ! [IN]

       restart_fid = -1
    endif

    return
  end subroutine atmos_phy_mp_vars_restart_close

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_def_var
    use scale_file_cartesc, only: &
       file_cartesc_def_var
    implicit none
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then

       call file_cartesc_def_var( restart_fid, var_name(1), var_desc(1), var_unit(1), 'XY', atmos_phy_mp_restart_out_dtype, &
                                  var_id(1) )
       call file_cartesc_def_var( restart_fid, var_name(2), var_desc(2), var_unit(2), 'XY', atmos_phy_mp_restart_out_dtype, &
                                  var_id(2) )
    endif

    return
  end subroutine atmos_phy_mp_vars_restart_def_var

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_write
    use scale_statistics, only: &
       statistics_checktotal, &
       statistics_total
    use scale_atmos_grid_cartesc_real, only: &
       atmos_grid_cartesc_real_area, &
       atmos_grid_cartesc_real_totarea
    use scale_file_cartesc, only: &
       file_cartesc_write_var
    implicit none
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then

       call atmos_phy_mp_vars_fillhalo

       if ( statistics_checktotal ) then
          call statistics_total( ia, is, ie, ja, js, je, &
                                 atmos_phy_mp_sflx_rain(:,:), var_name(1), & ! (in)
                                 atmos_grid_cartesc_real_area(:,:),        & ! (in)
                                 atmos_grid_cartesc_real_totarea           ) ! (in)
          call statistics_total( ia, is, ie, ja, js, je, &
                                 atmos_phy_mp_sflx_snow(:,:), var_name(2), & ! (in)
                                 atmos_grid_cartesc_real_area(:,:),        & ! (in)
                                 atmos_grid_cartesc_real_totarea           ) ! (in)
       endif

       call file_cartesc_write_var( restart_fid, var_id(1), atmos_phy_mp_sflx_rain(:,:), &
                              var_name(1), 'XY' ) ! [IN]
       call file_cartesc_write_var( restart_fid, var_id(2), atmos_phy_mp_sflx_snow(:,:), &
                              var_name(2), 'XY' ) ! [IN]

    endif

    return
  end subroutine atmos_phy_mp_vars_restart_write

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_history( &
       DENS, TEMP, QTRC )
    use scale_atmos_hydrometeor, only: &
       n_hyd
    use scale_file_history, only: &
       file_history_query, &
       file_history_put
    use mod_atmos_admin, only: &
       atmos_phy_mp_type
    implicit none

    real(RP), intent(in) :: DENS(ka,ia,ja)
    real(RP), intent(in) :: TEMP(ka,ia,ja)
    real(RP), intent(in) :: QTRC(ka,ia,ja,qa)

    real(RP) :: WORK  (ka,ia,ja,n_hyd)
    logical  :: do_put
    integer  :: ih
    !---------------------------------------------------------------------------

    if ( hist_cldfrac_id > 0 ) then
       call file_history_query( hist_cldfrac_id, do_put )

       if ( do_put ) then
          call atmos_phy_mp_vars_get_diagnostic( &
               dens(:,:,:), temp(:,:,:), qtrc(:,:,:,:), & ! [IN]
               cldfrac=work(:,:,:,1)                    ) ! [OUT]
          call file_history_put( hist_cldfrac_id, work(:,:,:,1) )
       end if
    end if

    if ( hist_re ) then
       do ih = 1, n_hyd
          if ( hist_re_id(ih) > 0 ) then
             call file_history_query( hist_re_id(ih), do_put )
             if ( do_put ) then
                call atmos_phy_mp_vars_get_diagnostic( &
                     dens(:,:,:), temp(:,:,:), qtrc(:,:,:,:), & ! [IN]
                     re=work(:,:,:,:)                         ) ! [OUT]
                exit
             end if
          end if
       end do
       if ( do_put ) then
          do ih = 1, n_hyd
             if ( hist_re_id(ih) > 0 ) then
                call file_history_query( hist_re_id(ih), do_put )
                if ( do_put ) call file_history_put( hist_re_id(ih), work(:,:,:,ih) )
             end if
          end do
       end if
    end if

    if ( hist_qe ) then
       do ih = 1, n_hyd
          if ( hist_qe_id(ih) > 0 ) then
             call file_history_query( hist_qe_id(ih), do_put )
             if ( do_put ) then
                call atmos_phy_mp_vars_get_diagnostic( &
                     dens(:,:,:), temp(:,:,:), qtrc(:,:,:,:), & ! [IN]
                     qe=work(:,:,:,:)                         ) ! [OUT]
                exit
             end if
          end if
       end do
       if ( do_put ) then
          do ih = 1, n_hyd
             if ( hist_qe_id(ih) > 0 ) then
                call file_history_query( hist_qe_id(ih), do_put )
                if( do_put ) call file_history_put( hist_qe_id(ih), work(:,:,:,ih) )
             end if
          end do
       end if
    end if

    if ( hist_ne ) then
       do ih = 1, n_hyd
          if ( hist_ne_id(ih) > 0 ) then
             call file_history_query( hist_ne_id(ih), do_put )
             if ( do_put ) then
                call atmos_phy_mp_vars_get_diagnostic( &
                     dens(:,:,:), temp(:,:,:), qtrc(:,:,:,:), & ! [IN]
                     ne=work(:,:,:,:)                         ) ! [OUT]
                exit
             end if
          end if
       end do
       if ( do_put ) then
          do ih = 1, n_hyd
             if ( hist_ne_id(ih) > 0 ) then
                call file_history_query( hist_ne_id(ih), do_put )
                if( do_put ) call file_history_put( hist_ne_id(ih), work(:,:,:,ih) )
             end if
          end do
       end if
    end if

    return
  end subroutine atmos_phy_mp_vars_history

  subroutine atmos_phy_mp_vars_get_diagnostic( &
       DENS, TEMP, QTRC,   &
       CLDFRAC, Re, Qe, Ne )
    use scale_atmos_hydrometeor, only: &
       n_hyd, &
       i_hc,  &
       i_hr,  &
       i_hi,  &
       i_hs,  &
       i_hg,  &
       i_hh
    use scale_atmos_phy_mp_kessler, only: &
       atmos_phy_mp_kessler_qtrc2qhyd, &
       atmos_phy_mp_kessler_effective_radius, &
       atmos_phy_mp_kessler_cloud_fraction
    use scale_atmos_phy_mp_tomita08, only: &
       atmos_phy_mp_tomita08_qtrc2qhyd, &
       atmos_phy_mp_tomita08_effective_radius, &
       atmos_phy_mp_tomita08_cloud_fraction
    use scale_atmos_phy_mp_sn14, only: &
       atmos_phy_mp_sn14_qtrc2qhyd, &
       atmos_phy_mp_sn14_qtrc2nhyd, &
       atmos_phy_mp_sn14_effective_radius, &
       atmos_phy_mp_sn14_cloud_fraction
    use scale_atmos_phy_mp_suzuki10, only: &
       atmos_phy_mp_suzuki10_qtrc2qhyd, &
       atmos_phy_mp_suzuki10_qtrc2nhyd, &
       atmos_phy_mp_suzuki10_effective_radius, &
       atmos_phy_mp_suzuki10_cloud_fraction
    use mod_atmos_admin, only: &
       atmos_phy_mp_type
    implicit none

    real(RP), intent(in) :: DENS(ka,ia,ja)
    real(RP), intent(in) :: TEMP(ka,ia,ja)
    real(RP), intent(in) :: QTRC(ka,ia,ja,qa)
    real(RP), intent(out), optional :: CLDFRAC(ka,ia,ja)
    real(RP), intent(out), optional :: Re     (ka,ia,ja,n_hyd)
    real(RP), intent(out), optional :: Qe     (ka,ia,ja,n_hyd)
    real(RP), intent(out), optional :: Ne     (ka,ia,ja,n_hyd)

    integer :: k, i, j, ih

    if ( present(cldfrac) ) then
       if ( .not. diag_cldfrac ) then
          select case ( atmos_phy_mp_type )
          case ( 'KESSLER' )
             call atmos_phy_mp_kessler_cloud_fraction( &
                  ka, ks, ke, ia, is, ie, ja, js, je, &
                  qtrc(:,:,:,qs_mp+1:qe_mp), atmos_phy_mp_cldfrac_thleshold, & ! [IN]
                  atmos_phy_mp_cldfrac(:,:,:)                                ) ! [OUT]
          case ( 'TOMITA08' )
             call atmos_phy_mp_tomita08_cloud_fraction( &
                  ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                  qtrc(:,:,:,qs_mp+1:qe_mp), atmos_phy_mp_cldfrac_thleshold, & ! [IN]
                  atmos_phy_mp_cldfrac(:,:,:)                                ) ! [OUT]
          case ( 'SN14' )
             call atmos_phy_mp_sn14_cloud_fraction( &
                  ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                  qtrc(:,:,:,qs_mp+1:qe_mp), atmos_phy_mp_cldfrac_thleshold, & ! [IN]
                  atmos_phy_mp_cldfrac(:,:,:)                                ) ! [OUT]
          case ( 'SUZUKI10' )
             call atmos_phy_mp_suzuki10_cloud_fraction( &
                  ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                  qtrc(:,:,:,qs_mp+1:qe_mp), atmos_phy_mp_cldfrac_thleshold, & ! [IN]
                  atmos_phy_mp_cldfrac(:,:,:)                                ) ! [OUT]
          case default
!OCL XFILL
             atmos_phy_mp_cldfrac(:,:,:) = 0.0_rp
          end select
          diag_cldfrac = .true.
       end if
!OCL XFILL
       do j = jsb, jeb
       do i = isb, ieb
       do k = ks, ke
          cldfrac(k,i,j) = atmos_phy_mp_cldfrac(k,i,j)
       end do
       end do
       end do
    end if

    if ( present(re) ) then
       if ( .not. diag_re ) then
          select case ( atmos_phy_mp_type )
          case ( 'KESSLER' )
             call atmos_phy_mp_kessler_effective_radius( &
                  ka, ks, ke, ia, is, ie, ja, js, je, &
                  dens(:,:,:), temp(:,:,:), qtrc(:,:,:,qs_mp+1:qe_mp), & ! [IN]
                  atmos_phy_mp_re(:,:,:,:)                             ) ! [OUT]
          case ( 'TOMITA08' )
             call atmos_phy_mp_tomita08_effective_radius( &
                  ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                  dens(:,:,:), temp(:,:,:), qtrc(:,:,:,qs_mp+1:qe_mp), & ! [IN]
                  atmos_phy_mp_re(:,:,:,:)                             ) ! [OUT]
          case ( 'SN14' )
             call atmos_phy_mp_sn14_effective_radius( &
                  ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                  dens(:,:,:), temp(:,:,:), qtrc(:,:,:,qs_mp+1:qe_mp), & ! [IN]
                  atmos_phy_mp_re(:,:,:,:)                             ) ! [OUT]
          case ( 'SUZUKI10' )
             call atmos_phy_mp_suzuki10_effective_radius( &
                  ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                  dens(:,:,:), temp(:,:,:), qtrc(:,:,:,qs_mp+1:qe_mp), & ! [IN]
                  atmos_phy_mp_re(:,:,:,:)                             ) ! [OUT]
          case default
!OCL XFILL
             atmos_phy_mp_re(:,:,:,:) = 0.0_rp
          end select
          diag_re = .true.
       end if
!OCL XFILL
       do ih = 1, n_hyd
       do j = jsb, jeb
       do i = isb, ieb
       do k = ks, ke
          re(k,i,j,ih) = atmos_phy_mp_re(k,i,j,ih)
       end do
       end do
       end do
       end do
    end if

    if ( present(qe) ) then
       if ( .not. diag_qe ) then
          select case ( atmos_phy_mp_type )
          case ( 'KESSLER' )
             call atmos_phy_mp_kessler_qtrc2qhyd( &
                  ka, ks, ke, ia, is, ie, ja, js, je, &
                  qtrc(:,:,:,qs_mp+1:qe_mp), & ! [IN]
                  atmos_phy_mp_qe(:,:,:,:)   ) ! [OUT]
          case ( 'TOMITA08' )
             call atmos_phy_mp_tomita08_qtrc2qhyd( &
                  ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                  qtrc(:,:,:,qs_mp+1:qe_mp), & ! [IN]
                  atmos_phy_mp_qe(:,:,:,:)   ) ! [OUT]
          case ( 'SN14' )
             call atmos_phy_mp_sn14_qtrc2qhyd( &
                  ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                  qtrc(:,:,:,qs_mp+1:qe_mp), & ! [IN]
                  atmos_phy_mp_qe(:,:,:,:)   ) ! [OUT]
          case ( 'SUZUKI10' )
             call atmos_phy_mp_suzuki10_qtrc2qhyd( &
                  ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                  qtrc(:,:,:,qs_mp+1:qe_mp), & ! [IN]
                  atmos_phy_mp_qe(:,:,:,:)   ) ! [OUT]
          case default
!OCL XFILL
             atmos_phy_mp_qe(:,:,:,:) = 0.0_rp
          end select
          diag_qe = .true.
       end if
!OCL XFILL
       do ih = 1, n_hyd
       do j = jsb, jeb
       do i = isb, ieb
       do k = ks, ke
          qe(k,i,j,ih) = atmos_phy_mp_qe(k,i,j,ih)
       end do
       end do
       end do
       end do
    end if

    if ( present(ne) ) then
       if ( .not. diag_ne ) then
          select case ( atmos_phy_mp_type )
          case ( 'KESSLER', 'TOMITA08' )
             ! do nothing
          case ( 'SN14' )
             call atmos_phy_mp_sn14_qtrc2nhyd( &
                  ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                  qtrc(:,:,:,qs_mp+1:qe_mp), & ! [IN]
                  atmos_phy_mp_ne(:,:,:,:)   ) ! [OUT]
          case ( 'SUZUKI10' )
             call atmos_phy_mp_suzuki10_qtrc2nhyd( &
                  ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                  dens(:,:,:), qtrc(:,:,:,qs_mp+1:qe_mp), & ! [IN]
                  atmos_phy_mp_ne(:,:,:,:)                ) ! [OUT]
          end select
          diag_ne = .true.
       end if
!OCL XFILL
       do ih = 1, n_hyd
       do j = jsb, jeb
       do i = isb, ieb
       do k = ks, ke
          ne(k,i,j,ih) = atmos_phy_mp_ne(k,i,j,ih)
       end do
       end do
       end do
       end do
    end if

    return
  end subroutine atmos_phy_mp_vars_get_diagnostic

  subroutine atmos_phy_mp_vars_reset_diagnostics
    diag_cldfrac = .false.
    diag_re      = .false.
    diag_qe      = .false.
    diag_ne      = .false.

    return
  end subroutine atmos_phy_mp_vars_reset_diagnostics

end module mod_atmos_phy_mp_vars