mod_atmos_phy_cp_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module mod_atmos_phy_cp_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_atmos_grid_cartesc_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_cp_vars_setup
  public :: atmos_phy_cp_vars_fillhalo
  public :: atmos_phy_cp_vars_restart_read
  public :: atmos_phy_cp_vars_restart_write

  public :: atmos_phy_cp_vars_restart_create
  public :: atmos_phy_cp_vars_restart_open
  public :: atmos_phy_cp_vars_restart_def_var
  public :: atmos_phy_cp_vars_restart_enddef
  public :: atmos_phy_cp_vars_restart_close

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,               public :: atmos_phy_cp_restart_output                 = .false.                

  character(len=H_LONG),  public :: atmos_phy_cp_restart_in_basename           = ''
  logical,                public :: atmos_phy_cp_restart_in_postfix_timelabel  = .false.                
  logical,                public :: atmos_phy_cp_restart_in_aggregate
  character(len=H_LONG),  public :: atmos_phy_cp_restart_out_basename          = ''
  logical,                public :: atmos_phy_cp_restart_out_aggregate
  logical,                public :: atmos_phy_cp_restart_out_postfix_timelabel = .true.                 
  character(len=H_MID),   public :: atmos_phy_cp_restart_out_title             = 'ATMOS_PHY_CP restart'
  character(len=H_SHORT), public :: atmos_phy_cp_restart_out_dtype             = 'DEFAULT'

  real(RP), public, allocatable :: atmos_phy_cp_dens_t  (:,:,:)   ! tendency DENS [kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_cp_momz_t  (:,:,:)   ! tendency MOMZ [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_cp_rhot_t  (:,:,:)   ! tendency RHOT [K*kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_cp_rhoqv_t (:,:,:)   ! tendency rho*QV   [kg/kg/s]
  real(RP), public, allocatable :: atmos_phy_cp_rhohyd_t(:,:,:,:) ! tendency rho*QHYD [kg/kg/s]

  real(RP), public, allocatable :: atmos_phy_cp_mflx_cloudbase(:,:)   ! cloud base mass flux [kg/m2/s]
  real(RP), public, allocatable :: atmos_phy_cp_sflx_rain     (:,:)   ! convective rain [kg/m2/s]
  real(RP), public, allocatable :: atmos_phy_cp_cloudtop      (:,:)   ! cloud top  height [m]
  real(RP), public, allocatable :: atmos_phy_cp_cloudbase     (:,:)   ! cloud base height [m]
  real(RP), public, allocatable :: atmos_phy_cp_cldfrac_dp    (:,:,:) ! cloud fraction (deep    convection) (0-1)
  real(RP), public, allocatable :: atmos_phy_cp_cldfrac_sh    (:,:,:) ! cloud fraction (shallow convection) (0-1)
  real(RP), public, allocatable :: atmos_phy_cp_w0mean        (:,:,:) ! running mean vertical wind velocity [m/s]
  ! only for K-F scheme
  real(RP), public, allocatable :: atmos_phy_cp_kf_nca        (:,:)   ! advection/cumulus convection timescale/dt for KF[step]

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,                private, parameter :: vmax = 8
  integer,                private, parameter :: i_mflx_cloudbase = 1
  integer,                private, parameter :: i_sflx_convrain  = 2
  integer,                private, parameter :: i_cloudtop       = 3
  integer,                private, parameter :: i_cloudbase      = 4
  integer,                private, parameter :: i_cldfrac_dp     = 5
  integer,                private, parameter :: i_cldfrac_sh     = 6
  integer,                private, parameter :: i_w0mean         = 7
  integer,                private, parameter :: i_kf_nca         = 8


  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)
  character(len=H_SHORT), private            :: var_dim (vmax)
  integer,                private            :: var_id  (vmax)
  integer,                private            :: restart_fid = -1  ! file ID

  data var_name / 'MFLX_cloudbase',  &
                  'SFLX_convrain',   &
                  'cloudtop',        &
                  'cloudbase',       &
                  'cldfrac_dp',      &
                  'cldfrac_sh',      &
                  'w0mean',          &
                  'kf_nca'           /
  data var_desc / 'cloud base mass flux',                             &
                  'convective rain',                                  &
                  'cloud top height',                                 &
                  'cloud base height',                                &
                  'cloud fraction (deep convection)',                 &
                  'cloud fraction (shallow convection)',              &
                  'running mean vertical wind velocity',              &
                  'advection/cumulus convection timescale/dt for KF'  /
  data var_unit / 'kg/m2/s', &
                  'kg/m2/s', &
                  'm',       &
                  'm',       &
                  '1',       &
                  '1',       &
                  'm/s',     &
                  'step'     /
  data var_dim  / 'XY',  &
                  'XY',  &
                  'XY',  &
                  'XY',  &
                  'ZXY', &
                  'ZXY', &
                  'ZXY', &
                  'XY'   /

  ! tendency names
  integer,                private              :: vmax_t
  integer,                private              :: i_cp_dens_t = 1
  integer,                private              :: i_cp_rhot_t = 2
  integer,                private              :: i_cp_qv_t   = 3

  character(len=H_SHORT), private, allocatable :: var_t_name(:)
  character(len=H_MID),   private, allocatable :: var_t_desc(:)
  character(len=H_SHORT), private, allocatable :: var_t_unit(:)
  integer,                private, allocatable :: var_t_id  (:)

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_setup
    use scale_prc, only: &
       prc_abort
    use scale_const, only: &
       undef => const_undef
    use scale_atmos_hydrometeor, only: &
       n_hyd, &
       hyd_name
    implicit none

    namelist / param_atmos_phy_cp_vars / &
       atmos_phy_cp_restart_in_basename,           &
       atmos_phy_cp_restart_in_aggregate,          &
       atmos_phy_cp_restart_in_postfix_timelabel,  &
       atmos_phy_cp_restart_output,                &
       atmos_phy_cp_restart_out_basename,          &
       atmos_phy_cp_restart_out_aggregate,         &
       atmos_phy_cp_restart_out_postfix_timelabel, &
       atmos_phy_cp_restart_out_title,             &
       atmos_phy_cp_restart_out_dtype

    integer :: ierr
    integer :: iv
    integer :: iq
    !---------------------------------------------------------------------------

    log_newline
    log_info("ATMOS_PHY_CP_vars_setup",*) 'Setup'

    allocate( atmos_phy_cp_dens_t(ka,ia,ja)       )
    allocate( atmos_phy_cp_momz_t(ka,ia,ja)       )
    allocate( atmos_phy_cp_rhot_t(ka,ia,ja)       )
    allocate( atmos_phy_cp_rhoqv_t(ka,ia,ja)       )
    allocate( atmos_phy_cp_rhohyd_t(ka,ia,ja,n_hyd) )
    atmos_phy_cp_dens_t(:,:,:)   = 0.0_rp
    atmos_phy_cp_momz_t(:,:,:)   = undef
    atmos_phy_cp_rhot_t(:,:,:)   = 0.0_rp
    atmos_phy_cp_rhoqv_t(:,:,:)   = 0.0_rp
    atmos_phy_cp_rhohyd_t(:,:,:,:) = 0.0_rp

    allocate( atmos_phy_cp_mflx_cloudbase(ia,ja)    )
    allocate( atmos_phy_cp_sflx_rain(ia,ja)    )
    allocate( atmos_phy_cp_cloudtop(ia,ja)    )
    allocate( atmos_phy_cp_cloudbase(ia,ja)    )
    allocate( atmos_phy_cp_cldfrac_dp(ka,ia,ja) )
    allocate( atmos_phy_cp_cldfrac_sh(ka,ia,ja) )
    allocate( atmos_phy_cp_w0mean(ka,ia,ja) )
    allocate( atmos_phy_cp_kf_nca(ia,ja)    )
    atmos_phy_cp_mflx_cloudbase(:,:)   =    0.0_rp
    atmos_phy_cp_sflx_rain(:,:)   =    0.0_rp
    atmos_phy_cp_cloudtop(:,:)   =    0.0_rp
    atmos_phy_cp_cloudbase(:,:)   =    0.0_rp
    atmos_phy_cp_cldfrac_dp(:,:,:) =    0.0_rp
    atmos_phy_cp_cldfrac_sh(:,:,:) =    0.0_rp
    atmos_phy_cp_w0mean(:,:,:) =    0.0_rp
    atmos_phy_cp_kf_nca(:,:)   = -100.0_rp

    ! for tendency restart
    vmax_t = 3 + n_hyd
    allocate( var_t_name(vmax_t) )
    allocate( var_t_desc(vmax_t) )
    allocate( var_t_unit(vmax_t) )
    allocate( var_t_id(vmax_t) )

    var_t_name(i_cp_dens_t) = 'DENS_t_CP'
    var_t_desc(i_cp_dens_t) = 'tendency DENS in CP'
    var_t_unit(i_cp_dens_t) = 'kg/m3/s'
    var_t_name(i_cp_rhot_t) = 'RHOT_t_CP'
    var_t_desc(i_cp_rhot_t) = 'tendency RHOT in CP'
    var_t_unit(i_cp_rhot_t) = 'K*kg/m3/s'

    var_t_name(i_cp_qv_t) = 'QV_t_CP'
    var_t_desc(i_cp_qv_t) = 'tendency rho*QV in CP'
    var_t_unit(i_cp_qv_t) = 'kg/m3/s'
    do iq = 1, n_hyd
       var_t_name(3+iq) = trim(hyd_name(iq))//'_t_CP'
       var_t_desc(3+iq) = 'tendency rho*'//trim(hyd_name(iq))//' in CP'
       var_t_unit(3+iq) = 'kg/m3/s'
    enddo

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_cp_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("ATMOS_PHY_CP_vars_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("ATMOS_PHY_CP_vars_setup",*) 'Not appropriate names in namelist PARAM_ATMOS_PHY_CP_VARS. Check!'
       call prc_abort
    endif
    log_nml(param_atmos_phy_cp_vars)

    log_newline
    log_info("ATMOS_PHY_CP_vars_setup",*) '[ATMOS_PHY_CP] prognostic/diagnostic variables'
    log_info_cont('(1x,A,A24,A,A48,A,A12,A)') &
               '      |', 'VARNAME                 ','|', &
               'DESCRIPTION                                     ', '[', 'UNIT        ', ']'
    do iv = 1, vmax
       log_info_cont('(1x,A,I3,A,A24,A,A48,A,A12,A)') &
                  'NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
    enddo

    ! tendency
    do iv = 1, vmax_t
       log_info_cont('(1x,A,I3,A,A24,A,A48,A,A12,A)') &
                  'NO.',iv+vmax,'|',var_t_name(iv),'|',var_t_desc(iv),'[',var_t_unit(iv),']'
    enddo

    log_newline
    if ( atmos_phy_cp_restart_in_basename /= '' ) then
       log_info("ATMOS_PHY_CP_vars_setup",*) 'Restart input?  : YES, file = ', trim(atmos_phy_cp_restart_in_basename)
       log_info("ATMOS_PHY_CP_vars_setup",*) 'Add timelabel?  : ', atmos_phy_cp_restart_in_postfix_timelabel
    else
       log_info("ATMOS_PHY_CP_vars_setup",*) 'Restart input?  : NO'
    endif
    if (       atmos_phy_cp_restart_output             &
         .AND. atmos_phy_cp_restart_out_basename /= '' ) then
       log_info("ATMOS_PHY_CP_vars_setup",*) 'Restart output? : YES, file = ', trim(atmos_phy_cp_restart_out_basename)
       log_info("ATMOS_PHY_CP_vars_setup",*) 'Add timelabel?  : ', atmos_phy_cp_restart_out_postfix_timelabel
    else
       log_info("ATMOS_PHY_CP_vars_setup",*) 'Restart output? : NO'
       atmos_phy_cp_restart_output = .false.
    endif

    return
  end subroutine atmos_phy_cp_vars_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_fillhalo
    use scale_comm_cartesc, only: &
       comm_vars8, &
       comm_wait
    use scale_atmos_hydrometeor, only: &
       n_hyd
    implicit none

    integer :: i, j
    integer :: iq
    !---------------------------------------------------------------------------

    do j = js, je
    do i = is, ie
       atmos_phy_cp_cldfrac_dp(   1:ks-1,i,j) = atmos_phy_cp_cldfrac_dp(ks,i,j)
       atmos_phy_cp_cldfrac_dp(ke+1:ka,  i,j) = atmos_phy_cp_cldfrac_dp(ke,i,j)
       atmos_phy_cp_cldfrac_sh(   1:ks-1,i,j) = atmos_phy_cp_cldfrac_sh(ks,i,j)
       atmos_phy_cp_cldfrac_sh(ke+1:ka,  i,j) = atmos_phy_cp_cldfrac_sh(ke,i,j)
       atmos_phy_cp_w0mean(   1:ks-1,i,j) = atmos_phy_cp_w0mean(ks,i,j)
       atmos_phy_cp_w0mean(ke+1:ka,  i,j) = atmos_phy_cp_w0mean(ke,i,j)
       atmos_phy_cp_dens_t(   1:ks-1,i,j) = atmos_phy_cp_dens_t(ks,i,j)
       atmos_phy_cp_dens_t(ke+1:ka  ,i,j) = atmos_phy_cp_dens_t(ke,i,j)
       atmos_phy_cp_rhot_t(   1:ks-1,i,j) = atmos_phy_cp_rhot_t(ks,i,j)
       atmos_phy_cp_rhot_t(ke+1:ka  ,i,j) = atmos_phy_cp_rhot_t(ke,i,j)
       atmos_phy_cp_rhoqv_t(   1:ks-1,i,j) = atmos_phy_cp_rhoqv_t(ks,i,j)
       atmos_phy_cp_rhoqv_t(ke+1:ka  ,i,j) = atmos_phy_cp_rhoqv_t(ke,i,j)
    enddo
    enddo

    do iq = 1, n_hyd
       do j = js, je
       do i = is, ie
          atmos_phy_cp_rhohyd_t(   1:ks-1,i,j,iq) = atmos_phy_cp_rhohyd_t(ks,i,j,iq)
          atmos_phy_cp_rhohyd_t(ke+1:ka  ,i,j,iq) = atmos_phy_cp_rhohyd_t(ke,i,j,iq)
       enddo
       enddo
    end do

    call comm_vars8( atmos_phy_cp_mflx_cloudbase(:,:)  , 1 )
    call comm_vars8( atmos_phy_cp_sflx_rain(:,:)  , 2 )
    call comm_vars8( atmos_phy_cp_cloudtop(:,:)  , 3 )
    call comm_vars8( atmos_phy_cp_cloudbase(:,:)  , 4 )
    call comm_vars8( atmos_phy_cp_cldfrac_dp(:,:,:), 5 )
    call comm_vars8( atmos_phy_cp_cldfrac_sh(:,:,:), 6 )
    call comm_vars8( atmos_phy_cp_w0mean(:,:,:), 7 )
    call comm_vars8( atmos_phy_cp_kf_nca(:,:)  , 8 )

    ! tendency
    call comm_vars8( atmos_phy_cp_dens_t(:,:,:), vmax+1 )
    call comm_vars8( atmos_phy_cp_rhot_t(:,:,:), vmax+2 )
    call comm_vars8( atmos_phy_cp_rhoqv_t(:,:,:), vmax+3 )
    do iq = 1, n_hyd
       call comm_vars8( atmos_phy_cp_rhohyd_t(:,:,:,iq), vmax+3+iq )
    enddo

    call comm_wait ( atmos_phy_cp_mflx_cloudbase(:,:)  , 1 )
    call comm_wait ( atmos_phy_cp_sflx_rain(:,:)  , 2 )
    call comm_wait ( atmos_phy_cp_cloudtop(:,:)  , 3 )
    call comm_wait ( atmos_phy_cp_cloudbase(:,:)  , 4 )
    call comm_wait ( atmos_phy_cp_cldfrac_dp(:,:,:), 5 )
    call comm_wait ( atmos_phy_cp_cldfrac_sh(:,:,:), 6 )
    call comm_wait ( atmos_phy_cp_w0mean(:,:,:), 7 )
    call comm_wait ( atmos_phy_cp_kf_nca(:,:)  , 8 )


    call comm_wait ( atmos_phy_cp_dens_t(:,:,:), vmax+1 )
    call comm_wait ( atmos_phy_cp_rhot_t(:,:,:), vmax+2 )
    call comm_wait ( atmos_phy_cp_rhoqv_t(:,:,:), vmax+3 )
    do iq = 1, n_hyd
       call comm_wait ( atmos_phy_cp_rhohyd_t(:,:,:,iq), vmax+3+iq )
    enddo

    return
  end subroutine atmos_phy_cp_vars_fillhalo

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_open
    use scale_time, only: &
       time_gettimelabel
    use scale_file_cartesc, only: &
       file_cartesc_open
    implicit none

    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    log_newline
    log_info("ATMOS_PHY_CP_vars_restart_open",*) 'Open restart file (ATMOS_PHY_CP) '

    if ( atmos_phy_cp_restart_in_basename /= '' ) then

       if ( atmos_phy_cp_restart_in_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_cp_restart_in_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_cp_restart_in_basename)
       endif

       log_info("ATMOS_PHY_CP_vars_restart_open",*) 'basename: ', trim(basename)

       call file_cartesc_open( basename, restart_fid, aggregate=atmos_phy_cp_restart_in_aggregate )
    else
       log_info("ATMOS_PHY_CP_vars_restart_open",*) 'restart file for ATMOS_PHY_CP is not specified.'
    endif

    return
  end subroutine atmos_phy_cp_vars_restart_open

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_read
    use scale_file, only: &
       file_get_aggregate
    use scale_file_cartesc, only: &
       file_cartesc_read, &
       file_cartesc_flush
    use scale_atmos_hydrometeor, only: &
       n_hyd
    implicit none

    integer  :: i, j, iq
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       log_newline
       log_info("ATMOS_PHY_CP_vars_restart_read",*) 'Read from restart file (ATMOS_PHY_CP) '

       call file_cartesc_read( restart_fid, var_name(1), 'XY',  & ! [IN]
                               atmos_phy_cp_mflx_cloudbase(:,:) ) ! [OUT]
       call file_cartesc_read( restart_fid, var_name(2), 'XY',  & ! [IN]
                               atmos_phy_cp_sflx_rain(:,:)      ) ! [OUT]
       call file_cartesc_read( restart_fid, var_name(3), 'XY',  & ! [IN]
                               atmos_phy_cp_cloudtop(:,:)       ) ! [OUT]
       call file_cartesc_read( restart_fid, var_name(4), 'XY',  & ! [IN]
                               atmos_phy_cp_cloudbase(:,:)      ) ! [OUT]
       call file_cartesc_read( restart_fid, var_name(5), 'ZXY', & ! [IN]
                               atmos_phy_cp_cldfrac_dp(:,:,:)   ) ! [OUT]
       call file_cartesc_read( restart_fid, var_name(6), 'ZXY', & ! [IN]
                               atmos_phy_cp_cldfrac_sh(:,:,:)   ) ! [OUT]
       call file_cartesc_read( restart_fid, var_name(7), 'ZXY', & ! [IN]
                               atmos_phy_cp_w0mean(:,:,:)       ) ! [OUT]
       call file_cartesc_read( restart_fid, var_name(8), 'XY',  & ! [IN]
                               atmos_phy_cp_kf_nca(:,:)         ) ! [OUT]
       ! tendency
       call file_cartesc_read( restart_fid, var_t_name(1), 'ZXY', & ! [IN]
                               atmos_phy_cp_dens_t(:,:,:)         ) ! [OUT]
       call file_cartesc_read( restart_fid, var_t_name(2), 'ZXY', & ! [IN]
                               atmos_phy_cp_rhot_t(:,:,:)         ) ! [OUT]
       call file_cartesc_read( restart_fid, var_t_name(3), 'ZXY', & ! [IN]
                               atmos_phy_cp_rhoqv_t(:,:,:)        ) ! [OUT]
       do iq = 1, n_hyd
          call file_cartesc_read( restart_fid, var_t_name(3+iq), 'ZXY', & ! [IN]
                                  atmos_phy_cp_rhohyd_t(:,:,:,iq)       ) ! [OUT]
       enddo

       if ( file_get_aggregate(restart_fid) ) then
          call file_cartesc_flush( restart_fid ) ! X/Y halos have been read from file

          ! fill K halos
          do j  = 1, ja
          do i  = 1, ia
             atmos_phy_cp_cldfrac_dp(   1:ks-1,i,j) = atmos_phy_cp_cldfrac_dp(ks,i,j)
             atmos_phy_cp_cldfrac_sh(   1:ks-1,i,j) = atmos_phy_cp_cldfrac_sh(ks,i,j)
             atmos_phy_cp_w0mean(   1:ks-1,i,j) = atmos_phy_cp_w0mean(ks,i,j)
             atmos_phy_cp_dens_t(   1:ks-1,i,j) = atmos_phy_cp_dens_t(ks,i,j)
             atmos_phy_cp_rhot_t(   1:ks-1,i,j) = atmos_phy_cp_rhot_t(ks,i,j)
             atmos_phy_cp_cldfrac_dp(ke+1:ka,  i,j) = atmos_phy_cp_cldfrac_dp(ke,i,j)
             atmos_phy_cp_cldfrac_sh(ke+1:ka,  i,j) = atmos_phy_cp_cldfrac_sh(ke,i,j)
             atmos_phy_cp_w0mean(ke+1:ka,  i,j) = atmos_phy_cp_w0mean(ke,i,j)
             atmos_phy_cp_dens_t(ke+1:ka,  i,j) = atmos_phy_cp_dens_t(ke,i,j)
             atmos_phy_cp_rhot_t(ke+1:ka,  i,j) = atmos_phy_cp_rhot_t(ke,i,j)
             atmos_phy_cp_rhoqv_t(   1:ks-1,i,j) = atmos_phy_cp_rhoqv_t(ks,i,j)
             atmos_phy_cp_rhoqv_t(ke+1:ka,  i,j) = atmos_phy_cp_rhoqv_t(ke,i,j)
          enddo
          enddo

          do iq = 1, n_hyd
             do j  = 1, ja
             do i  = 1, ia
                atmos_phy_cp_rhohyd_t(   1:ks-1,i,j,iq) = atmos_phy_cp_rhohyd_t(ks,i,j,iq)
                atmos_phy_cp_rhohyd_t(ke+1:ka,  i,j,iq) = atmos_phy_cp_rhohyd_t(ke,i,j,iq)
             enddo
             enddo
          enddo
       else
          call atmos_phy_cp_vars_fillhalo
       end if

       call atmos_phy_cp_vars_checktotal

    else
       log_info("ATMOS_PHY_CP_vars_restart_read",*) 'invalid restart file ID for ATMOS_PHY_CP.'
    endif

    return
  end subroutine atmos_phy_cp_vars_restart_read

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_create
    use scale_time, only: &
       time_gettimelabel
    use scale_file_cartesc, only: &
       file_cartesc_create
    implicit none

    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    if ( atmos_phy_cp_restart_out_basename /= '' ) then

       log_newline
       log_info("ATMOS_PHY_CP_vars_restart_create",*) 'Create restart file (ATMOS_PHY_AE) '

       if ( atmos_phy_cp_restart_out_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_cp_restart_out_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_cp_restart_out_basename)
       endif

       log_info("ATMOS_PHY_CP_vars_restart_create",*) 'basename: ', trim(basename)

       call file_cartesc_create( &
            basename, atmos_phy_cp_restart_out_title, atmos_phy_cp_restart_out_dtype, & ! [IN]
            restart_fid,                                                              & ! [OUT]
            aggregate=atmos_phy_cp_restart_out_aggregate                              ) ! [IN]

    endif

    return
  end subroutine atmos_phy_cp_vars_restart_create

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_enddef
    use scale_file_cartesc, only: &
       file_cartesc_enddef
    implicit none

    if ( restart_fid /= -1 ) then
       call file_cartesc_enddef( restart_fid ) ! [IN]
    endif

    return
  end subroutine atmos_phy_cp_vars_restart_enddef

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_close
    use scale_file_cartesc, only: &
       file_cartesc_close
    implicit none
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       log_newline
       log_info("ATMOS_PHY_CP_vars_restart_close",*) 'Close restart file (ATMOS_PHY_CP) '

       call file_cartesc_close( restart_fid ) ! [IN]

       restart_fid = -1
    endif

    return
  end subroutine atmos_phy_cp_vars_restart_close

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_def_var
    use scale_file_cartesc, only: &
       file_cartesc_def_var
    use scale_atmos_hydrometeor, only: &
       n_hyd
    implicit none

    integer :: i, iq
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then

       do i = 1, 8
          call file_cartesc_def_var( restart_fid,          & ! [IN]
               var_name(i), var_desc(i), var_unit(i),      & ! [IN]
               var_dim(i), atmos_phy_cp_restart_out_dtype, & ! [IN]
               var_id(i)                                   ) ! [OUT]
       end do

       do i = 1, 3
          call file_cartesc_def_var( restart_fid,           & ! [IN]
               var_t_name(i), var_t_desc(i), var_t_unit(i), & ! [IN]
               'ZXY',  atmos_phy_cp_restart_out_dtype,       & ! [IN]
               var_t_id(i)                                  ) ! [OUT]
       end do

       do iq = 1, n_hyd
          call file_cartesc_def_var( restart_fid,                    & ! [IN]
               var_t_name(3+iq), var_t_desc(3+iq), var_t_unit(3+iq), & ! [IN]
               'ZXY',  atmos_phy_cp_restart_out_dtype,               & ! [IN]
               var_t_id(3+iq)                                        ) ! [OUT]
       enddo

    endif

    return
  end subroutine atmos_phy_cp_vars_restart_def_var

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_write
    use scale_file_cartesc, only: &
       file_cartesc_write => file_cartesc_write_var
    use scale_atmos_hydrometeor, only: &
       n_hyd
    implicit none

    integer  :: iq
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then

       call atmos_phy_cp_vars_fillhalo

       call atmos_phy_cp_vars_checktotal

       call file_cartesc_write( restart_fid, var_id(1), atmos_phy_cp_mflx_cloudbase(:,:), & ! [IN]
                          var_name(1), 'XY' ) ! [IN]
       call file_cartesc_write( restart_fid, var_id(2), atmos_phy_cp_sflx_rain(:,:), & ! [IN]
                          var_name(2), 'XY' ) ! [IN]
       call file_cartesc_write( restart_fid, var_id(3), atmos_phy_cp_cloudtop(:,:), & ! [IN]
                          var_name(3), 'XY' ) ! [IN]
       call file_cartesc_write( restart_fid, var_id(4), atmos_phy_cp_cloudbase(:,:), & ! [IN]
                          var_name(4), 'XY' ) ! [IN]
       call file_cartesc_write( restart_fid, var_id(5), atmos_phy_cp_cldfrac_dp(:,:,:), & ! [IN]
                          var_name(5), 'ZXY' ) ! [IN]
       call file_cartesc_write( restart_fid, var_id(6), atmos_phy_cp_cldfrac_sh(:,:,:), & ! [IN]
                          var_name(6), 'ZXY' ) ! [IN]
       call file_cartesc_write( restart_fid, var_id(7), atmos_phy_cp_w0mean(:,:,:), & ! [IN]
                          var_name(7), 'ZXY' ) ! [IN]
       call file_cartesc_write( restart_fid, var_id(8), atmos_phy_cp_kf_nca(:,:), & ! [IN]
                          var_name(8), 'XY' ) ! [IN]

       ! tendency
       call file_cartesc_write( restart_fid, var_t_id(1), atmos_phy_cp_dens_t(:,:,:), & ! [IN]
                          var_t_name(1), 'ZXY' ) ! [IN]
       call file_cartesc_write( restart_fid, var_t_id(2), atmos_phy_cp_rhot_t(:,:,:), & ! [IN]
                          var_t_name(2), 'ZXY' ) ! [IN]
       call file_cartesc_write( restart_fid, var_t_id(3), atmos_phy_cp_rhoqv_t(:,:,:), & ! [IN]
                          var_t_name(3), 'ZXY' ) ! [IN]
       do iq = 1, n_hyd
          call file_cartesc_write( restart_fid, var_t_id(3+iq), atmos_phy_cp_rhohyd_t(:,:,:,iq), & ! [IN]
                             var_t_name(3+iq), 'ZXY' ) ! [IN]
       enddo

    endif

    return
  end subroutine atmos_phy_cp_vars_restart_write

  subroutine atmos_phy_cp_vars_checktotal
    use scale_statistics, only: &
       statistics_checktotal, &
       statistics_total
    use scale_atmos_grid_cartesc_real, only: &
       atmos_grid_cartesc_real_area,    &
       atmos_grid_cartesc_real_totarea, &
       atmos_grid_cartesc_real_vol,     &
       atmos_grid_cartesc_real_totvol
    use scale_atmos_hydrometeor, only: &
       n_hyd

    integer :: iq

    !---------------------------------------------------------------------------

    if ( statistics_checktotal ) then
       call statistics_total( ia, is, ie, ja, js, je, &
                              atmos_phy_cp_mflx_cloudbase(:,:)  , var_name(1), & ! (in)
                              atmos_grid_cartesc_real_area(:,:),               & ! (in)
                              atmos_grid_cartesc_real_totarea                  ) ! (in)
       call statistics_total( ia, is, ie, ja, js, je, &
                              atmos_phy_cp_sflx_rain(:,:)  , var_name(2), & ! (in)
                              atmos_grid_cartesc_real_area(:,:),               & ! (in)
                              atmos_grid_cartesc_real_totarea                  ) ! (in)
       call statistics_total( ia, is, ie, ja, js, je, &
                              atmos_phy_cp_cloudtop(:,:)  , var_name(3), & ! (in)
                              atmos_grid_cartesc_real_area(:,:),               & ! (in)
                              atmos_grid_cartesc_real_totarea                  ) ! (in)
       call statistics_total( ia, is, ie, ja, js, je, &
                              atmos_phy_cp_cloudbase(:,:)  , var_name(4), & ! (in)
                              atmos_grid_cartesc_real_area(:,:),               & ! (in)
                              atmos_grid_cartesc_real_totarea                  ) ! (in)
       call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                              atmos_phy_cp_cldfrac_dp(:,:,:), var_name(5), &
                              atmos_grid_cartesc_real_vol(:,:,:),              & ! (in)
                              atmos_grid_cartesc_real_totvol                   ) ! (in)
       call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                              atmos_phy_cp_cldfrac_sh(:,:,:), var_name(6), & ! (in)
                              atmos_grid_cartesc_real_vol(:,:,:),              & ! (in)
                              atmos_grid_cartesc_real_totvol                   ) ! (in)
       call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                              atmos_phy_cp_w0mean(:,:,:), var_name(7), & ! (in)
                              atmos_grid_cartesc_real_vol(:,:,:),              & ! (in)
                              atmos_grid_cartesc_real_totvol                   ) ! (in)
       call statistics_total( ia, is, ie, ja, js, je, &
                              atmos_phy_cp_kf_nca(:,:)  , var_name(8), & ! (in)
                              atmos_grid_cartesc_real_area(:,:),               & ! (in)
                              atmos_grid_cartesc_real_totarea                  ) ! (in)
       ! tendency
       call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                              atmos_phy_cp_dens_t(:,:,:), var_t_name(1), & ! (in)
                              atmos_grid_cartesc_real_vol(:,:,:),                & ! (in)
                              atmos_grid_cartesc_real_totvol                     ) ! (in)
       call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                              atmos_phy_cp_rhot_t(:,:,:), var_t_name(2), & ! (in)
                              atmos_grid_cartesc_real_vol(:,:,:),                & ! (in)
                              atmos_grid_cartesc_real_totvol                     ) ! (in)
       call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                              atmos_phy_cp_rhoqv_t(:,:,:), var_t_name(3), & ! (in)
                              atmos_grid_cartesc_real_vol(:,:,:),                & ! (in)
                              atmos_grid_cartesc_real_totvol                     ) ! (in)
       do iq = 1, n_hyd
          call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                                 atmos_phy_cp_rhohyd_t(:,:,:,iq), var_t_name(3+iq), & ! (in)
                                 atmos_grid_cartesc_real_vol(:,:,:),                & ! (in)
                                 atmos_grid_cartesc_real_totvol                     ) ! (in)
       enddo
    endif

    return
  end subroutine atmos_phy_cp_vars_checktotal

end module mod_atmos_phy_cp_vars