scale_tracer.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_tracer
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: tracer_regist

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  integer, public :: qa = 0

  integer, private, parameter :: qa_max = 1024

  real(RP),               public :: tracer_cp  (qa_max)
  real(RP),               public :: tracer_cv  (qa_max)
  real(RP),               public :: tracer_r   (qa_max)
  real(RP),               public :: tracer_mass(qa_max)
  logical,                public :: tracer_advc(qa_max)
  character(len=H_SHORT), public :: tracer_name(qa_max)
  character(len=H_MID),   public :: tracer_desc(qa_max)
  character(len=H_SHORT), public :: tracer_unit(qa_max)

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine tracer_regist(  &
       QS,                   &
       NQ, NAME, DESC, UNIT, &
       CV, CP, R, ADVC, MASS )
    use scale_prc, only: &
      prc_abort
    implicit none

    integer,          intent(out)          :: QS
    integer,          intent(in)           :: NQ
    character(len=*), intent(in)           :: NAME(nq)
    character(len=*), intent(in)           :: DESC(nq)
    character(len=*), intent(in)           :: UNIT(nq)
    real(RP),         intent(in), optional :: CV  (nq)
    real(RP),         intent(in), optional :: CP  (nq)
    real(RP),         intent(in), optional :: R   (nq)
    logical,          intent(in), optional :: ADVC(nq)
    logical,          intent(in), optional :: MASS(nq)

    real(RP) :: CV_  (nq)
    real(RP) :: CP_  (nq)
    real(RP) :: R_   (nq)
    logical  :: ADVC_(nq)
    logical  :: MASS_(nq)

    character(len=24) :: NAME_trim

    integer  :: n
    !---------------------------------------------------------------------------

    if ( qa + nq > qa_max ) then
       log_error("TRACER_regist",*) 'total number of tracer must be less or equal to ', qa_max
       call prc_abort
    end if

    if ( present(cv) ) then
       cv_(:) = cv(:)
    else
       cv_(:) = 0.0_rp
    end if

    if ( present(cp) ) then
       cp_(:) = cp(:)
    else
       cp_(:) = 0.0_rp
    end if

    if ( present(r) ) then
       r_(:) = r(:)
    else
       r_(:) = 0.0_rp
    end if

    if ( present(advc) ) then
       advc_(:) = advc(:)
    else
       advc_(:) = .true.
    end if

    if ( present(mass) ) then
       mass_(:) = mass(:)
    else
       mass_(:) = .false.
    end if

    log_newline
    do n = 1, nq

       name_trim = trim(name(n))

       log_info("TRACER_regist",'(1x,A,I3,A,A,A,F6.1,A,F6.1,A,L1,A,L1)') &
                                      '] Register tracer : No.', qa+n,      &
                                                    ', NAME = ', name_trim, &
                                                      ', CV = ', cv_(n),  &
                                                      ', CP = ', cp_(n),  &
                                                    ', ADVC = ', advc_(n),  &
                                                    ', MASS = ', mass_(n)

       tracer_name(qa+n) = name(n)
       tracer_desc(qa+n) = desc(n)
       tracer_unit(qa+n) = unit(n)
       tracer_cv(qa+n) = cv_(n)
       tracer_cp(qa+n) = cp_(n)
       tracer_r(qa+n) = r_(n)
       tracer_advc(qa+n) = advc_(n)

       if ( mass_(n) ) then
          tracer_mass(qa+n) = 1.0_rp
       else
          tracer_mass(qa+n) = 0.0_rp
       end if
    end do

    qs = qa + 1
    qa = qa + nq

    return
  end subroutine tracer_regist

end module scale_tracer