scale_ocean_phy_file.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
module scale_ocean_phy_file
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_debug
  use scale_grid_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: ocean_phy_file_setup
  public :: ocean_phy_file

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  logical, allocatable, private :: is_OCN(:,:)

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine ocean_phy_file_setup( OCEAN_TYPE )
    use scale_process, only: &
       prc_mpistop
    use scale_landuse, only: &
       landuse_fact_ocean
    use scale_external_input, only: &
       extin_regist
    use scale_const, only: &
       undef => const_undef
    implicit none

    character(len=*), intent(in) :: ocean_type

    character(len=H_LONG) :: ocean_phy_file_basename              = ''
    logical               :: ocean_phy_file_enable_periodic_year  = .false.
    logical               :: ocean_phy_file_enable_periodic_month = .false.
    logical               :: ocean_phy_file_enable_periodic_day   = .false.
    integer               :: ocean_phy_file_step_fixed            = 0
    real(RP)              :: ocean_phy_file_offset                = 0.0_rp
    real(RP)              :: ocean_phy_file_defval              ! = UNDEF
    logical               :: ocean_phy_file_check_coordinates     = .true.
    integer               :: ocean_phy_file_step_limit            = 0

    namelist / param_ocean_phy_file / &
       ocean_phy_file_basename,              &
       ocean_phy_file_enable_periodic_year,  &
       ocean_phy_file_enable_periodic_month, &
       ocean_phy_file_enable_periodic_day,   &
       ocean_phy_file_step_fixed,            &
       ocean_phy_file_offset,                &
       ocean_phy_file_defval,                &
       ocean_phy_file_check_coordinates,     &
       ocean_phy_file_step_limit

    integer :: i, j
    integer :: ierr
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[FILE] / Categ[OCEAN PHY] / Origin[SCALElib]'

    if ( ocean_type /= 'FILE' ) then
       write(*,*) 'xxx wrong OCEAN_TYPE. Check!'
       call prc_mpistop
    end if

    ocean_phy_file_defval = undef

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_ocean_phy_file,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       if( io_l ) write(io_fid_log,*) '*** Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       write(*,*) 'xxx Not appropriate names in namelist PARAM_OCEAN_PHY_FILE. Check!'
       call prc_mpistop
    endif
    if( io_nml ) write(io_fid_nml,nml=param_ocean_phy_file)

    if ( ocean_phy_file_basename == '' ) then
       write(*,*) 'xxx OCEAN_PHY_FILE_basename is necessary'
       call prc_mpistop
    end if

    call extin_regist( ocean_phy_file_basename,              & ! [IN]
                       'OCEAN_TEMP',                         & ! [IN]
                       'XY',                                 & ! [IN]
                       ocean_phy_file_enable_periodic_year,  & ! [IN]
                       ocean_phy_file_enable_periodic_month, & ! [IN]
                       ocean_phy_file_enable_periodic_day,   & ! [IN]
                       ocean_phy_file_step_fixed,            & ! [IN]
                       ocean_phy_file_offset,                & ! [IN]
                       ocean_phy_file_defval,                & ! [IN]
                       ocean_phy_file_check_coordinates,     & ! [IN]
                       ocean_phy_file_step_limit             ) ! [IN]

    ! judge to run slab ocean model
    allocate( is_ocn(ia,ja) )

    do j = js, je
    do i = is, ie
       if ( landuse_fact_ocean(i,j) > 0.0_rp ) then
          is_ocn(i,j) = .true.
       else
          is_ocn(i,j) = .false.
       end if
    end do
    end do

    return
  end subroutine ocean_phy_file_setup

  !-----------------------------------------------------------------------------
  subroutine ocean_phy_file( &
       OCEAN_TEMP_t,    &
       OCEAN_TEMP,      &
       OCEAN_SFLX_WH,   &
       OCEAN_SFLX_prec, &
       OCEAN_SFLX_evap, &
       dt               )
    use scale_grid_index
    use scale_time, only: &
         nowdaysec => time_nowdaysec
    use scale_process, only: &
         prc_mpistop
    use scale_external_input, only: &
         extin_update
    implicit none

    real(RP), intent(out) :: ocean_temp_t   (ia,ja)
    real(RP), intent(in)  :: ocean_temp     (ia,ja)
    real(RP), intent(in)  :: ocean_sflx_wh  (ia,ja)
    real(RP), intent(in)  :: ocean_sflx_prec(ia,ja)
    real(RP), intent(in)  :: ocean_sflx_evap(ia,ja)
    real(DP), intent(in)  :: dt

    real(RP) :: ocean_temp_new(ia,ja)

    logical :: error

    integer :: i, j
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*) '*** Ocean physics step: File'

    call extin_update( &
         ocean_temp_new, & ! (out)
         'OCEAN_TEMP',   & ! (in)
         nowdaysec,      & ! (in)
         error           ) ! (out)
    if ( error ) then
       write(*,*) 'xxx Requested data is not found!'
       call prc_mpistop
    end if

    do j = js, je
    do i = is, ie
       if( is_ocn(i,j) ) then
          ocean_temp_t(i,j) = ( ocean_temp_new(i,j) - ocean_temp(i,j) ) / dt
       else
          ocean_temp_t(i,j) = 0.0_rp
       endif
    enddo
    enddo

    return
  end subroutine ocean_phy_file

end module scale_ocean_phy_file