scale_ocean_sfc.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
module scale_ocean_sfc
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_grid_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: ocean_sfc_setup

  abstract interface
     subroutine ocnsfc( &
           SST_t,  &
           ZMFLX,  &
           XMFLX,  &
           YMFLX,  &
           SHFLX,  &
           LHFLX,  &
           WHFLX,  &
           U10,    &
           V10,    &
           T2,     &
           Q2,     &
           TMPA,   &
           PRSA,   &
           WA,     &
           UA,     &
           VA,     &
           RHOA,   &
           QVA,    &
           Z1,     &
           PBL,    &
           PRSS,   &
           LWD,    &
           SWD,    &
           TW,     &
           SST,    &
           ALB_LW, &
           ALB_SW, &
           Z0M,    &
           Z0H,    &
           Z0E,    &
           dt      )
       use scale_precision
       use scale_grid_index
       implicit none

       real(RP), intent(out) :: SST_t(IA,JA) ! tendency of sea surface temperature
       real(RP), intent(out) :: ZMFLX(IA,JA) ! z-momentum flux at the surface [kg/m/s2]
       real(RP), intent(out) :: XMFLX(IA,JA) ! x-momentum flux at the surface [kg/m/s2]
       real(RP), intent(out) :: YMFLX(IA,JA) ! y-momentum flux at the surface [kg/m/s2]
       real(RP), intent(out) :: SHFLX(IA,JA) ! sensible heat flux at the surface [W/m2]
       real(RP), intent(out) :: LHFLX(IA,JA) ! latent heat flux at the surface [W/m2]
       real(RP), intent(out) :: WHFLX(IA,JA) ! water heat flux at the surface [W/m2]
       real(RP), intent(out) :: U10  (IA,JA) ! velocity u at 10m [m/s]
       real(RP), intent(out) :: V10  (IA,JA) ! velocity v at 10m [m/s]
       real(RP), intent(out) :: T2   (IA,JA) ! temperature at 2m [K]
       real(RP), intent(out) :: Q2   (IA,JA) ! water vapor at 2m [kg/kg]

       real(RP), intent(in) :: TMPA(IA,JA) ! temperature at the lowest atmospheric layer [K]
       real(RP), intent(in) :: PRSA(IA,JA) ! pressure at the lowest atmospheric layer [Pa]
       real(RP), intent(in) :: WA  (IA,JA) ! velocity w at the lowest atmospheric layer [m/s]
       real(RP), intent(in) :: UA  (IA,JA) ! velocity u at the lowest atmospheric layer [m/s]
       real(RP), intent(in) :: VA  (IA,JA) ! velocity v at the lowest atmospheric layer [m/s]
       real(RP), intent(in) :: RHOA(IA,JA) ! density at the lowest atmospheric layer [kg/m3]
       real(RP), intent(in) :: QVA (IA,JA) ! ratio of water vapor mass to total mass at the lowest atmospheric layer [kg/kg]
       real(RP), intent(in) :: Z1  (IA,JA) ! cell center height at the lowest atmospheric layer [m]
       real(RP), intent(in) :: PBL (IA,JA) ! the top of atmospheric mixing layer [m]
       real(RP), intent(in) :: PRSS(IA,JA) ! pressure at the surface [Pa]
       real(RP), intent(in) :: LWD (IA,JA) ! downward long-wave radiation flux at the surface (upward positive) [W/m2]
       real(RP), intent(in) :: SWD (IA,JA) ! downward short-wave radiation flux at the surface (upward positive) [W/m2]

       real(RP), intent(in) :: TW    (IA,JA) ! water temperature [K]
       real(RP), intent(in) :: SST   (IA,JA) ! sea surface temperature [K]
       real(RP), intent(in) :: ALB_LW(IA,JA) ! surface albedo for LW (0-1)
       real(RP), intent(in) :: ALB_SW(IA,JA) ! surface albedo for SW (0-1)
       real(RP), intent(in) :: Z0M   (IA,JA) ! roughness length for momentum [m]
       real(RP), intent(in) :: Z0H   (IA,JA) ! roughness length for heat [m]
       real(RP), intent(in) :: Z0E   (IA,JA) ! roughness length for vapor [m]
       real(DP), intent(in) :: dt            ! delta time
     end subroutine ocnsfc
  end interface

  procedure(ocnsfc), pointer :: ocean_sfc => null()

  public :: ocean_sfc
  public :: ocean_sfc_simplealbedo

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains

  subroutine ocean_sfc_setup( OCEAN_TYPE )
    use scale_process, only: &
       prc_mpistop
    use scale_ocean_sfc_const, only: &
       ocean_sfc_const_setup, &
       ocean_sfc_const
    use scale_ocean_sfc_slab, only: &
       ocean_sfc_slab_setup, &
       ocean_sfc_slab
    implicit none

    character(len=*), intent(in) :: ocean_type
    !---------------------------------------------------------------------------

    select case( ocean_type )
    case( 'CONST' )
       call ocean_sfc_const_setup( ocean_type )
       ocean_sfc => ocean_sfc_const
    case( 'SLAB', 'FILE' )
       call ocean_sfc_slab_setup( ocean_type )
       ocean_sfc => ocean_sfc_slab
    end select

    return
  end subroutine ocean_sfc_setup

  !-----------------------------------------------------------------------------
  subroutine ocean_sfc_simplealbedo( &
       SFC_albedo_t, &
       SFC_albedo,   &
       cosSZA,       &
       dt            )
    use scale_grid_index
    use scale_const, only: &
       i_sw  => const_i_sw, &
       i_lw  => const_i_lw
    implicit none

    ! arguments
    real(RP), intent(out) :: sfc_albedo_t(ia,ja,2) ! tendency of sea surface albedo (0-1)
    real(RP), intent(in)  :: sfc_albedo  (ia,ja,2) ! sea surface                    (0-1)
    real(RP), intent(in)  :: cossza      (ia,ja)   ! cos(solar zenith angle)        (0-1)
    real(DP), intent(in)  :: dt                    ! delta time

    ! works
    real(RP) :: sfc_albedo1(ia,ja,2)
    real(RP) :: am1

    real(RP), parameter :: c_ocean_albedo(3) = (/ -0.747900_rp, &
                                                  -4.677039_rp, &
                                                   1.583171_rp  /)

    integer :: i, j
    !---------------------------------------------------------------------------

    do j = js, je
    do i = is, ie
       am1 = max( min( cossza(i,j), 0.961_rp ), 0.0349_rp )

       ! SFC_albedo1(i,j,I_LW) = 0.5_RP do nothing
       sfc_albedo1(i,j,i_sw) = exp( ( c_ocean_albedo(3)*am1 + c_ocean_albedo(2) )*am1 + c_ocean_albedo(1) )
    enddo
    enddo

    ! calculate tendency
    do j = js, je
    do i = is, ie
       sfc_albedo_t(i,j,i_lw) = 0.0_rp
       sfc_albedo_t(i,j,i_sw) = ( sfc_albedo1(i,j,i_sw) - sfc_albedo(i,j,i_sw) ) / dt
    enddo
    enddo

    return
  end subroutine ocean_sfc_simplealbedo

end module scale_ocean_sfc