mod_atmos_phy_cp_vars.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "inc_openmp.h"
module mod_atmos_phy_cp_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_cp_vars_setup
  public :: atmos_phy_cp_vars_fillhalo
  public :: atmos_phy_cp_vars_restart_read
  public :: atmos_phy_cp_vars_restart_write

  public :: atmos_phy_cp_vars_restart_create
  public :: atmos_phy_cp_vars_restart_open
  public :: atmos_phy_cp_vars_restart_def_var
  public :: atmos_phy_cp_vars_restart_enddef
  public :: atmos_phy_cp_vars_restart_close

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,               public :: atmos_phy_cp_restart_output                = .false.                

  character(len=H_LONG),  public :: atmos_phy_cp_restart_in_basename           = ''
  logical,                public :: atmos_phy_cp_restart_in_postfix_timelabel  = .false.                
  character(len=H_LONG),  public :: atmos_phy_cp_restart_out_basename          = ''
  logical,                public :: atmos_phy_cp_restart_out_postfix_timelabel = .true.                 
  character(len=H_MID),   public :: atmos_phy_cp_restart_out_title             = 'ATMOS_PHY_CP restart'
  character(len=H_SHORT), public :: atmos_phy_cp_restart_out_dtype             = 'DEFAULT'

  real(RP), public, allocatable :: atmos_phy_cp_dens_t(:,:,:)    ! tendency DENS [kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_cp_momz_t(:,:,:)    ! tendency MOMZ [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_cp_momx_t(:,:,:)    ! tendency MOMX [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_cp_momy_t(:,:,:)    ! tendency MOMY [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_cp_rhot_t(:,:,:)    ! tendency RHOT [K*kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_cp_rhoq_t(:,:,:,:)  ! tendency rho*QTRC [kg/kg/s]

  real(RP), public, allocatable :: atmos_phy_cp_mflx_cloudbase(:,:)   ! cloud base mass flux [kg/m2/s]
  real(RP), public, allocatable :: atmos_phy_cp_sflx_rain     (:,:)   ! convective rain [kg/m2/s]
  real(RP), public, allocatable :: atmos_phy_cp_cloudtop      (:,:)   ! cloud top  height [m]
  real(RP), public, allocatable :: atmos_phy_cp_cloudbase     (:,:)   ! cloud base height [m]
  real(RP), public, allocatable :: atmos_phy_cp_cldfrac_dp    (:,:,:) ! cloud fraction (deep    convection) (0-1)
  real(RP), public, allocatable :: atmos_phy_cp_cldfrac_sh    (:,:,:) ! cloud fraction (shallow convection) (0-1)
  ! only for K-F scheme
  real(RP), public, allocatable :: atmos_phy_cp_kf_nca        (:,:)   ! advection/cumulus convection timescale/dt for KF[step]
  real(RP), public, allocatable :: atmos_phy_cp_kf_w0avg      (:,:,:) ! running mean vertical wind velocity for KF[m/s]

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,                private, parameter :: vmax = 8
  integer,                private, parameter :: i_mflx_cloudbase = 1
  integer,                private, parameter :: i_sflx_convrain  = 2
  integer,                private, parameter :: i_cloudtop       = 3
  integer,                private, parameter :: i_cloudbase      = 4
  integer,                private, parameter :: i_cldfrac_dp     = 5
  integer,                private, parameter :: i_cldfrac_sh     = 6
  integer,                private, parameter :: i_kf_nca         = 7
  integer,                private, parameter :: i_kf_w0avg       = 8

  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)
  integer,                private            :: var_id  (vmax)
  integer,                private            :: restart_fid = -1  ! file ID

  data var_name / 'MFLX_cloudbase',  &
                  'SFLX_convrain',   &
                  'cloudtop',        &
                  'cloudbase',       &
                  'cldfrac_dp',      &
                  'cldfrac_sh',      &
                  'kf_nca',          &
                  'kf_w0avg'         /
  data var_desc / 'cloud base mass flux',                             &
                  'convective rain',                                  &
                  'cloud top height',                                 &
                  'cloud base height',                                &
                  'cloud fraction (deep convection)',                 &
                  'cloud fraction (shallow convection)',              &
                  'advection/cumulus convection timescale/dt for KF', &
                  'running mean vertical wind velocity for KF'        /
  data var_unit / 'kg/m2/s', &
                  'kg/m2/s', &
                  'm',       &
                  'm',       &
                  '1',       &
                  '1',       &
                  'step',    &
                  'm/s'      /

  ! tendency names
  integer,                private              :: vmax_t
  integer,                private              :: i_cp_dens_t = 1
  integer,                private              :: i_cp_rhot_t = 2

  character(len=H_SHORT), private, allocatable :: var_t_name(:)
  character(len=H_MID),   private, allocatable :: var_t_desc(:)
  character(len=H_SHORT), private, allocatable :: var_t_unit(:)
  integer,                private, allocatable :: var_t_id  (:)

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_setup
    use scale_process, only: &
       prc_mpistop
    use scale_const, only: &
       undef => const_undef
    use scale_atmos_phy_mp, only: &
       aq_name => atmos_phy_mp_name, &
       qs_mp,                        &
       qe_mp,                        &
       qa_mp
    implicit none

    namelist / param_atmos_phy_cp_vars / &
       atmos_phy_cp_restart_in_basename,           &
       atmos_phy_cp_restart_in_postfix_timelabel,  &
       atmos_phy_cp_restart_output,                &
       atmos_phy_cp_restart_out_basename,          &
       atmos_phy_cp_restart_out_postfix_timelabel, &
       atmos_phy_cp_restart_out_title,             &
       atmos_phy_cp_restart_out_dtype

    integer :: ierr
    integer :: iv
    integer :: iq
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[VARS] / Categ[ATMOS PHY_CP] / Origin[SCALE-RM]'

    allocate( atmos_phy_cp_dens_t(ka,ia,ja)       )
    allocate( atmos_phy_cp_momz_t(ka,ia,ja)       )
    allocate( atmos_phy_cp_momx_t(ka,ia,ja)       )
    allocate( atmos_phy_cp_momy_t(ka,ia,ja)       )
    allocate( atmos_phy_cp_rhot_t(ka,ia,ja)       )
    allocate( atmos_phy_cp_rhoq_t(ka,ia,ja,qs_mp:qe_mp) )
    atmos_phy_cp_dens_t(:,:,:)   = 0.0_rp
    atmos_phy_cp_momz_t(:,:,:)   = undef
    atmos_phy_cp_momx_t(:,:,:)   = undef
    atmos_phy_cp_momy_t(:,:,:)   = undef
    atmos_phy_cp_rhot_t(:,:,:)   = 0.0_rp
    atmos_phy_cp_rhoq_t(:,:,:,:) = 0.0_rp

    allocate( atmos_phy_cp_mflx_cloudbase(ia,ja)    )
    allocate( atmos_phy_cp_sflx_rain(ia,ja)    )
    allocate( atmos_phy_cp_cloudtop(ia,ja)    )
    allocate( atmos_phy_cp_cloudbase(ia,ja)    )
    allocate( atmos_phy_cp_cldfrac_dp(ka,ia,ja) )
    allocate( atmos_phy_cp_cldfrac_sh(ka,ia,ja) )
    allocate( atmos_phy_cp_kf_nca(ia,ja)    )
    allocate( atmos_phy_cp_kf_w0avg(ka,ia,ja) )
    atmos_phy_cp_mflx_cloudbase(:,:)   =    0.0_rp
    atmos_phy_cp_sflx_rain(:,:)   =    0.0_rp
    atmos_phy_cp_cloudtop(:,:)   =    0.0_rp
    atmos_phy_cp_cloudbase(:,:)   =    0.0_rp
    atmos_phy_cp_cldfrac_dp(:,:,:) =    0.0_rp
    atmos_phy_cp_cldfrac_sh(:,:,:) =    0.0_rp
    atmos_phy_cp_kf_nca(:,:)   = -100.0_rp
    atmos_phy_cp_kf_w0avg(:,:,:) =    0.0_rp

    ! for tendency restart
    vmax_t = 2 + qa_mp
    allocate( var_t_name(vmax_t) )
    allocate( var_t_desc(vmax_t) )
    allocate( var_t_unit(vmax_t) )
    allocate( var_t_id(vmax_t) )

    var_t_name(i_cp_dens_t) = 'DENS_t_CP'
    var_t_desc(i_cp_dens_t) = 'tendency DENS in CP'
    var_t_unit(i_cp_dens_t) = 'kg/m3/s'
    var_t_name(i_cp_rhot_t) = 'RHOT_t_CP'
    var_t_desc(i_cp_rhot_t) = 'tendency RHOT in CP'
    var_t_unit(i_cp_rhot_t) = 'K*kg/m3/s'

    do iq = 1, qa_mp
       var_t_name(2+iq) = trim(aq_name(iq))//'_t_CP'
       var_t_desc(2+iq) = 'tendency rho*'//trim(aq_name(iq))//' in CP'
       var_t_unit(2+iq) = 'kg/m3/s'
    enddo

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_cp_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       if( io_l ) write(io_fid_log,*) '*** Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       write(*,*) 'xxx Not appropriate names in namelist PARAM_ATMOS_PHY_CP_VARS. Check!'
       call prc_mpistop
    endif
    if( io_nml ) write(io_fid_nml,nml=param_atmos_phy_cp_vars)

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** [ATMOS_PHY_CP] prognostic/diagnostic variables'
    if( io_l ) write(io_fid_log,'(1x,A,A24,A,A48,A,A12,A)') &
               '***       |', 'VARNAME                 ','|', &
               'DESCRIPTION                                     ', '[', 'UNIT        ', ']'
    do iv = 1, vmax
       if( io_l ) write(io_fid_log,'(1x,A,I3,A,A24,A,A48,A,A12,A)') &
                  '*** NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
    enddo

    ! tendency
    do iv = 1, vmax_t
       if( io_l ) write(io_fid_log,'(1x,A,I3,A,A24,A,A48,A,A12,A)') &
                  '*** NO.',iv+vmax,'|',var_t_name(iv),'|',var_t_desc(iv),'[',var_t_unit(iv),']'
    enddo

    if( io_l ) write(io_fid_log,*)
    if ( atmos_phy_cp_restart_in_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** Restart input?  : YES, file = ', trim(atmos_phy_cp_restart_in_basename)
       if( io_l ) write(io_fid_log,*) '*** Add timelabel?  : ', atmos_phy_cp_restart_in_postfix_timelabel
    else
       if( io_l ) write(io_fid_log,*) '*** Restart input?  : NO'
    endif
    if (       atmos_phy_cp_restart_output             &
         .AND. atmos_phy_cp_restart_out_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** Restart output? : YES, file = ', trim(atmos_phy_cp_restart_out_basename)
       if( io_l ) write(io_fid_log,*) '*** Add timelabel?  : ', atmos_phy_cp_restart_out_postfix_timelabel
    else
       if( io_l ) write(io_fid_log,*) '*** Restart output? : NO'
       atmos_phy_cp_restart_output = .false.
    endif

    return
  end subroutine atmos_phy_cp_vars_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_fillhalo
    use scale_comm, only: &
       comm_vars8, &
       comm_wait
    use scale_atmos_phy_mp, only: &
       qa_mp
    implicit none

    integer :: i, j
    integer :: iq
    !---------------------------------------------------------------------------

    do j  = js, je
    do i  = is, ie
       atmos_phy_cp_cldfrac_dp(   1:ks-1,i,j) = atmos_phy_cp_cldfrac_dp(ks,i,j)
       atmos_phy_cp_cldfrac_dp(ke+1:ka,  i,j) = atmos_phy_cp_cldfrac_dp(ke,i,j)
       atmos_phy_cp_cldfrac_sh(   1:ks-1,i,j) = atmos_phy_cp_cldfrac_sh(ks,i,j)
       atmos_phy_cp_cldfrac_sh(ke+1:ka,  i,j) = atmos_phy_cp_cldfrac_sh(ke,i,j)
       atmos_phy_cp_kf_w0avg(   1:ks-1,i,j) = atmos_phy_cp_kf_w0avg(ks,i,j)
       atmos_phy_cp_kf_w0avg(ke+1:ka,  i,j) = atmos_phy_cp_kf_w0avg(ke,i,j)
       atmos_phy_cp_dens_t(   1:ks-1,i,j) = atmos_phy_cp_dens_t(ks,i,j)
       atmos_phy_cp_dens_t(ke+1:ka  ,i,j) = atmos_phy_cp_dens_t(ke,i,j)
       atmos_phy_cp_rhot_t(   1:ks-1,i,j) = atmos_phy_cp_rhot_t(ks,i,j)
       atmos_phy_cp_rhot_t(ke+1:ka  ,i,j) = atmos_phy_cp_rhot_t(ke,i,j)
    enddo
    enddo

    do iq = 1, qa_mp
       do j  = js, je
       do i  = is, ie
          atmos_phy_cp_rhoq_t(   1:ks-1,i,j,iq) = atmos_phy_cp_rhoq_t(ks,i,j,iq)
          atmos_phy_cp_rhoq_t(ke+1:ka  ,i,j,iq) = atmos_phy_cp_rhoq_t(ke,i,j,iq)
       enddo
       enddo
    end do

    call comm_vars8( atmos_phy_cp_mflx_cloudbase(:,:)  , 1 )
    call comm_vars8( atmos_phy_cp_sflx_rain(:,:)  , 2 )
    call comm_vars8( atmos_phy_cp_cloudtop(:,:)  , 3 )
    call comm_vars8( atmos_phy_cp_cloudbase(:,:)  , 4 )
    call comm_vars8( atmos_phy_cp_cldfrac_dp(:,:,:), 5 )
    call comm_vars8( atmos_phy_cp_cldfrac_sh(:,:,:), 6 )
    call comm_vars8( atmos_phy_cp_kf_nca(:,:)  , 7 )
    call comm_vars8( atmos_phy_cp_kf_w0avg(:,:,:), 8 )

    ! tendency
    call comm_vars8( atmos_phy_cp_dens_t(:,:,:), vmax+1 )
    call comm_vars8( atmos_phy_cp_rhot_t(:,:,:), vmax+2 )

    do iq = 1, qa_mp
       call comm_vars8( atmos_phy_cp_rhoq_t(:,:,:,iq), vmax+2+iq )
    enddo

    call comm_wait ( atmos_phy_cp_mflx_cloudbase(:,:)  , 1 )
    call comm_wait ( atmos_phy_cp_sflx_rain(:,:)  , 2 )
    call comm_wait ( atmos_phy_cp_cloudtop(:,:)  , 3 )
    call comm_wait ( atmos_phy_cp_cloudbase(:,:)  , 4 )
    call comm_wait ( atmos_phy_cp_cldfrac_dp(:,:,:), 5 )
    call comm_wait ( atmos_phy_cp_cldfrac_sh(:,:,:), 6 )
    call comm_wait ( atmos_phy_cp_kf_nca(:,:)  , 7 )
    call comm_wait ( atmos_phy_cp_kf_w0avg(:,:,:), 8 )

    call comm_wait ( atmos_phy_cp_dens_t(:,:,:), vmax+1 )
    call comm_wait ( atmos_phy_cp_rhot_t(:,:,:), vmax+2 )

    do iq = 1, qa_mp
       call comm_wait ( atmos_phy_cp_rhoq_t(:,:,:,iq), vmax+2+iq )
    enddo

    return
  end subroutine atmos_phy_cp_vars_fillhalo

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_open
    use scale_time, only: &
       time_gettimelabel
    use scale_fileio, only: &
       fileio_open
    implicit none

    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Open restart file (ATMOS_PHY_CP) ***'

    if ( atmos_phy_cp_restart_in_basename /= '' ) then

       if ( atmos_phy_cp_restart_in_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_cp_restart_in_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_cp_restart_in_basename)
       endif

       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(basename)

       call fileio_open( restart_fid, basename )
    else
       if( io_l ) write(io_fid_log,*) '*** restart file for ATMOS_PHY_CP is not specified.'
    endif

    return
  end subroutine atmos_phy_cp_vars_restart_open

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_read
    use scale_rm_statistics, only: &
       statistics_checktotal, &
       stat_total
    use scale_fileio, only: &
       fileio_read, &
       fileio_flush
    use scale_atmos_phy_mp, only: &
       qa_mp
    implicit none

    real(RP) :: total
    integer  :: i, j, iq
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Read from restart file (ATMOS_PHY_CP) ***'

       call fileio_read( atmos_phy_cp_mflx_cloudbase(:,:),                            & ! [OUT]
                         restart_fid, var_name(1), 'XY',  step=1 ) ! [IN]
       call fileio_read( atmos_phy_cp_sflx_rain(:,:),                                 & ! [OUT]
                         restart_fid, var_name(2), 'XY',  step=1 ) ! [IN]
       call fileio_read( atmos_phy_cp_cloudtop(:,:),                                  & ! [OUT]
                         restart_fid, var_name(3), 'XY',  step=1 ) ! [IN]
       call fileio_read( atmos_phy_cp_cloudbase(:,:),                                 & ! [OUT]
                         restart_fid, var_name(4), 'XY',  step=1 ) ! [IN]
       call fileio_read( atmos_phy_cp_cldfrac_dp(:,:,:),                              & ! [OUT]
                         restart_fid, var_name(5), 'ZXY', step=1 ) ! [IN]
       call fileio_read( atmos_phy_cp_cldfrac_sh(:,:,:),                              & ! [OUT]
                         restart_fid, var_name(6), 'ZXY', step=1 ) ! [IN]
       call fileio_read( atmos_phy_cp_kf_nca(:,:),                                    & ! [OUT]
                         restart_fid, var_name(7), 'XY',  step=1 ) ! [IN]
       call fileio_read( atmos_phy_cp_kf_w0avg(:,:,:),                                & ! [OUT]
                         restart_fid, var_name(8), 'ZXY', step=1 ) ! [IN]
       ! tendency
       call fileio_read( atmos_phy_cp_dens_t(:,:,:),                                    & ! [OUT]
                         restart_fid, var_t_name(1), 'ZXY', step=1 ) ! [IN]
       call fileio_read( atmos_phy_cp_rhot_t(:,:,:),                                    & ! [OUT]
                         restart_fid, var_t_name(2), 'ZXY', step=1 ) ! [IN]
       do iq = 1, qa_mp
          call fileio_read( atmos_phy_cp_rhoq_t(:,:,:,iq),                                    & ! [OUT]
                            restart_fid, var_t_name(2+iq), 'ZXY', step=1 ) ! [IN]
       enddo

       if ( io_aggregate ) then
          call fileio_flush( restart_fid ) ! X/Y halos have been read from file

          ! fill K halos
          do j  = 1, ja
          do i  = 1, ia
             atmos_phy_cp_cldfrac_dp(   1:ks-1,i,j) = atmos_phy_cp_cldfrac_dp(ks,i,j)
             atmos_phy_cp_cldfrac_sh(   1:ks-1,i,j) = atmos_phy_cp_cldfrac_sh(ks,i,j)
             atmos_phy_cp_kf_w0avg(   1:ks-1,i,j) = atmos_phy_cp_kf_w0avg(ks,i,j)
             atmos_phy_cp_dens_t(   1:ks-1,i,j) = atmos_phy_cp_dens_t(ks,i,j)
             atmos_phy_cp_rhot_t(   1:ks-1,i,j) = atmos_phy_cp_rhot_t(ks,i,j)
             atmos_phy_cp_cldfrac_dp(ke+1:ka,  i,j) = atmos_phy_cp_cldfrac_dp(ke,i,j)
             atmos_phy_cp_cldfrac_sh(ke+1:ka,  i,j) = atmos_phy_cp_cldfrac_sh(ke,i,j)
             atmos_phy_cp_kf_w0avg(ke+1:ka,  i,j) = atmos_phy_cp_kf_w0avg(ke,i,j)
             atmos_phy_cp_dens_t(ke+1:ka,  i,j) = atmos_phy_cp_dens_t(ke,i,j)
             atmos_phy_cp_rhot_t(ke+1:ka,  i,j) = atmos_phy_cp_rhot_t(ke,i,j)
          enddo
          enddo

          do iq = 1, qa_mp
             do j  = 1, ja
             do i  = 1, ia
                atmos_phy_cp_rhoq_t(   1:ks-1,i,j,iq) = atmos_phy_cp_rhoq_t(ks,i,j,iq)
                atmos_phy_cp_rhoq_t(ke+1:ka,  i,j,iq) = atmos_phy_cp_rhoq_t(ke,i,j,iq)
             enddo
             enddo
          enddo
       else
          call atmos_phy_cp_vars_fillhalo
       end if

       if ( statistics_checktotal ) then
          call stat_total( total, atmos_phy_cp_mflx_cloudbase(:,:)  , var_name(1) )
          call stat_total( total, atmos_phy_cp_sflx_rain(:,:)  , var_name(2) )
          call stat_total( total, atmos_phy_cp_cloudtop(:,:)  , var_name(3) )
          call stat_total( total, atmos_phy_cp_cloudbase(:,:)  , var_name(4) )
          call stat_total( total, atmos_phy_cp_cldfrac_dp(:,:,:), var_name(5) )
          call stat_total( total, atmos_phy_cp_cldfrac_sh(:,:,:), var_name(6) )
          call stat_total( total, atmos_phy_cp_kf_nca(:,:)  , var_name(7) )
          call stat_total( total, atmos_phy_cp_kf_w0avg(:,:,:), var_name(8) )
          ! tendency
          call stat_total( total, atmos_phy_cp_dens_t(:,:,:), var_t_name(1) )
          call stat_total( total, atmos_phy_cp_rhot_t(:,:,:), var_t_name(2) )
          do iq = 1, qa_mp
             call stat_total( total, atmos_phy_cp_rhoq_t(:,:,:,iq), var_t_name(2+iq) )
          enddo
       endif
    else
       if( io_l ) write(io_fid_log,*) '*** invalid restart file ID for ATMOS_PHY_CP.'
    endif

    return
  end subroutine atmos_phy_cp_vars_restart_read

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_create
    use scale_time, only: &
       time_gettimelabel
    use scale_fileio, only: &
       fileio_create
    implicit none

    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    if ( atmos_phy_cp_restart_out_basename /= '' ) then

       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Create restart file (ATMOS_PHY_AE) ***'

       if ( atmos_phy_cp_restart_out_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_cp_restart_out_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_cp_restart_out_basename)
       endif

       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(basename)

       call fileio_create( restart_fid,                                                             & ! [OUT]
                           basename, atmos_phy_cp_restart_out_title, atmos_phy_cp_restart_out_dtype ) ! [IN]

    endif

    return
  end subroutine atmos_phy_cp_vars_restart_create

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_enddef
    use scale_fileio, only: &
       fileio_enddef
    implicit none

    if ( restart_fid /= -1 ) then
       call fileio_enddef( restart_fid ) ! [IN]
    endif

    return
  end subroutine atmos_phy_cp_vars_restart_enddef

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_close
    use scale_fileio, only: &
       fileio_close
    implicit none
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Close restart file (ATMOS_PHY_CP) ***'

       call fileio_close( restart_fid ) ! [IN]

       restart_fid = -1
    endif

    return
  end subroutine atmos_phy_cp_vars_restart_close

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_def_var
    use scale_fileio, only: &
       fileio_def_var
    use scale_atmos_phy_mp, only: &
       qa_mp
    implicit none

    integer :: iq
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then

       call fileio_def_var( restart_fid, var_id(1), var_name(1), var_desc(1),   &
                            var_unit(1), 'XY',  atmos_phy_cp_restart_out_dtype  ) ! [IN]
       call fileio_def_var( restart_fid, var_id(2), var_name(2), var_desc(2),   &
                            var_unit(2), 'XY',  atmos_phy_cp_restart_out_dtype  ) ! [IN]
       call fileio_def_var( restart_fid, var_id(3), var_name(3), var_desc(3),   &
                            var_unit(3), 'XY',  atmos_phy_cp_restart_out_dtype  ) ! [IN]
       call fileio_def_var( restart_fid, var_id(4), var_name(4), var_desc(4),   &
                            var_unit(4), 'XY',  atmos_phy_cp_restart_out_dtype  ) ! [IN]
       call fileio_def_var( restart_fid, var_id(5), var_name(5), var_desc(5),   &
                            var_unit(5), 'ZXY', atmos_phy_cp_restart_out_dtype  ) ! [IN]
       call fileio_def_var( restart_fid, var_id(6), var_name(6), var_desc(6),   &
                            var_unit(6), 'ZXY', atmos_phy_cp_restart_out_dtype  ) ! [IN]
       call fileio_def_var( restart_fid, var_id(7), var_name(7), var_desc(7),   &
                            var_unit(7), 'XY',  atmos_phy_cp_restart_out_dtype  ) ! [IN]
       call fileio_def_var( restart_fid, var_id(8), var_name(8), var_desc(8),   &
                            var_unit(8), 'ZXY', atmos_phy_cp_restart_out_dtype  ) ! [IN]

       call fileio_def_var( restart_fid, var_t_id(1), var_t_name(1), var_t_desc(1), &
                            var_t_unit(1), 'ZXY',  atmos_phy_cp_restart_out_dtype   ) ! [IN]
       call fileio_def_var( restart_fid, var_t_id(2), var_t_name(2), var_t_desc(2), &
                            var_t_unit(2), 'ZXY',  atmos_phy_cp_restart_out_dtype   ) ! [IN]

       do iq = 1, qa_mp
          call fileio_def_var( restart_fid, var_t_id(2+iq), var_t_name(2+iq), var_t_desc(2+iq), &
                               var_t_unit(2+iq), 'ZXY',  atmos_phy_cp_restart_out_dtype         ) ! [IN]
       enddo

    endif

    return
  end subroutine atmos_phy_cp_vars_restart_def_var

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_vars_restart_write
    use scale_rm_statistics, only: &
       statistics_checktotal, &
       stat_total
    use scale_fileio, only: &
       fileio_write => fileio_write_var
    use scale_atmos_phy_mp, only: &
       qa_mp
    implicit none

    real(RP) :: total
    integer  :: iq
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then

       call atmos_phy_cp_vars_fillhalo

       if ( statistics_checktotal ) then
          call stat_total( total, atmos_phy_cp_mflx_cloudbase(:,:)  , var_name(1) )
          call stat_total( total, atmos_phy_cp_sflx_rain(:,:)  , var_name(2) )
          call stat_total( total, atmos_phy_cp_cloudtop(:,:)  , var_name(3) )
          call stat_total( total, atmos_phy_cp_cloudbase(:,:)  , var_name(4) )
          call stat_total( total, atmos_phy_cp_cldfrac_dp(:,:,:), var_name(5) )
          call stat_total( total, atmos_phy_cp_cldfrac_sh(:,:,:), var_name(6) )
          call stat_total( total, atmos_phy_cp_kf_nca(:,:)  , var_name(7) )
          call stat_total( total, atmos_phy_cp_kf_w0avg(:,:,:), var_name(8) )
          ! tendency
          call stat_total( total, atmos_phy_cp_dens_t(:,:,:), var_t_name(1) )
          call stat_total( total, atmos_phy_cp_rhot_t(:,:,:), var_t_name(2) )
          do iq = 1, qa_mp
             call stat_total( total, atmos_phy_cp_rhoq_t(:,:,:,iq), var_t_name(2+iq) )
          enddo
       endif

       call fileio_write( restart_fid, var_id(1), atmos_phy_cp_mflx_cloudbase(:,:), & ! [IN]
                          var_name(1), 'XY' ) ! [IN]
       call fileio_write( restart_fid, var_id(2), atmos_phy_cp_sflx_rain(:,:), & ! [IN]
                          var_name(2), 'XY' ) ! [IN]
       call fileio_write( restart_fid, var_id(3), atmos_phy_cp_cloudtop(:,:), & ! [IN]
                          var_name(3), 'XY' ) ! [IN]
       call fileio_write( restart_fid, var_id(4), atmos_phy_cp_cloudbase(:,:), & ! [IN]
                          var_name(4), 'XY' ) ! [IN]
       call fileio_write( restart_fid, var_id(5), atmos_phy_cp_cldfrac_dp(:,:,:), & ! [IN]
                          var_name(5), 'ZXY' ) ! [IN]
       call fileio_write( restart_fid, var_id(6), atmos_phy_cp_cldfrac_sh(:,:,:), & ! [IN]
                          var_name(6), 'ZXY' ) ! [IN]
       call fileio_write( restart_fid, var_id(7), atmos_phy_cp_kf_nca(:,:), & ! [IN]
                          var_name(7), 'XY' ) ! [IN]
       call fileio_write( restart_fid, var_id(8), atmos_phy_cp_kf_w0avg(:,:,:), & ! [IN]
                          var_name(8), 'ZXY' ) ! [IN]

       ! tendency
       call fileio_write( restart_fid, var_t_id(1), atmos_phy_cp_dens_t(:,:,:), & ! [IN]
                          var_t_name(1), 'ZXY' ) ! [IN]
       call fileio_write( restart_fid, var_t_id(2), atmos_phy_cp_rhot_t(:,:,:), & ! [IN]
                          var_t_name(2), 'ZXY' ) ! [IN]
       do iq = 1, qa_mp
          call fileio_write( restart_fid, var_t_id(2+iq), atmos_phy_cp_rhoq_t(:,:,:,iq), & ! [IN]
                             var_t_name(2+iq), 'ZXY' ) ! [IN]
       enddo

    endif

    return
  end subroutine atmos_phy_cp_vars_restart_write

end module mod_atmos_phy_cp_vars