mod_urban_driver.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module mod_urban_driver
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_urban_grid_cartesc_index
  use scale_tracer
  use scale_cpl_sfc_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: urban_driver_setup
  public :: urban_driver_calc_tendency
  public :: urban_driver_update
  public :: urban_surface_get
  public :: urban_surface_set
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  real(RP), private, allocatable :: AH_URB (:,:,:)   ! urban grid average of anthropogenic sensible heat [W/m2]
  real(RP), private, allocatable :: AHL_URB(:,:,:)  ! urban grid average of anthropogenic latent heat [W/m2]
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine urban_driver_setup
    use scale_prc, only: &
       prc_abort
    use scale_const, only: &
       undef => const_undef
    use mod_urban_admin, only: &
       urban_do, &
       urban_dyn_type, &
       urban_sfc_type
    use scale_urban_dyn_kusaka01, only: &
       urban_dyn_kusaka01_setup
    use scale_landuse, only: &
       landuse_fact_urban
    use mod_urban_vars, only: &
       urban_z0m, &
       urban_z0h, &
       urban_z0e, &
       urban_zd
    implicit none
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("URBAN_driver_setup",*) 'Setup'
 
    if ( urban_do ) then
 
       allocate( ah_urb(uia,uja,1:24) )
       allocate( ahl_urb(uia,uja,1:24) )
       ah_urb(:,:,:) = undef
       ahl_urb(:,:,:) = undef
 
       select case ( urban_dyn_type )
       case ( 'KUSAKA01' )
          call urban_dyn_kusaka01_setup( uia, uis, uie, uja, ujs, uje,                   & ! [IN]
                                         landuse_fact_urban(:,:),                        & ! [IN]
                                         urban_z0m(:,:), urban_z0h(:,:), urban_z0e(:,:), & ! [OUT]
                                         urban_zd(:,:),                                  & ! [OUT]
                                         ah_urb(:,:,:), ahl_urb(:,:,:)                   ) ! [OUT]
 
          urban_sfc_type = 'KUSAKA01'
       case default
          log_error("URBAN_driver_setup",*) 'LAND_DYN_TYPE is invalid: ', trim(urban_dyn_type)
          call prc_abort
       end select
 
       select case ( urban_sfc_type )
       case ( 'KUSAKA01' )
          ! do nothing
       case default
          log_error("URBAN_driver_setup",*) 'LAND_SFC_TYPE is invalid: ', trim(urban_sfc_type)
          call prc_abort
       end select
 
    end if
 
    return
  end subroutine urban_driver_setup
 
  !-----------------------------------------------------------------------------
  subroutine urban_driver_calc_tendency( force )
    use scale_const, only: &
       d2r => const_d2r
    use scale_statistics, only: &
       statistics_checktotal, &
       statistics_total
    use scale_urban_grid_cartesc_real, only: &
       urban_grid_cartesc_real_vol,    &
       urban_grid_cartesc_real_totvol, &
       urban_grid_cartesc_real_area,   &
       urban_grid_cartesc_real_totarea
    use scale_topography, only: &
       tansl_x => topography_tansl_x, &
       tansl_y => topography_tansl_y
    use scale_file_history, only: &
       file_history_in
    use mod_atmos_admin, only: &
       atmos_sw_phy_ch
    use mod_atmos_phy_ch_driver, only: &
       atmos_phy_ch_driver_urban_flux
    use mod_urban_vars, only: &
       atmos_temp,      &
       atmos_pres,      &
       atmos_u,         &
       atmos_v,         &
       atmos_dens,      &
       atmos_qv,        &
       atmos_pbl,       &
       atmos_sfc_dens,  &
       atmos_sfc_pres,  &
       atmos_sflx_lw,   &
       atmos_sflx_sw,   &
       atmos_cossza,    &
       atmos_sflx_water, &
       atmos_sflx_engi, &
       urban_trl_t,     &
       urban_tbl_t,     &
       urban_tgl_t,     &
       urban_tr_t,      &
       urban_tb_t,      &
       urban_tg_t,      &
       urban_tc_t,      &
       urban_qc_t,      &
       urban_uc_t,      &
       urban_rainr_t,   &
       urban_rainb_t,   &
       urban_raing_t,   &
       urban_sfc_temp,    &
       urban_sfc_albedo,  &
       urban_sflx_mw,     &
       urban_sflx_mu,     &
       urban_sflx_mv,     &
       urban_sflx_sh,     &
       urban_sflx_lh,     &
       urban_sflx_shex,   &
       urban_sflx_qvex,   &
       urban_sflx_qtrc,   &
       urban_sflx_gh,     &
       urban_z0m,         &
       urban_z0h,         &
       urban_z0e,         &
       urban_zd,          &
       urban_ah,          &
       urban_ahl,         &
       urban_ustar,       &
       urban_tstar,       &
       urban_qstar,       &
       urban_wstar,       &
       urban_rlmo,        &
       urban_u10,         &
       urban_v10,         &
       urban_t2,          &
       urban_q2,          &
       urban_tr,          &
       urban_tb,          &
       urban_tg,          &
       urban_tc,          &
       urban_qc,          &
       urban_uc,          &
       urban_trl,         &
       urban_tbl,         &
       urban_tgl,         &
       urban_rainr,       &
       urban_rainb,       &
       urban_raing,       &
       urban_roff
    use scale_atmos_hydrometeor, only: &
       hydrometeor_lhv => atmos_hydrometeor_lhv, &
       atmos_hydrometeor_dry,                    &
       i_qv
    use scale_time, only: &
       dt => time_dtsec_urban, &
       nowdate => time_nowdate
    use scale_mapprojection, only: &
       base_lon => mapprojection_basepoint_lon, &
       base_lat => mapprojection_basepoint_lat
    use scale_atmos_grid_cartesc_real, only: &
       real_z1 => atmos_grid_cartesc_real_z1
    use scale_urban_grid_cartesc, only: &
       cdz => urban_grid_cartesc_cdz
    use scale_landuse, only: &
       landuse_fact_urban, &
       exists_urban => landuse_exists_urban
    use mod_urban_admin, only: &
       urban_sfc_type
    use scale_urban_dyn_kusaka01, only: &
       urban_dyn_kusaka01
    implicit none
    logical, intent(in) :: force
 
    real(rp) :: trl(uka,uia,uja), tbl(uka,uia,uja), tgl(uka,uia,uja)
    real(rp) :: tr(uia,uja), tb(uia,uja), tg(uia,uja)
    real(rp) :: tc(uia,uja), qc(uia,uja), uc(uia,uja)
    real(rp) :: rainr(uia,uja), rainb(uia,uja), raing(uia,uja), roff(uia,uja)
 
    real(rp) :: lhv(uia,uja) ! latent heat of vaporization [J/kg]
 
    real(rp) :: urban_sflx_lhex(uia,uja)
 
    real(rp) :: lat, lon ! [deg]
    integer  :: tloc     ! local time (1-24h)
    real(rp) :: dsec     ! second [s]
 
    integer :: k, i, j, iq
    !---------------------------------------------------------------------------
 
    call prof_rapstart('URB_CalcTend', 1)
 
    !########## Get Surface Boundary from coupler ##########
    call urban_surface_get
 
    !########## initialize tendency ##########
!OCL XFILL
    do j = ujs, uje
    do i = uis, uie
    do k = uks, uke
       urban_trl_t(k,i,j) = 0.0_rp
       urban_tbl_t(k,i,j) = 0.0_rp
       urban_tgl_t(k,i,j) = 0.0_rp
    end do
    end do
    end do
 
!OCL XFILL
    do j = ujs, uje
    do i = uis, uie
       urban_tr_t(i,j) = 0.0_rp
       urban_tb_t(i,j) = 0.0_rp
       urban_tg_t(i,j) = 0.0_rp
       urban_tc_t(i,j) = 0.0_rp
       urban_qc_t(i,j) = 0.0_rp
       urban_uc_t(i,j) = 0.0_rp
 
       urban_rainr_t(i,j) = 0.0_rp
       urban_rainb_t(i,j) = 0.0_rp
       urban_raing_t(i,j) = 0.0_rp
    enddo
    enddo
 
!OCL XFILL
    !$omp parallel do
    do iq = 1, qa
    do j  = ujs, uje
    do i  = uis, uie
       urban_sflx_qtrc(i,j,iq) = 0.0_rp
    enddo
    enddo
    enddo
 
    select case ( urban_sfc_type )
    case ( 'KUSAKA01' )
 
!OCL XFILL
       !$omp parallel do
       do j = ujs, uje
       do i = uis, uie
       do k = uks, uke
          trl(k,i,j) = urban_trl(k,i,j)
          tbl(k,i,j) = urban_tbl(k,i,j)
          tgl(k,i,j) = urban_tgl(k,i,j)
       end do
       end do
       end do
 
!OCL XFILL
       !$omp parallel do
       do j = ujs, uje
       do i = uis, uie
          tr(i,j) = urban_tr(i,j)
          tb(i,j) = urban_tb(i,j)
          tg(i,j) = urban_tg(i,j)
          tc(i,j) = urban_tc(i,j)
          qc(i,j) = urban_qc(i,j)
          uc(i,j) = urban_uc(i,j)
          rainr(i,j) = urban_rainr(i,j)
          rainb(i,j) = urban_rainb(i,j)
          raing(i,j) = urban_raing(i,j)
       end do
       end do
 
 
       ! local time
       lat = base_lat
       lon = base_lon
       if (lon < 0.0_rp )   lon = mod(lon, 360.0_rp) + 360.0_rp
       if (lon > 360.0_rp ) lon = mod(lon, 360.0_rp)
       tloc = mod( (nowdate(4) + int(lon/15.0_rp)),24 )
       dsec = real( nowdate(5)*60.0_rp + nowdate(6), kind=rp ) / 3600.0_rp
       if( tloc == 0 ) tloc = 24
 
       !--- Calculate AH at LST
       if ( tloc == 24 ) then
          do j = ujs, uje
          do i = uis, uie
          if ( exists_urban(i,j) ) then
             urban_ah(i,j)  = ( 1.0_rp-dsec ) * ah_urb(i,j,tloc  ) &
                            + (        dsec ) * ah_urb(i,j,1     )
             urban_ahl(i,j) = ( 1.0_rp-dsec ) * ahl_urb(i,j,tloc  ) &
                            + (        dsec ) * ahl_urb(i,j,1     )
          end if
          enddo
          enddo
       else
          do j = ujs, uje
          do i = uis, uie
          if ( exists_urban(i,j) ) then
             urban_ah(i,j)  = ( 1.0_rp-dsec ) * ah_urb(i,j,tloc  ) &
                            + (        dsec ) * ah_urb(i,j,tloc+1)
             urban_ahl(i,j) = ( 1.0_rp-dsec ) * ahl_urb(i,j,tloc  ) &
                            + (        dsec ) * ahl_urb(i,j,tloc+1)
          end if
          enddo
          enddo
       endif
 
       call hydrometeor_lhv( uia, uis, uie, uja, ujs, uje, &
                             atmos_temp(:,:), lhv(:,:) )
 
       call urban_dyn_kusaka01( uka, uks, uke, uia, uis, uie, uja, ujs, uje, &
                                atmos_temp(:,:), atmos_pres(:,:),                            & ! [IN]
                                atmos_u(:,:), atmos_v(:,:),                                  & ! [IN]
                                atmos_dens(:,:), atmos_qv(:,:), lhv(:,:),                    & ! [IN]
                                real_z1(:,:), atmos_pbl(:,:),                                & ! [IN]
                                atmos_sfc_dens(:,:), atmos_sfc_pres(:,:),                    & ! [IN]
                                atmos_sflx_lw(:,:,:), atmos_sflx_sw(:,:,:),                  & ! [IN]
                                atmos_sflx_water(:,:), atmos_sflx_engi(:,:),                 & ! [IN]
                                urban_z0m(:,:), urban_z0h(:,:), urban_z0e(:,:),              & ! [IN]
                                urban_zd(:,:),                                               & ! [IN]
                                cdz(:),                                                      & ! [IN]
                                tansl_x(:,:), tansl_y(:,:),                                  & ! [IN]
                                landuse_fact_urban(:,:),                                     & ! [IN]
                                dt,                                                          & ! [IN]
                                trl(:,:,:), tbl(:,:,:), tgl(:,:,:),                          & ! [INOUT]
                                tr(:,:), tb(:,:), tg(:,:), tc(:,:), qc(:,:), uc(:,:),        & ! [INOUT]
                                rainr(:,:), rainb(:,:), raing(:,:), urban_roff(:,:),         & ! [INOUT]
                                urban_sfc_temp(:,:),                                         & ! [OUT]
                                urban_sfc_albedo(:,:,:,:),                                   & ! [OUT]
                                urban_sflx_mw(:,:), urban_sflx_mu(:,:), urban_sflx_mv(:,:),  & ! [OUT]
                                urban_sflx_sh(:,:), urban_sflx_lh(:,:), urban_sflx_gh(:,:),  & ! [OUT]
                                urban_ustar(:,:), urban_tstar(:,:), urban_qstar(:,:),        & ! [OUT]
                                urban_wstar(:,:),                                            & ! [OUT]
                                urban_rlmo(:,:),                                             & ! [OUT]
                                urban_u10(:,:), urban_v10(:,:), urban_t2(:,:), urban_q2(:,:) ) ! [OUT]
 
       !-----------------------------------------------------------
       ! anthropogenic heat fluxes
       !-----------------------------------------------------------
       !$omp parallel do
       do j = ujs, uje
       do i = uis, uie
       if ( exists_urban(i,j) ) then
          urban_sflx_shex(i,j) = urban_ah(i,j) / landuse_fact_urban(i,j) ! Sensible heat flux [W/m2]
          urban_sflx_lhex(i,j) = urban_ahl(i,j) / landuse_fact_urban(i,j) ! Latent heat flux   [W/m2]
          urban_sflx_sh(i,j) = urban_sflx_sh(i,j) + urban_sflx_shex(i,j)
          urban_sflx_lh(i,j) = urban_sflx_lh(i,j) + urban_sflx_lhex(i,j)
       end if
       end do
       end do
 
!OCL XFILL
       !$omp parallel do
       do j = ujs, uje
       do i = uis, uie
       if ( exists_urban(i,j) ) then
          do k = uks, uke
             urban_trl_t(k,i,j) = ( trl(k,i,j) - urban_trl(k,i,j) ) / dt
             urban_tbl_t(k,i,j) = ( tbl(k,i,j) - urban_tbl(k,i,j) ) / dt
             urban_tgl_t(k,i,j) = ( tgl(k,i,j) - urban_tgl(k,i,j) ) / dt
          end do
       end if
       end do
       end do
 
!OCL XFILL
       !$omp parallel do
       do j = ujs, uje
       do i = uis, uie
       if ( exists_urban(i,j) ) then
          urban_tr_t(i,j) = ( tr(i,j) - urban_tr(i,j) ) / dt
          urban_tb_t(i,j) = ( tb(i,j) - urban_tb(i,j) ) / dt
          urban_tg_t(i,j) = ( tg(i,j) - urban_tg(i,j) ) / dt
          urban_tc_t(i,j) = ( tc(i,j) - urban_tc(i,j) ) / dt
          urban_qc_t(i,j) = ( qc(i,j) - urban_qc(i,j) ) / dt
          urban_uc_t(i,j) = ( uc(i,j) - urban_uc(i,j) ) / dt
          urban_rainr_t(i,j) = ( rainr(i,j) - urban_rainr(i,j) ) / dt
          urban_rainb_t(i,j) = ( rainb(i,j) - urban_rainb(i,j) ) / dt
          urban_raing_t(i,j) = ( raing(i,j) - urban_raing(i,j) ) / dt
       end if
       end do
       end do
 
       if ( .NOT. atmos_hydrometeor_dry ) then
          !$omp parallel do
          do j = ujs, uje
          do i = uis, uie
          if ( exists_urban(i,j) ) then
             urban_sflx_qtrc(i,j,i_qv) = urban_sflx_lh(i,j) / lhv(i,j)
             urban_sflx_qvex(i,j)      = urban_sflx_lhex(i,j) / lhv(i,j)
          end if
          enddo
          enddo
       endif
 
    end select
 
    ! Surface flux for chemical tracers
    if ( atmos_sw_phy_ch ) then
       call atmos_phy_ch_driver_urban_flux( urban_sflx_qtrc(:,:,:) ) ! [INOUT]
    endif
 
    call file_history_in( urban_tr_t(:,:), 'URBAN_TR_t', 'tendency of URBAN_TR', 'K/s',     dim_type='XY' )
    call file_history_in( urban_tb_t(:,:), 'URBAN_TB_t', 'tendency of URBAN_TB', 'K/s',     dim_type='XY' )
    call file_history_in( urban_tg_t(:,:), 'URBAN_TG_t', 'tendency of URBAN_TG', 'K/s',     dim_type='XY' )
    call file_history_in( urban_tc_t(:,:), 'URBAN_TC_t', 'tendency of URBAN_TC', 'K/s',     dim_type='XY' )
    call file_history_in( urban_qc_t(:,:), 'URBAN_QC_t', 'tendency of URBAN_QC', 'kg/kg/s', dim_type='XY' )
    call file_history_in( urban_uc_t(:,:), 'URBAN_UC_t', 'tendency of URBAN_UC', 'm/s2',    dim_type='XY' )
 
    call file_history_in( urban_trl_t(:,:,:), 'URBAN_TRL_t', 'tendency of URBAN_TRL', 'K/s', dim_type='UXY' )
    call file_history_in( urban_tbl_t(:,:,:), 'URBAN_TBL_t', 'tendency of URBAN_TBL', 'K/s', dim_type='UXY' )
    call file_history_in( urban_tgl_t(:,:,:), 'URBAN_TGL_t', 'tendency of URBAN_TGL', 'K/s', dim_type='UXY' )
 
    call file_history_in( urban_rainr_t(:,:), 'URBAN_RAINR_t', 'tendency of URBAN_RAINR', 'kg/m2/s', dim_type='XY' )
    call file_history_in( urban_rainb_t(:,:), 'URBAN_RAINB_t', 'tendency of URBAN_RAINB', 'kg/m2/s', dim_type='XY' )
    call file_history_in( urban_raing_t(:,:), 'URBAN_RAING_t', 'tendency of URBAN_RAING', 'kg/m2/s', dim_type='XY' )
    call file_history_in( urban_roff(:,:), 'URBAN_ROFF',    'urban runoff water',      'kg/m2/s', dim_type='XY' )
 
    if ( statistics_checktotal ) then
 
       call statistics_total( uka, uks, uke, uia, uis, uie, uja, ujs, uje, &
                              urban_trl_t(:,:,:), 'URBAN_TRL_t', &
                              urban_grid_cartesc_real_vol(:,:,:), &
                              urban_grid_cartesc_real_totvol      )
       call statistics_total( uka, uks, uke, uia, uis, uie, uja, ujs, uje, &
                              urban_tbl_t(:,:,:), 'URBAN_TBL_t', &
                              urban_grid_cartesc_real_vol(:,:,:), &
                              urban_grid_cartesc_real_totvol      )
       call statistics_total( uka, uks, uke, uia, uis, uie, uja, ujs, uje, &
                              urban_tgl_t(:,:,:), 'URBAN_TGL_t', &
                              urban_grid_cartesc_real_vol(:,:,:), &
                              urban_grid_cartesc_real_totvol      )
 
       call statistics_total( uia, uis, uie, uja, ujs, uje, &
                              urban_tr_t(:,:), 'URBAN_TR_t',     &
                              urban_grid_cartesc_real_area(:,:), &
                              urban_grid_cartesc_real_totarea    )
       call statistics_total( uia, uis, uie, uja, ujs, uje, &
                              urban_tb_t(:,:), 'URBAN_TB_t',     &
                              urban_grid_cartesc_real_area(:,:), &
                              urban_grid_cartesc_real_totarea    )
       call statistics_total( uia, uis, uie, uja, ujs, uje, &
                              urban_tg_t(:,:), 'URBAN_TG_t',     &
                              urban_grid_cartesc_real_area(:,:), &
                              urban_grid_cartesc_real_totarea    )
       call statistics_total( uia, uis, uie, uja, ujs, uje, &
                              urban_tc_t(:,:), 'URBAN_TC_t',     &
                              urban_grid_cartesc_real_area(:,:), &
                              urban_grid_cartesc_real_totarea    )
       call statistics_total( uia, uis, uie, uja, ujs, uje, &
                              urban_qc_t(:,:), 'URBAN_QC_t',     &
                              urban_grid_cartesc_real_area(:,:), &
                              urban_grid_cartesc_real_totarea    )
       call statistics_total( uia, uis, uie, uja, ujs, uje, &
                              urban_uc_t(:,:), 'URBAN_UC_t',     &
                              urban_grid_cartesc_real_area(:,:), &
                              urban_grid_cartesc_real_totarea    )
 
       call statistics_total( uia, uis, uie, uja, ujs, uje, &
                              urban_rainr_t(:,:), 'URBAN_RAINR_t', &
                              urban_grid_cartesc_real_area(:,:),   &
                              urban_grid_cartesc_real_totarea      )
       call statistics_total( uia, uis, uie, uja, ujs, uje, &
                              urban_rainb_t(:,:), 'URBAN_RAINB_t', &
                              urban_grid_cartesc_real_area(:,:),   &
                              urban_grid_cartesc_real_totarea      )
       call statistics_total( uia, uis, uie, uja, ujs, uje, &
                              urban_raing_t(:,:), 'URBAN_RAING_t', &
                              urban_grid_cartesc_real_area(:,:),   &
                              urban_grid_cartesc_real_totarea      )
       call statistics_total( uia, uis, uie, uja, ujs, uje, &
                              urban_roff(:,:),    'URBAN_ROFF',    &
                              urban_grid_cartesc_real_area(:,:),   &
                              urban_grid_cartesc_real_totarea      )
    endif
 
 
    call prof_rapend  ('URB_CalcTend', 1)
 
    !########## Set Surface Boundary to coupler ##########
    call urban_surface_set( countup=.true. )
 
    return
  end subroutine urban_driver_calc_tendency
 
  !-----------------------------------------------------------------------------
  subroutine urban_driver_update
    use scale_time, only: &
       dt => time_dtsec_urban
    use mod_urban_vars, only: &
       urban_trl_t,       &
       urban_tbl_t,       &
       urban_tgl_t,       &
       urban_tr_t,        &
       urban_tb_t,        &
       urban_tg_t,        &
       urban_tc_t,        &
       urban_qc_t,        &
       urban_uc_t,        &
       urban_rainr_t,     &
       urban_rainb_t,     &
       urban_raing_t,     &
       urban_tr,          &
       urban_tb,          &
       urban_tg,          &
       urban_tc,          &
       urban_qc,          &
       urban_uc,          &
       urban_trl,         &
       urban_tbl,         &
       urban_tgl,         &
       urban_rainr,       &
       urban_rainb,       &
       urban_raing,       &
       urban_vars_check
    use mod_urban_admin, only: &
       urban_dyn_type
    use scale_landuse, only: &
       exists_urban => landuse_exists_urban
    implicit none
 
    integer :: k, i, j
    !---------------------------------------------------------------------------
 
    call prof_rapstart('URB_Update', 1)
 
    !########## Get Surface Boundary from coupler ##########
    call urban_surface_get
 
    !########## Dynamics / Update variables ##########
    select case ( urban_dyn_type )
    case ( 'KUSAKA01' )
 
!OCL XFILL
       !$omp parallel do
       do j = ujs, uje
       do i = uis, uie
       if ( exists_urban(i,j) ) then
          do k = uks, uke
             urban_trl(k,i,j) = urban_trl(k,i,j) + urban_trl_t(k,i,j) * dt
             urban_tbl(k,i,j) = urban_tbl(k,i,j) + urban_tbl_t(k,i,j) * dt
             urban_tgl(k,i,j) = urban_tgl(k,i,j) + urban_tgl_t(k,i,j) * dt
          end do
       end if
       end do
       end do
 
!OCL XFILL
       !$omp parallel do
       do j = ujs, uje
       do i = uis, uie
       if ( exists_urban(i,j) ) then
          urban_tr(i,j) = urban_tr(i,j) + urban_tr_t(i,j) * dt
          urban_tb(i,j) = urban_tb(i,j) + urban_tb_t(i,j) * dt
          urban_tg(i,j) = urban_tg(i,j) + urban_tg_t(i,j) * dt
          urban_tc(i,j) = urban_tc(i,j) + urban_tc_t(i,j) * dt
          urban_qc(i,j) = max( real(urban_qc(i,j) + urban_qc_t(i,j) * dt, rp), 0.0_rp )
          urban_uc(i,j) = max( real(urban_uc(i,j) + urban_uc_t(i,j) * dt, rp), 0.0_rp )
          urban_rainr(i,j) = max( real(urban_rainr(i,j) + urban_rainr_t(i,j) * dt, rp), 0.0_rp )
          urban_rainb(i,j) = max( real(urban_rainb(i,j) + urban_rainb_t(i,j) * dt, rp), 0.0_rp )
          urban_raing(i,j) = max( real(urban_raing(i,j) + urban_raing_t(i,j) * dt, rp), 0.0_rp )
       end if
       end do
       end do
 
    end select
 
    call urban_vars_check
 
    call prof_rapend  ('URB_Update', 1)
 
    return
  end subroutine urban_driver_update
 
  !-----------------------------------------------------------------------------
  subroutine urban_surface_get
    use mod_urban_admin, only: &
       urban_do
    use mod_urban_vars, only: &
       atmos_temp,      &
       atmos_pres,      &
       atmos_w,         &
       atmos_u,         &
       atmos_v,         &
       atmos_dens,      &
       atmos_qv,        &
       atmos_pbl,       &
       atmos_sfc_dens,  &
       atmos_sfc_pres,  &
       atmos_sflx_lw,   &
       atmos_sflx_sw,   &
       atmos_cossza,    &
       atmos_sflx_water, &
       atmos_sflx_engi
    use mod_cpl_vars, only: &
       cpl_getatm_urb
    implicit none
 
    real(rp) :: atmos_sflx_rad_dn(uia,uja,n_rad_dir,n_rad_rgn)
 
    integer  :: i, j
    !---------------------------------------------------------------------------
 
    call prof_rapstart('URB_SfcExch', 2)
 
    if ( urban_do ) then
       call cpl_getatm_urb( atmos_temp(:,:),     & ! [OUT]
                            atmos_pres(:,:),     & ! [OUT]
                            atmos_w(:,:),     & ! [OUT]
                            atmos_u(:,:),     & ! [OUT]
                            atmos_v(:,:),     & ! [OUT]
                            atmos_dens(:,:),     & ! [OUT]
                            atmos_qv(:,:),     & ! [OUT]
                            atmos_pbl(:,:),     & ! [OUT]
                            atmos_sfc_dens(:,:),     & ! [OUT]
                            atmos_sfc_pres(:,:),     & ! [OUT]
                            atmos_sflx_rad_dn(:,:,:,:), & ! [OUT]
                            atmos_cossza(:,:),     & ! [OUT]
                            atmos_sflx_water(:,:),     & ! [OUT]
                            atmos_sflx_engi(:,:)      ) ! [OUT]
    endif
 
!OCL XFILL
    do j = ujs, uje
    do i = uis, uie
       atmos_sflx_lw(i,j,i_r_direct ) = atmos_sflx_rad_dn(i,j,i_r_direct ,i_r_ir)    ! IR, direct
       atmos_sflx_lw(i,j,i_r_diffuse) = atmos_sflx_rad_dn(i,j,i_r_diffuse,i_r_ir)    ! IR, diffuse
 
       atmos_sflx_sw(i,j,i_r_direct ) = atmos_sflx_rad_dn(i,j,i_r_direct ,i_r_nir) & ! NIR, direct
                                      + atmos_sflx_rad_dn(i,j,i_r_direct ,i_r_vis)   ! VIS, direct
       atmos_sflx_sw(i,j,i_r_diffuse) = atmos_sflx_rad_dn(i,j,i_r_diffuse,i_r_nir) & ! NIR, diffuse
                                      + atmos_sflx_rad_dn(i,j,i_r_diffuse,i_r_vis)   ! VIS, diffuse
    enddo
    enddo
 
    call prof_rapend  ('URB_SfcExch', 2)
 
    return
  end subroutine urban_surface_get
 
  !-----------------------------------------------------------------------------
  subroutine urban_surface_set( countup )
    use mod_urban_admin, only: &
       urban_do
    use mod_urban_vars, only: &
       urban_sfc_temp,   &
       urban_sfc_albedo, &
       urban_sflx_mw,    &
       urban_sflx_mu,    &
       urban_sflx_mv,    &
       urban_sflx_sh,    &
       urban_sflx_lh,    &
       urban_sflx_shex,  &
       urban_sflx_qvex,  &
       urban_sflx_gh,    &
       urban_sflx_qtrc,  &
       urban_z0m,        &
       urban_z0h,        &
       urban_z0e,        &
       urban_u10,        &
       urban_v10,        &
       urban_t2,         &
       urban_q2
    use mod_cpl_vars, only: &
       cpl_puturb
    use scale_landuse, only: &
       exists_urban => landuse_exists_urban
    implicit none
 
    ! arguments
    logical, intent(in) :: countup
    !---------------------------------------------------------------------------
 
    call prof_rapstart('URB_SfcExch', 2)
 
    if ( urban_do ) then
       call cpl_puturb( urban_sfc_temp(:,:),     & ! [IN]
                        urban_sfc_albedo(:,:,:,:), & ! [IN]
                        urban_z0m(:,:),     & ! [IN]
                        urban_z0h(:,:),     & ! [IN]
                        urban_z0e(:,:),     & ! [IN]
                        urban_sflx_mw(:,:),     & ! [IN]
                        urban_sflx_mu(:,:),     & ! [IN]
                        urban_sflx_mv(:,:),     & ! [IN]
                        urban_sflx_sh(:,:),     & ! [IN]
                        urban_sflx_lh(:,:),     & ! [IN]
                        urban_sflx_shex(:,:),     & ! [IN]
                        urban_sflx_qvex(:,:),     & ! [IN]
                        urban_sflx_gh(:,:),     & ! [IN]
                        urban_sflx_qtrc(:,:,:),   & ! [IN]
                        urban_u10(:,:),     & ! [IN]
                        urban_v10(:,:),     & ! [IN]
                        urban_t2(:,:),     & ! [IN]
                        urban_q2(:,:),     & ! [IN]
                        exists_urban(:,:),     & ! [IN]
                        countup                    ) ! [IN]
    endif
 
    call prof_rapend  ('URB_SfcExch', 2)
 
    return
  end subroutine urban_surface_set
 
end module mod_urban_driver