mod_atmos_phy_cp_driver Module Reference

module ATMOSPHERE / Physics Cumulus More...

Functions/Subroutines
subroutine, public	atmos_phy_cp_driver_setup
	Setup. More...
subroutine, public	atmos_phy_cp_driver_calc_tendency (update_flag)
	Driver. More...

Detailed Description

module ATMOSPHERE / Physics Cumulus

Description

Cumulus parameterization driver

Author

Team SCALE

NAMELIST

• No namelist group

History Output

name	description	unit	variable
CBMFX	cloud base mass flux	kg/m2/s	MFLX_cloudbase
CUBASE	CP cloud base height	m	cloudbase
CUMFRC_DP	CP cloud fraction (deep)	1	cldfrac_dp
CUMFRC_SH	CP cloud fraction (shallow)	1	cldfrac_sh
CUMHGT	CP cloud top height	m	cloudtop
DENS_t_CP	tendency DENS in CP	kg/m3/s	DENS_t_CP
PREC_CP	surface precipitation rate by CP	kg/m2/s	SFLX_rain
QV_t_CP	tendency rho*QV in CP	kg/m3/s	RHOQV_t_CP
RAIN_CP	surface rain rate by CP	kg/m2/s	SFLX_rain
RHOT_t_CP	tendency RHOT in CP	K*kg/m3/s	RHOT_t_CP
kf_nca	advection or cumulus convection timescale for KF	s	kf_nca
{HYD_NAME}_t_CP	tendency rho*{HYD_NAME} in CP; {HYD_NAME} is QC, QR, QI, QS, QG, QH.	kg/m3/s	RHOHYD_t_CP
w0mean	running mean vertical wind velocity	kg/m2/s	w0mean

Function/Subroutine Documentation

atmos_phy_cp_driver_setup()

subroutine, public mod_atmos_phy_cp_driver::atmos_phy_cp_driver_setup

(

)

Setup.

Definition at line 49 of file mod_atmos_phy_cp_driver.F90.

References scale_atmos_grid_cartesc_real::atmos_grid_cartesc_real_area, scale_atmos_grid_cartesc_real::atmos_grid_cartesc_real_cz, scale_atmos_hydrometeor::atmos_hydrometeor_ice_phase, scale_atmos_phy_cp_common::atmos_phy_cp_common_setup(), scale_atmos_phy_cp_kf::atmos_phy_cp_kf_setup(), mod_atmos_admin::atmos_phy_cp_type, mod_atmos_admin::atmos_sw_phy_cp, scale_atmos_grid_cartesc_index::ia, scale_atmos_grid_cartesc_index::ja, scale_atmos_grid_cartesc_index::ka, scale_atmos_grid_cartesc_index::ke, scale_atmos_grid_cartesc_index::ks, scale_prc::prc_abort(), scale_time::time_dtsec, and scale_time::time_dtsec_atmos_phy_cp.

Referenced by mod_atmos_driver::atmos_driver_setup().

    use scale_prc, only: &
       prc_abort
    use scale_atmos_phy_cp_common, only: &
       atmos_phy_cp_common_setup
    use scale_atmos_phy_cp_kf, only: &
       atmos_phy_cp_kf_setup
    use mod_atmos_admin, only: &
       atmos_phy_cp_type, &
       atmos_sw_phy_cp
    use scale_time , only :&
       time_dtsec,             &
       time_dtsec_atmos_phy_cp
    use scale_atmos_grid_cartesc_real, only: &
       atmos_grid_cartesc_real_cz, &
       atmos_grid_cartesc_real_area
    use scale_atmos_hydrometeor, only: &
       atmos_hydrometeor_ice_phase
    implicit none

    logical :: warmrain
    !---------------------------------------------------------------------------

    log_newline
    log_info("ATMOS_PHY_CP_driver_setup",*) 'Setup'

    if ( atmos_sw_phy_cp ) then

       ! setup library component
       call atmos_phy_cp_common_setup
       select case ( atmos_phy_cp_type )
       case ( 'KF' )
          warmrain = ( .not. atmos_hydrometeor_ice_phase )
          call atmos_phy_cp_kf_setup( ka, ks, ke, ia, 1, ia, ja, 1, ja, &
                                      atmos_grid_cartesc_real_cz, atmos_grid_cartesc_real_area, &
                                      time_dtsec, time_dtsec_atmos_phy_cp,                      &
                                      warmrain                                                  )
       case default
          log_error("ATMOS_PHY_CP_driver_setup",*) 'ATMOS_PHY_CP_TYPE (', trim(atmos_phy_cp_type), ') is invalid. Check!'
          call prc_abort
       end select

    else
       log_info("ATMOS_PHY_CP_driver_setup",*) 'this component is never called.'
    endif

    return

Here is the call graph for this function:

Here is the caller graph for this function:

atmos_phy_cp_driver_calc_tendency()

subroutine, public mod_atmos_phy_cp_driver::atmos_phy_cp_driver_calc_tendency

(

logical, intent(in)

update_flag

)

Driver.

Definition at line 100 of file mod_atmos_phy_cp_driver.F90.

References scale_atmos_grid_cartesc_real::atmos_grid_cartesc_real_fz, scale_atmos_grid_cartesc_real::atmos_grid_cartesc_real_totvol, scale_atmos_grid_cartesc_real::atmos_grid_cartesc_real_totvolwxy, scale_atmos_grid_cartesc_real::atmos_grid_cartesc_real_totvolzuy, scale_atmos_grid_cartesc_real::atmos_grid_cartesc_real_totvolzxv, scale_atmos_grid_cartesc_real::atmos_grid_cartesc_real_vol, scale_atmos_grid_cartesc_real::atmos_grid_cartesc_real_volwxy, scale_atmos_grid_cartesc_real::atmos_grid_cartesc_real_volzuy, scale_atmos_grid_cartesc_real::atmos_grid_cartesc_real_volzxv, scale_atmos_phy_cp_common::atmos_phy_cp_common_wmean(), mod_atmos_phy_cp_vars::atmos_phy_cp_dens_t, scale_atmos_phy_cp_kf::atmos_phy_cp_kf_tendency(), mod_atmos_phy_cp_vars::atmos_phy_cp_mflx_cloudbase, mod_atmos_phy_cp_vars::atmos_phy_cp_rhohyd_t, mod_atmos_phy_cp_vars::atmos_phy_cp_rhoqv_t, mod_atmos_phy_cp_vars::atmos_phy_cp_rhot_t, mod_atmos_phy_cp_vars::atmos_phy_cp_sflx_rain, mod_atmos_admin::atmos_phy_cp_type, mod_atmos_phy_mp_driver::atmos_phy_mp_driver_qhyd2qtrc(), mod_atmos_vars::cptot, mod_atmos_vars::dens, mod_atmos_vars::dens_av, mod_atmos_vars::dens_tp, scale_atmos_hydrometeor::hyd_name, scale_atmos_grid_cartesc_index::ia, scale_atmos_grid_cartesc_index::ie, scale_atmos_grid_cartesc_index::ieb, scale_atmos_grid_cartesc_index::is, scale_atmos_grid_cartesc_index::isb, scale_atmos_grid_cartesc_index::ja, scale_atmos_grid_cartesc_index::je, scale_atmos_grid_cartesc_index::jeb, scale_atmos_grid_cartesc_index::js, scale_atmos_grid_cartesc_index::jsb, scale_atmos_grid_cartesc_index::ka, scale_atmos_grid_cartesc_index::ke, scale_atmos_grid_cartesc_index::ks, mod_atmos_vars::momx, mod_atmos_vars::momx_av, mod_atmos_vars::momx_tp, mod_atmos_vars::momy, mod_atmos_vars::momy_av, mod_atmos_vars::momy_tp, mod_atmos_vars::momz, mod_atmos_vars::momz_av, mod_atmos_vars::momz_tp, scale_atmos_hydrometeor::n_hyd, mod_atmos_vars::pres, mod_atmos_vars::qdry, mod_atmos_phy_mp_vars::qe_mp, mod_atmos_phy_mp_vars::qs_mp, mod_atmos_vars::qtrc, mod_atmos_vars::qtrc_av, mod_atmos_vars::qv, mod_atmos_vars::rhoq_tp, mod_atmos_vars::rhot, mod_atmos_vars::rhot_av, mod_atmos_vars::rhot_tp, mod_atmos_vars::rtot, scale_statistics::statistics_checktotal, mod_atmos_vars::temp, scale_time::time_dtsec, scale_time::time_dtsec_atmos_phy_cp, scale_tracer::tracer_name, mod_atmos_vars::u, mod_atmos_vars::v, and mod_atmos_vars::w.

Referenced by mod_atmos_driver::atmos_driver_calc_tendency().

    use scale_statistics, only: &
       statistics_checktotal, &
       statistics_total
    use scale_atmos_grid_cartesc_real, only: &
       atmos_grid_cartesc_real_vol,       &
       atmos_grid_cartesc_real_totvol,    &
       atmos_grid_cartesc_real_volwxy,    &
       atmos_grid_cartesc_real_totvolwxy, &
       atmos_grid_cartesc_real_volzuy,    &
       atmos_grid_cartesc_real_totvolzuy, &
       atmos_grid_cartesc_real_volzxv,    &
       atmos_grid_cartesc_real_totvolzxv
    use scale_file_history, only: &
       file_history_in
    use scale_time , only :&
       time_dtsec, &
       time_dtsec_atmos_phy_cp
    use scale_atmos_grid_cartesc_real, only: &
       fz => atmos_grid_cartesc_real_fz
    use scale_atmos_hydrometeor, only: &
       hyd_name
    use scale_atmos_phy_cp_kf, only: &
       atmos_phy_cp_kf_tendency
    use scale_atmos_phy_cp_common, only: &
       atmos_phy_cp_common_wmean
    use mod_atmos_phy_mp_vars, only: &
       qs_mp, &
       qe_mp
    use mod_atmos_phy_mp_driver, only: &
       atmos_phy_mp_driver_qhyd2qtrc
    use mod_atmos_admin, only: &
       atmos_phy_cp_type
    use mod_atmos_vars, only: &
       dens   => dens_av, &
       momz   => momz_av, &
       momx   => momx_av, &
       momy   => momy_av, &
       rhot   => rhot_av, &
       qtrc   => qtrc_av, &
       dens_t => dens_tp, &
       momz_t => momz_tp, &
       momx_t => momx_tp, &
       momy_t => momy_tp, &
       rhot_t => rhot_tp, &
       rhoq_t => rhoq_tp, &
       u,                 &
       v,                 &
       w,                 &
       temp,              &
       pres,              &
       qdry,              &
       qv,                &
       rtot,              &
       cptot
    use scale_atmos_hydrometeor, only: &
       n_hyd
    use mod_atmos_phy_cp_vars, only: &
       dens_t_cp      => atmos_phy_cp_dens_t,         &
       rhot_t_cp      => atmos_phy_cp_rhot_t,         &
       rhoqv_t_cp     => atmos_phy_cp_rhoqv_t,        &
       rhohyd_t_cp    => atmos_phy_cp_rhohyd_t,       &
       mflx_cloudbase => atmos_phy_cp_mflx_cloudbase, &
       sflx_rain      => atmos_phy_cp_sflx_rain,      &  ! convective rain [kg/m2/s]
       cloudtop       => atmos_phy_cp_cloudtop,       &  ! cloud top height [m]
       cloudbase      => atmos_phy_cp_cloudbase,      &  ! cloud base height [m]
       cldfrac_dp     => atmos_phy_cp_cldfrac_dp,     &  ! cloud fraction (deep convection) (0-1)
       cldfrac_sh     => atmos_phy_cp_cldfrac_sh,     &  ! cloud fraction (shallow convection) (0-1)
       w0mean         => atmos_phy_cp_w0mean,         &  ! running mean vertical wind velocity [m/s]
       kf_nca         => atmos_phy_cp_kf_nca             ! advection/cumulus convection timescale/dt for KF [step]
    implicit none

    logical, intent(in) :: update_flag

    real(RP) :: rhoq_t_cp(ka,ia,ja,qs_mp:qe_mp)

    integer  :: k, i, j, iq
    !---------------------------------------------------------------------------

    ! temporal running mean of vertical velocity
    call atmos_phy_cp_common_wmean( ka, ks, ke, ia, 1, ia, ja, 1, ja, &
                                    w(:,:,:),                            & ! [IN]
                                    time_dtsec, time_dtsec_atmos_phy_cp, & ! [IN]
                                    w0mean(:,:,:)                        ) ! [INOUT]
    call file_history_in( w0mean(:,:,:), 'w0mean', 'running mean vertical wind velocity', 'kg/m2/s', fill_halo=.true. )

    if ( update_flag ) then ! update
       select case ( atmos_phy_cp_type )
       case ( 'KF' )
          call atmos_phy_cp_kf_tendency( ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                                         dens(:,:,:),                              & ! [IN]
                                         u(:,:,:), v(:,:,:),                       & ! [IN]
                                         rhot(:,:,:), temp(:,:,:), pres(:,:,:),    & ! [IN]
                                         qdry(:,:,:), qv(:,:,:),                   & ! [IN]
                                         rtot(:,:,:), cptot(:,:,:),                & ! [IN]
                                         w0mean(:,:,:),                            & ! [IN]
                                         fz,                                       & ! [IN]
                                         time_dtsec_atmos_phy_cp,                  & ! [IN]
                                         dens_t_cp(:,:,:),                         & ! [INOUT]
                                         rhot_t_cp(:,:,:),                         & ! [INOUT]
                                         rhoqv_t_cp(:,:,:), rhohyd_t_cp(:,:,:,:),  & ! [INOUT]
                                         sflx_rain(:,:),                           & ! [OUT]
                                         cloudtop(:,:), cloudbase(:,:),            & ! [OUT]
                                         cldfrac_dp(:,:,:), cldfrac_sh(:,:,:),     & ! [OUT]
                                         kf_nca(:,:)                               ) ! [OUT]
       end select

!OCL XFILL
       do j  = jsb, jeb
       do i  = isb, ieb
          mflx_cloudbase(i,j) = 0.0_rp
       enddo
       enddo

       ! diagnose tendency of number concentration

       call file_history_in( mflx_cloudbase(:,:),   'CBMFX',     'cloud base mass flux',             'kg/m2/s', fill_halo=.true. )
       call file_history_in( sflx_rain(:,:),   'RAIN_CP',   'surface rain rate by CP',          'kg/m2/s', fill_halo=.true. )
       call file_history_in( sflx_rain(:,:),   'PREC_CP',   'surface precipitation rate by CP', 'kg/m2/s', fill_halo=.true. )
       call file_history_in( cloudtop(:,:),   'CUMHGT',    'CP cloud top height',              'm',       fill_halo=.true. )
       call file_history_in( cloudbase(:,:),   'CUBASE',    'CP cloud base height',             'm',       fill_halo=.true. )
       call file_history_in( cldfrac_dp(:,:,:), 'CUMFRC_DP', 'CP cloud fraction (deep)',         '1',       fill_halo=.true. )
       call file_history_in( cldfrac_sh(:,:,:), 'CUMFRC_SH', 'CP cloud fraction (shallow)',      '1',       fill_halo=.true. )
       call file_history_in( kf_nca(:,:),   'kf_nca',    'advection or cumulus convection timescale for KF', 's', fill_halo=.true. )

       call file_history_in( dens_t_cp(:,:,:), 'DENS_t_CP', 'tendency DENS in CP', 'kg/m3/s'  , fill_halo=.true. )
       call file_history_in( rhot_t_cp(:,:,:), 'RHOT_t_CP', 'tendency RHOT in CP', 'K*kg/m3/s', fill_halo=.true. )

       call file_history_in( rhoqv_t_cp(:,:,:), 'QV_t_CP',  'tendency rho*QV in CP', 'kg/m3/s', fill_halo=.true. )
       do iq = 1, n_hyd
          call file_history_in( rhohyd_t_cp(:,:,:,iq), trim(hyd_name(iq))//'_t_CP', &
                                'tendency rho*'//trim(hyd_name(iq))//' in CP', 'kg/m3/s', fill_halo=.true. )
       enddo

    endif ! update

    !$omp parallel do private(i,j,k) OMP_SCHEDULE_ collapse(2)
    do j = jsb, jeb
    do i = isb, ieb
    do k = ks, ke
       dens_t(k,i,j) = dens_t(k,i,j) + dens_t_cp(k,i,j)
       rhot_t(k,i,j) = rhot_t(k,i,j) + rhot_t_cp(k,i,j)
    enddo
    enddo
    enddo

    call atmos_phy_mp_driver_qhyd2qtrc( ka, ks, ke, ia, isb, ieb, ja, jsb, jeb, &
                                        rhoqv_t_cp(:,:,:), rhohyd_t_cp(:,:,:,:), & ! [IN]
                                        rhoq_t_cp(:,:,:,qs_mp:qe_mp)             ) ! [OUT]

    do iq = qs_mp, qe_mp
    !$omp parallel do private(i,j,k) OMP_SCHEDULE_ collapse(3)
    do j  = jsb, jeb
    do i  = isb, ieb
    do k  = ks, ke
       rhoq_t(k,i,j,iq) = rhoq_t(k,i,j,iq) + rhoq_t_cp(k,i,j,iq)
    enddo
    enddo
    enddo
    enddo

    if ( statistics_checktotal ) then
       call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                              dens_t_cp(:,:,:), 'DENS_t_CP',       &
                              atmos_grid_cartesc_real_vol(:,:,:),  &
                              atmos_grid_cartesc_real_totvol       )
       call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                              rhot_t_cp(:,:,:), 'RHOT_t_CP',       &
                              atmos_grid_cartesc_real_vol(:,:,:),  &
                              atmos_grid_cartesc_real_totvol       )

       do iq = qs_mp, qe_mp
          call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                                 rhoq_t_cp(:,:,:,iq), trim(tracer_name(iq))//'_t_CP', &
                                 atmos_grid_cartesc_real_vol(:,:,:),                  &
                                 atmos_grid_cartesc_real_totvol                       )
       enddo
    endif

    return

Here is the call graph for this function:

Here is the caller graph for this function: