mod_atmos_phy_mp_vars.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "inc_openmp.h"
module mod_atmos_phy_mp_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_mp_vars_setup
  public :: atmos_phy_mp_vars_fillhalo
  public :: atmos_phy_mp_vars_restart_read
  public :: atmos_phy_mp_vars_restart_write

  public :: atmos_phy_mp_vars_restart_create
  public :: atmos_phy_mp_vars_restart_open
  public :: atmos_phy_mp_vars_restart_def_var
  public :: atmos_phy_mp_vars_restart_enddef
  public :: atmos_phy_mp_vars_restart_close

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,               public :: atmos_phy_mp_restart_output                = .false.                

  character(len=H_LONG),  public :: atmos_phy_mp_restart_in_basename           = ''
  logical,                public :: atmos_phy_mp_restart_in_postfix_timelabel  = .false.                
  character(len=H_LONG),  public :: atmos_phy_mp_restart_out_basename          = ''
  logical,                public :: atmos_phy_mp_restart_out_postfix_timelabel = .true.                 
  character(len=H_MID),   public :: atmos_phy_mp_restart_out_title             = 'ATMOS_PHY_MP restart'
  character(len=H_SHORT), public :: atmos_phy_mp_restart_out_dtype             = 'DEFAULT'

  real(RP), public, allocatable :: atmos_phy_mp_dens_t(:,:,:)    ! tendency DENS [kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_mp_momz_t(:,:,:)    ! tendency MOMZ [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_mp_momx_t(:,:,:)    ! tendency MOMX [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_mp_momy_t(:,:,:)    ! tendency MOMY [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_mp_rhot_t(:,:,:)    ! tendency RHOT [K*kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_mp_rhoq_t(:,:,:,:)  ! tendency rho*QTRC [kg/kg/s]

  real(RP), public, allocatable :: atmos_phy_mp_evaporate(:,:,:) ! number concentration of evaporated cloud [/m3]
  real(RP), public, allocatable :: atmos_phy_mp_sflx_rain(:,:)   ! precipitation flux (liquid) [kg/m2/s]
  real(RP), public, allocatable :: atmos_phy_mp_sflx_snow(:,:)   ! precipitation flux (solid)  [kg/m2/s]

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,                private, parameter :: vmax = 2
  integer,                private, parameter :: i_sflx_rain = 1
  integer,                private, parameter :: i_sflx_snow = 2

  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)
  integer,                private            :: var_id(vmax)
  integer,                private            :: restart_fid = -1  ! file ID

  data var_name / 'SFLX_rain', &
                  'SFLX_snow'  /
  data var_desc / 'precipitation flux (liquid)', &
                  'precipitation flux (solid)'   /
  data var_unit / 'kg/m2/s', &
                  'kg/m2/s' /

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_setup
    use scale_process, only: &
       prc_mpistop
    use scale_const, only: &
       undef => const_undef
    use scale_atmos_phy_mp, only: &
       qs_mp, &
       qe_mp
    implicit none

    namelist / param_atmos_phy_mp_vars / &
       atmos_phy_mp_restart_in_basename,           &
       atmos_phy_mp_restart_in_postfix_timelabel,  &
       atmos_phy_mp_restart_output,                &
       atmos_phy_mp_restart_out_basename,          &
       atmos_phy_mp_restart_out_postfix_timelabel, &
       atmos_phy_mp_restart_out_title,             &
       atmos_phy_mp_restart_out_dtype

    integer :: ierr
    integer :: iv
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[VARS] / Categ[ATMOS PHY_MP] / Origin[SCALE-RM]'

    allocate( atmos_phy_mp_dens_t(ka,ia,ja)    )
    allocate( atmos_phy_mp_momz_t(ka,ia,ja)    )
    allocate( atmos_phy_mp_momx_t(ka,ia,ja)    )
    allocate( atmos_phy_mp_momy_t(ka,ia,ja)    )
    allocate( atmos_phy_mp_rhot_t(ka,ia,ja)    )
    allocate( atmos_phy_mp_rhoq_t(ka,ia,ja,qs_mp:qe_mp) )
    allocate( atmos_phy_mp_evaporate(ka,ia,ja)    )
    ! tentative approach
    atmos_phy_mp_dens_t(:,:,:)   = 0.0_rp
    atmos_phy_mp_momz_t(:,:,:)   = 0.0_rp
    atmos_phy_mp_momx_t(:,:,:)   = 0.0_rp
    atmos_phy_mp_momy_t(:,:,:)   = 0.0_rp
    atmos_phy_mp_rhot_t(:,:,:)   = 0.0_rp
    atmos_phy_mp_rhoq_t(:,:,:,:) = 0.0_rp
    atmos_phy_mp_evaporate(:,:,:) = 0.0_rp

    allocate( atmos_phy_mp_sflx_rain(ia,ja) )
    allocate( atmos_phy_mp_sflx_snow(ia,ja) )
    atmos_phy_mp_sflx_rain(:,:) = undef
    atmos_phy_mp_sflx_snow(:,:) = undef

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_mp_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       if( io_l ) write(io_fid_log,*) '*** Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       write(*,*) 'xxx Not appropriate names in namelist PARAM_ATMOS_PHY_MP_VARS. Check!'
       call prc_mpistop
    endif
    if( io_nml ) write(io_fid_nml,nml=param_atmos_phy_mp_vars)

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** [ATMOS_PHY_MP] prognostic/diagnostic variables'
    if( io_l ) write(io_fid_log,'(1x,A,A24,A,A48,A,A12,A)') &
               '***       |', 'VARNAME                 ','|', &
               'DESCRIPTION                                     ', '[', 'UNIT        ', ']'
    do iv = 1, vmax
       if( io_l ) write(io_fid_log,'(1x,A,I3,A,A24,A,A48,A,A12,A)') &
                  '*** NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
    enddo

    if( io_l ) write(io_fid_log,*)
    if ( atmos_phy_mp_restart_in_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** Restart input?  : YES, file = ', trim(atmos_phy_mp_restart_in_basename)
       if( io_l ) write(io_fid_log,*) '*** Add timelabel?  : ', atmos_phy_mp_restart_in_postfix_timelabel
    else
       if( io_l ) write(io_fid_log,*) '*** Restart input?  : NO'
    endif
    if (       atmos_phy_mp_restart_output             &
         .AND. atmos_phy_mp_restart_out_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** Restart output? : YES, file = ', trim(atmos_phy_mp_restart_out_basename)
       if( io_l ) write(io_fid_log,*) '*** Add timelabel?  : ', atmos_phy_mp_restart_out_postfix_timelabel
    else
       if( io_l ) write(io_fid_log,*) '*** Restart output? : NO'
       atmos_phy_mp_restart_output = .false.
    endif

    return
  end subroutine atmos_phy_mp_vars_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_fillhalo
    use scale_comm, only: &
       comm_vars8, &
       comm_wait
    implicit none
    !---------------------------------------------------------------------------

    call comm_vars8( atmos_phy_mp_sflx_rain(:,:), 1 )
    call comm_vars8( atmos_phy_mp_sflx_snow(:,:), 2 )
    call comm_wait ( atmos_phy_mp_sflx_rain(:,:), 1 )
    call comm_wait ( atmos_phy_mp_sflx_snow(:,:), 2 )

    return
  end subroutine atmos_phy_mp_vars_fillhalo

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_open
    use scale_time, only: &
       time_gettimelabel
    use scale_fileio, only: &
       fileio_open
    implicit none

    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Open restart file (ATMOS_PHY_MP) ***'

    if ( atmos_phy_mp_restart_in_basename /= '' ) then

       if ( atmos_phy_mp_restart_in_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_mp_restart_in_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_mp_restart_in_basename)
       endif

       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(basename)

       call fileio_open( restart_fid, basename )
    else
       if( io_l ) write(io_fid_log,*) '*** restart file for ATMOS_PHY_MP is not specified.'
    endif

    return
  end subroutine atmos_phy_mp_vars_restart_open

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_read
    use scale_rm_statistics, only: &
       statistics_checktotal, &
       stat_total
    use scale_fileio, only: &
       fileio_read, &
       fileio_flush
    implicit none

    real(RP) :: total
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Read from restart file (ATMOS_PHY_MP) ***'

       call fileio_read( atmos_phy_mp_sflx_rain(:,:),             & ! [OUT]
                         restart_fid, var_name(1), 'XY', step=1 ) ! [IN]
       call fileio_read( atmos_phy_mp_sflx_snow(:,:),             & ! [OUT]
                         restart_fid, var_name(2), 'XY', step=1 ) ! [IN]

       if ( io_aggregate ) then
          call fileio_flush( restart_fid ) ! X/Y halos have been read from file
       else
          call atmos_phy_mp_vars_fillhalo
       end if

       if ( statistics_checktotal ) then
          call stat_total( total, atmos_phy_mp_sflx_rain(:,:), var_name(1) )
          call stat_total( total, atmos_phy_mp_sflx_snow(:,:), var_name(2) )
       endif
    else
       if( io_l ) write(io_fid_log,*) '*** invalid restart file ID for ATMOS_PHY_MP.'
    endif

    return
  end subroutine atmos_phy_mp_vars_restart_read

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_create
    use scale_time, only: &
       time_gettimelabel
    use scale_fileio, only: &
       fileio_create
    implicit none

    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    if ( atmos_phy_mp_restart_out_basename /= '' ) then

       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Create restart file (ATMOS_PHY_AE) ***'

       if ( atmos_phy_mp_restart_out_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_mp_restart_out_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_mp_restart_out_basename)
       endif

       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(basename)

       call fileio_create( restart_fid,                                                             & ! [OUT]
                           basename, atmos_phy_mp_restart_out_title, atmos_phy_mp_restart_out_dtype ) ! [IN]

    endif

    return
  end subroutine atmos_phy_mp_vars_restart_create

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_enddef
    use scale_fileio, only: &
       fileio_enddef
    implicit none

    if ( restart_fid /= -1 ) then
       call fileio_enddef( restart_fid ) ! [IN]
    endif

    return
  end subroutine atmos_phy_mp_vars_restart_enddef

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_close
    use scale_fileio, only: &
       fileio_close
    implicit none
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Close restart file (ATMOS_PHY_MP) ***'

       call fileio_close( restart_fid ) ! [IN]

       restart_fid = -1
    endif

    return
  end subroutine atmos_phy_mp_vars_restart_close

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_def_var
    use scale_fileio, only: &
       fileio_def_var
    implicit none
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then

       call fileio_def_var( restart_fid, var_id(1), var_name(1), var_desc(1), &
                            var_unit(1), 'XY', atmos_phy_mp_restart_out_dtype  ) ! [IN]
       call fileio_def_var( restart_fid, var_id(2), var_name(2), var_desc(2), &
                            var_unit(2), 'XY', atmos_phy_mp_restart_out_dtype  ) ! [IN]

    endif

    return
  end subroutine atmos_phy_mp_vars_restart_def_var

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_mp_vars_restart_write
    use scale_rm_statistics, only: &
       statistics_checktotal, &
       stat_total
    use scale_fileio, only: &
       fileio_write_var
    implicit none

    real(RP) :: total
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then

       call atmos_phy_mp_vars_fillhalo

       if ( statistics_checktotal ) then
          call stat_total( total, atmos_phy_mp_sflx_rain(:,:), var_name(1) )
          call stat_total( total, atmos_phy_mp_sflx_snow(:,:), var_name(2) )
       endif

       call fileio_write_var( restart_fid, var_id(1), atmos_phy_mp_sflx_rain(:,:), &
                              var_name(1), 'XY' ) ! [IN]
       call fileio_write_var( restart_fid, var_id(2), atmos_phy_mp_sflx_snow(:,:), &
                              var_name(2), 'XY' ) ! [IN]

    endif

    return
  end subroutine atmos_phy_mp_vars_restart_write

end module mod_atmos_phy_mp_vars