scale_topography.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_topography
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_atmos_grid_cartesc_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: topo_setup
  public :: topo_fillhalo
  public :: topo_write

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical, public :: topo_exist = .false. 

  real(RP), public, allocatable :: topo_zsfc(:,:)

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  private :: topo_read

  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  character(len=H_LONG),  private :: topo_in_basename  = ''
  logical,                private :: topo_in_aggregate
  logical,                private :: topo_in_check_coordinates = .false.
  character(len=H_LONG),  private :: topo_out_basename = ''
  logical,                private :: topo_out_aggregate
  character(len=H_MID),   private :: topo_out_title    = 'SCALE-RM TOPOGRAPHY'
  character(len=H_SHORT), private :: topo_out_dtype    = 'DEFAULT'

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine topo_setup
    use scale_file, only: &
       file_aggregate
    use scale_prc, only: &
       prc_abort
    implicit none

    namelist / param_topo / &
       topo_in_basename,          &
       topo_in_aggregate,         &
       topo_in_check_coordinates, &
       topo_out_basename,         &
       topo_out_aggregate,        &
       topo_out_dtype

    integer :: ierr
    !---------------------------------------------------------------------------

    log_newline
    log_info("TOPO_setup",*) 'Setup'

    topo_in_aggregate  = file_aggregate
    topo_out_aggregate = file_aggregate

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_topo,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("TOPO_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("TOPO_setup",*) 'Not appropriate names in namelist PARAM_TOPO. Check!'
       call prc_abort
    endif
    log_nml(param_topo)

    allocate( topo_zsfc(ia,ja) )
    topo_zsfc(:,:) = 0.0_rp

    ! read from file
    call topo_read

    return
  end subroutine topo_setup

  !-----------------------------------------------------------------------------
  subroutine topo_fillhalo( Zsfc, FILL_BND )
    use scale_comm_cartesc, only: &
       comm_vars8, &
       comm_wait
    implicit none

    real(RP), intent(inout), optional :: Zsfc(ia,ja)
    logical,  intent(in),    optional :: FILL_BND

    logical :: FILL_BND_
    !---------------------------------------------------------------------------

    fill_bnd_ = .false.
    if ( present(fill_bnd) ) fill_bnd_ = fill_bnd

    if ( present(zsfc) ) then
       call comm_vars8( zsfc(:,:), 1 )
       call comm_wait ( zsfc(:,:), 1, fill_bnd_ )
    else
       call comm_vars8( topo_zsfc(:,:), 1 )
       call comm_wait ( topo_zsfc(:,:), 1, fill_bnd_ )
    end if

    return
  end subroutine topo_fillhalo

  !-----------------------------------------------------------------------------
  subroutine topo_read
    use scale_file_cartesc, only: &
       file_cartesc_open, &
       file_cartesc_read, &
       file_cartesc_flush, &
       file_cartesc_check_coordinates, &
       file_cartesc_close
    use scale_prc, only: &
       prc_abort
    implicit none

    integer :: fid
    !---------------------------------------------------------------------------

    log_newline
    log_info("TOPO_read",*) 'Input topography file '

    if ( topo_in_basename /= '' ) then

       call file_cartesc_open( topo_in_basename, fid, aggregate=topo_in_aggregate )
       call file_cartesc_read( fid, 'TOPO', 'XY', topo_zsfc(:,:) )

       call file_cartesc_flush( fid )

       if ( topo_in_check_coordinates ) then
          call file_cartesc_check_coordinates( fid )
       end if

       call file_cartesc_close( fid )

       call topo_fillhalo( fill_bnd=.false. )

       topo_exist = .true.

    else
       log_info_cont(*) 'topography file is not specified.'

       topo_exist = .false.
    endif

    return
  end subroutine topo_read

  !-----------------------------------------------------------------------------
  subroutine topo_write
    use scale_file_cartesc, only: &
       file_cartesc_write
    implicit none
    !---------------------------------------------------------------------------

    if ( topo_out_basename /= '' ) then

       log_newline
       log_info("TOPO_write",*) 'Output topography file '

       call topo_fillhalo( fill_bnd=.false. )

       call file_cartesc_write( topo_zsfc(:,:), topo_out_basename, topo_out_title, & ! [IN]
                                'TOPO', 'Topography', 'm', 'XY',   topo_out_dtype, & ! [IN]
                                standard_name="surface_altitude",                  & ! [IN]
                                haszcoord=.false., aggregate=topo_out_aggregate    ) ! [IN]

    endif

    return
  end subroutine topo_write

end module scale_topography