scale_atmos_phy_ae.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
module scale_atmos_phy_ae
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  abstract interface
     subroutine ae( &
          QQA,  &
          DENS, &
          MOMZ, &
          MOMX, &
          MOMY, &
          RHOT, &
          EMIT, &
          NREG, &
          QTRC, &
          CN,   &
          CCN,  &
          RHOQ_t_AE )
       use scale_precision
       use scale_grid_index
       use scale_tracer
       integer,  intent(in)    :: QQA
       real(RP), intent(inout) :: DENS(KA,IA,JA)
       real(RP), intent(inout) :: MOMZ(KA,IA,JA)
       real(RP), intent(inout) :: MOMX(KA,IA,JA)
       real(RP), intent(inout) :: MOMY(KA,IA,JA)
       real(RP), intent(inout) :: RHOT(KA,IA,JA)
       real(RP), intent(inout) :: EMIT(KA,IA,JA,QQA)
       real(RP), intent(in)    :: NREG(KA,IA,JA)
       real(RP), intent(inout) :: QTRC(KA,IA,JA,QA)
       real(RP), intent(out)   :: CN(KA,IA,JA)
       real(RP), intent(out)   :: CCN(KA,IA,JA)
       real(RP), intent(inout) :: RHOQ_t_AE(KA,IA,JA,QA)
     end subroutine ae
     subroutine su
     end subroutine su
     subroutine er( &
          RE, &
          QTRC, &
          RH )
       use scale_precision
       use scale_grid_index
       use scale_tracer
       use scale_atmos_aerosol, only: n_ae
       real(RP), intent(out) :: Re  (KA,IA,JA,N_AE) ! effective radius
       real(RP), intent(in)  :: QTRC(KA,IA,JA,QA)   ! tracer mass concentration [kg/kg]
       real(RP), intent(in)  :: RH  (KA,IA,JA)      ! relative humidity         (0-1)
     end subroutine er
  end interface

  procedure(ae), pointer :: atmos_phy_ae => null()
  procedure(su), pointer :: atmos_phy_ae_setup => null()
  procedure(er), pointer :: atmos_phy_ae_effectiveradius => null()
  public :: atmos_phy_ae_config
  public :: atmos_phy_ae
  public :: atmos_phy_ae_setup
  public :: atmos_phy_ae_effectiveradius

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  integer, public    :: qa_ae  ! number of aerosol microphysical tracers
  integer, public    :: qs_ae  ! start index in QTRC
  integer, public    :: qe_ae  ! end   index in QTRC

  character(len=H_SHORT), pointer, public :: atmos_phy_ae_name(:)
  character(len=H_MID),   pointer, public :: atmos_phy_ae_desc(:)
  character(len=H_SHORT), pointer, public :: atmos_phy_ae_unit(:)
  real(RP), pointer, public :: atmos_phy_ae_dens(:) ! aerosol density [kg/m3]=[g/L]
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_config( AE_TYPE )
    use scale_process, only: &
       prc_mpistop
    use scale_atmos_phy_ae_dummy, only: &
       atmos_phy_ae_dummy_config, &
       atmos_phy_ae_dummy_setup, &
       atmos_phy_ae_dummy, &
       atmos_phy_ae_dummy_effectiveradius, &
       atmos_phy_ae_dummy_name, &
       atmos_phy_ae_dummy_unit, &
       atmos_phy_ae_dummy_desc, &
       atmos_phy_ae_dummy_dens
    use scale_atmos_phy_ae_kajino13, only: &
       atmos_phy_ae_kajino13_config, &
       atmos_phy_ae_kajino13_setup, &
       atmos_phy_ae_kajino13, &
       atmos_phy_ae_kajino13_effectiveradius, &
       atmos_phy_ae_kajino13_name, &
       atmos_phy_ae_kajino13_unit, &
       atmos_phy_ae_kajino13_desc, &
       atmos_phy_ae_kajino13_dens
    implicit none

    character(len=*), intent(in) :: ae_type
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*) '*** => ', trim(ae_type), ' is selected.'

    select case( ae_type )
    case('DUMMY','NONE')
       call atmos_phy_ae_dummy_config( &
            ae_type, &
            qa_ae, qs_ae ) ! (out)
       atmos_phy_ae_setup           => atmos_phy_ae_dummy_setup
       atmos_phy_ae                 => atmos_phy_ae_dummy
       atmos_phy_ae_effectiveradius => atmos_phy_ae_dummy_effectiveradius
       atmos_phy_ae_name            => atmos_phy_ae_dummy_name
       atmos_phy_ae_desc            => atmos_phy_ae_dummy_desc
       atmos_phy_ae_unit            => atmos_phy_ae_dummy_unit
       atmos_phy_ae_dens            => atmos_phy_ae_dummy_dens
    case('KAJINO13')
       call atmos_phy_ae_kajino13_config( &
            ae_type, &
            qa_ae, qs_ae ) ! (out)
       atmos_phy_ae_setup           => atmos_phy_ae_kajino13_setup
       atmos_phy_ae                 => atmos_phy_ae_kajino13
       atmos_phy_ae_effectiveradius => atmos_phy_ae_kajino13_effectiveradius
       atmos_phy_ae_name            => atmos_phy_ae_kajino13_name
       atmos_phy_ae_desc            => atmos_phy_ae_kajino13_desc
       atmos_phy_ae_unit            => atmos_phy_ae_kajino13_unit
       atmos_phy_ae_dens            => atmos_phy_ae_kajino13_dens
       write(*,*) '### aerosol type(', ae_type, '). is not recommended in current version!'
    case default
       write(*,*) 'xxx invalid aerosol type(', ae_type, '). CHECK!'
       call prc_mpistop
    end select

    qe_ae = qs_ae + qa_ae - 1

    return
  end subroutine atmos_phy_ae_config

end module scale_atmos_phy_ae