mod_atmos_phy_ae_vars.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "inc_openmp.h"
module mod_atmos_phy_ae_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_ae_vars_setup
  public :: atmos_phy_ae_vars_fillhalo
  public :: atmos_phy_ae_vars_restart_read
  public :: atmos_phy_ae_vars_restart_write

  public :: atmos_phy_ae_vars_restart_create
  public :: atmos_phy_ae_vars_restart_open
  public :: atmos_phy_ae_vars_restart_def_var
  public :: atmos_phy_ae_vars_restart_enddef
  public :: atmos_phy_ae_vars_restart_close

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,               public :: atmos_phy_ae_restart_output                = .false.                

  character(len=H_LONG),  public :: atmos_phy_ae_restart_in_basename           = ''
  logical,                public :: atmos_phy_ae_restart_in_postfix_timelabel  = .false.                
  character(len=H_LONG),  public :: atmos_phy_ae_restart_out_basename          = ''
  logical,                public :: atmos_phy_ae_restart_out_postfix_timelabel = .true.                 
  character(len=H_MID),   public :: atmos_phy_ae_restart_out_title             = 'ATMOS_PHY_AE restart'
  character(len=H_SHORT), public :: atmos_phy_ae_restart_out_dtype             = 'DEFAULT'

  real(RP), public, allocatable :: atmos_phy_ae_rhoq_t(:,:,:,:)                               ! tendency rho*QTRC [kg/kg/s]

  real(RP), public, allocatable :: atmos_phy_ae_ccn(:,:,:)                                    ! cloud condensation nuclei [/m3]
  real(RP), public, allocatable :: atmos_phy_ae_ccn_t(:,:,:)                                  ! tendency CCN [/m3/s]
  real(RP), public, allocatable :: atmos_phy_ae_emit(:,:,:,:)                                 ! emission of aerosol and gas
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,                private, parameter :: vmax = 1
  integer,                private, parameter :: i_ccn = 1

  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)
  integer,                private            :: var_id(vmax)
  integer,                private            :: restart_fid = -1  ! file ID

  data var_name / 'CCN' /
  data var_desc / 'cloud condensation nuclei' /
  data var_unit / 'num/m3' /

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_setup
    use scale_process, only: &
       prc_mpistop
    use scale_const, only: &
       undef => const_undef
    use scale_atmos_phy_ae, only: &
       qa_ae, &
       qs_ae, &
       qe_ae
    implicit none

    namelist / param_atmos_phy_ae_vars / &
       atmos_phy_ae_restart_in_basename,           &
       atmos_phy_ae_restart_in_postfix_timelabel,  &
       atmos_phy_ae_restart_output,                &
       atmos_phy_ae_restart_out_basename,          &
       atmos_phy_ae_restart_out_postfix_timelabel, &
       atmos_phy_ae_restart_out_title,             &
       atmos_phy_ae_restart_out_dtype

    integer :: ierr
    integer :: iv
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[VARS] / Categ[ATMOS PHY_AE] / Origin[SCALE-RM]'

    allocate( atmos_phy_ae_rhoq_t(ka,ia,ja,qs_ae:qe_ae) )
    atmos_phy_ae_rhoq_t(:,:,:, :) = undef

    allocate( atmos_phy_ae_ccn(ka,ia,ja) )
    atmos_phy_ae_ccn(:,:,:) = undef

    allocate( atmos_phy_ae_ccn_t(ka,ia,ja) )
    atmos_phy_ae_ccn_t(:,:,:) = undef

    allocate( atmos_phy_ae_emit(ka,ia,ja,qa_ae) )
    atmos_phy_ae_emit(:,:,:,:) = 0.0_rp

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_ae_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       if( io_l ) write(io_fid_log,*) '*** Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       write(*,*) 'xxx Not appropriate names in namelist PARAM_ATMOS_PHY_AE_VARS. Check!'
       call prc_mpistop
    endif
    if( io_nml ) write(io_fid_nml,nml=param_atmos_phy_ae_vars)

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** [ATMOS_PHY_AE] prognostic/diagnostic variables'
    if( io_l ) write(io_fid_log,'(1x,A,A24,A,A48,A,A12,A)') &
               '***       |', 'VARNAME                 ','|', &
               'DESCRIPTION                                     ', '[', 'UNIT        ', ']'
    do iv = 1, vmax
       if( io_l ) write(io_fid_log,'(1x,A,I3,A,A24,A,A48,A,A12,A)') &
                  '*** NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
    enddo

    if( io_l ) write(io_fid_log,*)
    if ( atmos_phy_ae_restart_in_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** Restart input?  : YES, file = ', trim(atmos_phy_ae_restart_in_basename)
       if( io_l ) write(io_fid_log,*) '*** Add timelabel?  : ', atmos_phy_ae_restart_in_postfix_timelabel
    else
       if( io_l ) write(io_fid_log,*) '*** Restart input?  : NO'
    endif
    if (       atmos_phy_ae_restart_output             &
         .AND. atmos_phy_ae_restart_out_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** Restart output? : YES, file = ', trim(atmos_phy_ae_restart_out_basename)
       if( io_l ) write(io_fid_log,*) '*** Add timelabel?  : ', atmos_phy_ae_restart_out_postfix_timelabel
    else
       if( io_l ) write(io_fid_log,*) '*** Restart output? : NO'
       atmos_phy_ae_restart_output = .false.
    endif

    return
  end subroutine atmos_phy_ae_vars_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_fillhalo
    use scale_comm, only: &
       comm_vars8, &
       comm_wait
    implicit none

    integer :: i, j
    !---------------------------------------------------------------------------

    do j  = js, je
    do i  = is, ie
       atmos_phy_ae_ccn(   1:ks-1,i,j) = atmos_phy_ae_ccn(ks,i,j)
       atmos_phy_ae_ccn(ke+1:ka,  i,j) = atmos_phy_ae_ccn(ke,i,j)
    enddo
    enddo

    call comm_vars8( atmos_phy_ae_ccn(:,:,:), 1 )
    call comm_wait ( atmos_phy_ae_ccn(:,:,:), 1 )

    return
  end subroutine atmos_phy_ae_vars_fillhalo

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_open
    use scale_time, only: &
       time_gettimelabel
    use scale_fileio, only: &
       fileio_open
    implicit none

    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Open restart file (ATMOS_PHY_AE) ***'

    if ( atmos_phy_ae_restart_in_basename /= '' ) then

       if ( atmos_phy_ae_restart_in_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_ae_restart_in_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_ae_restart_in_basename)
       endif

       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(basename)

       call fileio_open( restart_fid, basename )
    else
       if( io_l ) write(io_fid_log,*) '*** restart file for ATMOS_PHY_AE is not specified.'
    endif

    return
  end subroutine atmos_phy_ae_vars_restart_open

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_read
    use scale_rm_statistics, only: &
       statistics_checktotal, &
       stat_total
    use scale_fileio, only: &
       fileio_read, &
       fileio_flush
    implicit none

    real(RP) :: total
    integer  :: i, j
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Read from restart file (ATMOS_PHY_AE) ***'

       call fileio_read( atmos_phy_ae_ccn(:,:,:),                & ! [OUT]
                         restart_fid, var_name(1), 'ZXY', step=1 ) ! [IN]

       if ( io_aggregate ) then
          call fileio_flush( restart_fid ) ! X/Y halos have been read from file

          ! fill K halos
          do j  = 1, ja
          do i  = 1, ia
             atmos_phy_ae_ccn(   1:ks-1,i,j) = atmos_phy_ae_ccn(ks,i,j)
             atmos_phy_ae_ccn(ke+1:ka,  i,j) = atmos_phy_ae_ccn(ke,i,j)
          enddo
          enddo
       else
          call atmos_phy_ae_vars_fillhalo
       end if

       if ( statistics_checktotal ) then
          call stat_total( total, atmos_phy_ae_ccn(:,:,:), var_name(1) )
       end if
    else
       if( io_l ) write(io_fid_log,*) '*** invlaid restart file ID for ATMOS_PHY_AE.'
    endif

    return
  end subroutine atmos_phy_ae_vars_restart_read

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_create
    use scale_time, only: &
       time_gettimelabel
    use scale_fileio, only: &
       fileio_create
    implicit none

    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    if ( atmos_phy_ae_restart_out_basename /= '' ) then

       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Create restart file (ATMOS_PHY_AE) ***'

       if ( atmos_phy_ae_restart_out_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_ae_restart_out_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_ae_restart_out_basename)
       endif

       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(basename)

       call fileio_create( restart_fid,                                                             & ! [OUT]
                           basename, atmos_phy_ae_restart_out_title, atmos_phy_ae_restart_out_dtype ) ! [IN]

    endif

    return
  end subroutine atmos_phy_ae_vars_restart_create

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_enddef
    use scale_fileio, only: &
       fileio_enddef
    implicit none

    if ( restart_fid /= -1 ) then
       call fileio_enddef( restart_fid ) ! [IN]
    endif

    return
  end subroutine atmos_phy_ae_vars_restart_enddef

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_close
    use scale_fileio, only: &
       fileio_close
    implicit none
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Close restart file (ATMOS_PHY_AE) ***'

       call fileio_close( restart_fid ) ! [IN]

       restart_fid = -1
    endif

    return
  end subroutine atmos_phy_ae_vars_restart_close

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_def_var
    use scale_fileio, only: &
       fileio_def_var
    implicit none
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       call fileio_def_var( restart_fid, var_id(1), var_name(1), var_desc(1), var_unit(1), &
                            'ZXY', atmos_phy_ae_restart_out_dtype  ) ! [IN]
    endif

    return
  end subroutine atmos_phy_ae_vars_restart_def_var

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_write
    use scale_rm_statistics, only: &
       statistics_checktotal, &
       stat_total
    use scale_fileio, only: &
       fileio_write_var
    implicit none

    real(RP) :: total
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then

       call atmos_phy_ae_vars_fillhalo

       if ( statistics_checktotal ) then
          call stat_total( total, atmos_phy_ae_ccn(:,:,:), var_name(1) )
       end if

       call fileio_write_var( restart_fid, var_id(1), atmos_phy_ae_ccn(:,:,:), &
                              var_name(1), 'ZXY' ) ! [IN]

    endif

    return
  end subroutine atmos_phy_ae_vars_restart_write

end module mod_atmos_phy_ae_vars