scale_ocean_grid_cartesC.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_ocean_grid_cartesc
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_atmos_grid_cartesc_index
  use scale_ocean_grid_cartesc_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: ocean_grid_cartesc_setup

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  real(RP), public, allocatable :: ocean_grid_cartesc_cz (:)
  real(RP), public, allocatable :: ocean_grid_cartesc_fz (:)
  real(RP), public, allocatable :: ocean_grid_cartesc_cdz(:)

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  private :: ocean_grid_cartesc_read
  private :: ocean_grid_cartesc_generate

  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,  private, parameter :: fz_max = 100
  real(RP), private :: fz(fz_max) ! face coordinate without surface (=0 m)

  character(len=H_LONG) :: ocean_grid_cartesc_in_basename  = ''
  logical               :: ocean_grid_cartesc_in_aggregate

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine ocean_grid_cartesc_setup
    use scale_prc, only: &
       prc_abort
    use scale_file, only: &
       file_aggregate
    implicit none

    namelist / param_ocean_grid_cartesc / &
       ocean_grid_cartesc_in_basename,  &
       ocean_grid_cartesc_in_aggregate, &
       fz

    integer :: ierr
    integer :: k
    !---------------------------------------------------------------------------

    log_newline
    log_info("OCEAN_GRID_CARTESC_setup",*) 'Setup'

    if ( okmax < 1 ) then
       log_info("OCEAN_GRID_CARTESC_setup",*) 'Skip because OKMAX < 1'
       return
    end if

    fz(:) = 0.0_rp

    ocean_grid_cartesc_in_aggregate = file_aggregate

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_ocean_grid_cartesc,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("OCEAN_GRID_CARTESC_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("OCEAN_GRID_CARTESC_setup",*) 'Not appropriate names in namelist PARAM_OCEAN_GRID_CARTESC. Check!'
       call prc_abort
    endif
    log_nml(param_ocean_grid_cartesc)

    allocate( ocean_grid_cartesc_cz(oks  :oke) )
    allocate( ocean_grid_cartesc_fz(oks-1:oke) )
    allocate( ocean_grid_cartesc_cdz(oks  :oke) )

    log_newline
    log_info("OCEAN_GRID_CARTESC_setup",*) 'Ocean grid information '

    if ( ocean_grid_cartesc_in_basename /= '' ) then
       call ocean_grid_cartesc_read
    else
       log_info("OCEAN_GRID_CARTESC_setup",*) 'Not found input grid file. Grid position is calculated.'

       call ocean_grid_cartesc_generate
    endif

    if ( oke == oks ) then
       log_newline
       log_info("OCEAN_GRID_CARTESC_setup",*) 'Single layer. ODZ = ', ocean_grid_cartesc_cdz(1)
    else
       log_newline
       log_info("OCEAN_GRID_CARTESC_setup",'(1x,A)') 'Vertical Coordinate'
       log_info_cont('(1x,A)')                  '|   k       z      zh      dz   k |'
       log_info_cont('(1x,A)')                  '|         [m]     [m]     [m]     |'
       k = oks-1
       log_info_cont('(1x,A,F8.3,A,I4,A)')      '|            ',ocean_grid_cartesc_fz(k),'        ',k,' | Atmosphere interface'
       do k = oks, oke-1
       log_info_cont('(1x,A,I4,F8.3,A,F8.3,A)') '|',k,ocean_grid_cartesc_cz(k),'        ',ocean_grid_cartesc_cdz(k),'     | '
       log_info_cont('(1x,A,F8.3,A,I4,A)')      '|            ',ocean_grid_cartesc_fz(k),'       |',k,' | '
       enddo
       k = oke
       log_info_cont('(1x,A,I4,F8.3,A,F8.3,A)') '|',k,ocean_grid_cartesc_cz(k),'        ',ocean_grid_cartesc_cdz(k),'     | '
       log_info_cont('(1x,A,F8.3,A,I4,A)')      '|            ',ocean_grid_cartesc_fz(k),'        ',k,' | layer of no motion'
       log_info_cont('(1x,A)')                  '|=================================|'
    endif

    return
  end subroutine ocean_grid_cartesc_setup

  !-----------------------------------------------------------------------------
  subroutine ocean_grid_cartesc_read
    use scale_file, only: &
       file_open, &
       file_read
    use scale_prc, only: &
       prc_myrank
    implicit none

    integer  :: fid
    !---------------------------------------------------------------------------

    log_newline
    log_info("OCEAN_GRID_CARTESC_read",*) 'Input ocean grid file '

    call file_open( ocean_grid_cartesc_in_basename, fid, rankid=prc_myrank, aggregate=ocean_grid_cartesc_in_aggregate )

    call file_read( fid, 'OCZ',  ocean_grid_cartesc_cz(:) )
    call file_read( fid, 'OCDZ', ocean_grid_cartesc_cdz(:) )
    call file_read( fid, 'OFZ',  ocean_grid_cartesc_fz(:) )

    return
  end subroutine ocean_grid_cartesc_read

  !-----------------------------------------------------------------------------
  ! It uses FZ, not DZ. Note, LAND_GRID_CARTESC_generate uses DZ
  subroutine ocean_grid_cartesc_generate
    implicit none

    integer :: k
    !---------------------------------------------------------------------------

    if ( oka == 1 .and. fz(1) == 0.0_rp ) then
       fz(1) = 1.0_rp ! to avoid zero thickness (tentative)
    end if
    ocean_grid_cartesc_fz(oks-1) = 0.0_rp
    do k = oks, oke
       ocean_grid_cartesc_fz(k) = fz(k)
    enddo

    do k = oks, oke
       ocean_grid_cartesc_cdz(k) = ocean_grid_cartesc_fz(k) - ocean_grid_cartesc_fz(k-1)
       ocean_grid_cartesc_cz(k) = ocean_grid_cartesc_cdz(k) / 2.0_rp + ocean_grid_cartesc_fz(k-1)
    enddo

    return
  end subroutine ocean_grid_cartesc_generate

end module scale_ocean_grid_cartesc