module ATMOSPHERE / Physics Surface fluxes More...

Functions/Subroutines
subroutine, public	atmos_phy_sf_driver_setup
	Setup. More...

subroutine, public	atmos_phy_sf_driver_calc_tendency (update_flag)
	calculation tendency More...

subroutine	history_output

Detailed Description

module ATMOSPHERE / Physics Surface fluxes

Description: Flux from/to bottom boundary of atmosphere (surface)

Author: Team SCALE

NAMELIST

No namelist group

History Output

name	description	unit	variable
SFLX_{TRACER_NAME}	surface {TRACER_NAME} flux; {TRACER_NAME} depends on the physics schemes, e.g., QV, QC, QR.	kg/m2/s	SFLX_QTRC
GHFLX	ground heat flux (downward)	W/m2	SFLX_GH
LHFLX	latent heat flux	W/m2	SFLX_LH
MSLP	mean sea-level pressure	Pa	MSLP
MUFLX	u-momentum flux	kg/m/s2	SFLX_MU
MVFLX	v-momentum flux	kg/m/s2	SFLX_MV
MWFLX	w-momentum flux	kg/m/s2	SFLX_MW
Q2	2m specific humidity	kg/kg	Q2
Qstar	moisuter scale	kg/kg	Qstar
RLmo	inverse of Obukhov length	1/m	RLmo
SFC_ALB_IR_dif	surface albedo (IR; diffuse)	1	SFC_albedo
SFC_ALB_IR_dir	surface albedo (IR; direct	1	SFC_albedo
SFC_ALB_NIR_dif	surface albedo (NIR; diffuse	1	SFC_albedo
SFC_ALB_NIR_dir	surface albedo (NIR; direct	1	SFC_albedo
SFC_ALB_VIS_dif	surface albedo (VIS; diffuse	1	SFC_albedo
SFC_ALB_VIS_dir	surface albedo (VIS; direct	1	SFC_albedo
SFC_DENS	surface atmospheric density	kg/m3	SFC_DENS
SFC_PRES	surface atmospheric pressure	Pa	SFC_PRES
SFC_TEMP	surface skin temperature	K	SFC_TEMP
SFC_Z0E	roughness length (vapor)	m	SFC_Z0E
SFC_Z0H	roughness length (heat)	m	SFC_Z0H
SFC_Z0M	roughness length (momentum)	m	SFC_Z0M
SFLX_ENGI	ground internal energy flux (merged)	W/m2	SFLX_ENGI
SHFLX	sensible heat flux	W/m2	SFLX_SH
T2	2m air temperature	K	T2
Tstar	temperature scale	K	Tstar
U10	10m x-wind	m/s	U10
U10m	10m eastward wind	m/s	U10m
Uabs10	10m absolute wind	m/s	Uabs10
Ustar	friction velocity	m/s	Ustar
V10	10m y-wind	m/s	V10
V10m	10m northward wind	m/s	V10m
Wstar	convective velocity scale	m/s	Wstar

Function/Subroutine Documentation

◆ atmos_phy_sf_driver_setup()

subroutine, public mod_atmos_phy_sf_driver::atmos_phy_sf_driver_setup

Setup.

Definition at line 50 of file mod_atmos_phy_sf_driver.F90.

     use scale_prc, only: &
        prc_abort
     use scale_atmos_phy_sf_bulk, only: &
        atmos_phy_sf_bulk_setup
     use scale_atmos_phy_sf_const, only: &
        atmos_phy_sf_const_setup
     use mod_atmos_admin, only: &
        atmos_phy_sf_type, &
        atmos_sw_phy_sf
     use mod_atmos_phy_sf_vars, only: &
        sfc_z0m   => atmos_phy_sf_sfc_z0m,   &
        sfc_z0h   => atmos_phy_sf_sfc_z0h,   &
        sfc_z0e   => atmos_phy_sf_sfc_z0e,   &
        sflx_mw   => atmos_phy_sf_sflx_mw,   &
        sflx_mu   => atmos_phy_sf_sflx_mu,   &
        sflx_mv   => atmos_phy_sf_sflx_mv,   &
        sflx_sh   => atmos_phy_sf_sflx_sh,   &
        sflx_lh   => atmos_phy_sf_sflx_lh,   &
        sflx_shex => atmos_phy_sf_sflx_shex, &
        sflx_qvex => atmos_phy_sf_sflx_qvex, &
        sflx_qtrc => atmos_phy_sf_sflx_qtrc, &
        sflx_engi => atmos_phy_sf_sflx_engi, &
        ustar     => atmos_phy_sf_ustar,     &
        tstar     => atmos_phy_sf_tstar,     &
        qstar     => atmos_phy_sf_qstar,     &
        wstar     => atmos_phy_sf_wstar,     &
        rlmo      => atmos_phy_sf_rlmo
     use mod_cpl_admin, only: &
        cpl_sw
     implicit none
     !---------------------------------------------------------------------------
  
     log_newline
     log_info("ATMOS_PHY_SF_driver_setup",*) 'Setup'
  
     if ( atmos_sw_phy_sf ) then
  
        if ( cpl_sw ) then
           log_info("ATMOS_PHY_SF_driver_setup",*) 'Coupler is enabled.'
        else
           ! setup library component
           select case( atmos_phy_sf_type )
           case ( 'BULK' )
              call atmos_phy_sf_bulk_setup
           case ( 'CONST' )
              call atmos_phy_sf_const_setup
           case default
              log_error("ATMOS_PHY_SF_driver_setup",*) 'invalid Surface flux type(', trim(atmos_phy_sf_type), '). CHECK!'
              call prc_abort
           end select
        endif
  
     else
  
        log_info("ATMOS_PHY_SF_driver_setup",*) 'this component is never called.'
        log_info("ATMOS_PHY_SF_driver_setup",*) 'surface fluxes are set to zero.'
        sflx_mw(:,:) = 0.0_rp
        sflx_mu(:,:) = 0.0_rp
        sflx_mv(:,:) = 0.0_rp
        sflx_sh(:,:) = 0.0_rp
        sflx_lh(:,:) = 0.0_rp
        sflx_shex(:,:) = 0.0_rp
        sflx_qvex(:,:) = 0.0_rp
        ustar(:,:) = 0.0_rp
        tstar(:,:) = 0.0_rp
        qstar(:,:) = 0.0_rp
        wstar(:,:) = 0.0_rp
        rlmo(:,:) = 0.0_rp
        log_info("ATMOS_PHY_SF_driver_setup",*) 'SFC_TEMP, SFC_albedo is set in ATMOS_PHY_SF_vars.'
  
     endif
  
     sflx_qtrc(:,:,:) = 0.0_rp
     sflx_engi(:,:)   = 0.0_rp
  
     return

Referenced by mod_atmos_driver::atmos_driver_setup().

Here is the call graph for this function:

Here is the caller graph for this function:

◆ atmos_phy_sf_driver_calc_tendency()

subroutine, public mod_atmos_phy_sf_driver::atmos_phy_sf_driver_calc_tendency ( logical, intent(in) update_flag )

calculation tendency

Definition at line 131 of file mod_atmos_phy_sf_driver.F90.

     use scale_const, only: &
        undef  => const_undef, &
        pre00  => const_pre00
     use scale_atmos_grid_cartesc_real, only: &
        cz => atmos_grid_cartesc_real_cz, &
        fz => atmos_grid_cartesc_real_fz, &
        z1 => atmos_grid_cartesc_real_z1, &
        atmos_grid_cartesc_real_area, &
        atmos_grid_cartesc_real_totarea
     use scale_topography, only: &
        tansl_x => topography_tansl_x, &
        tansl_y => topography_tansl_y
     use scale_time, only: &
        dt_sf => time_dtsec_atmos_phy_sf
     use scale_statistics, only: &
        statistics_checktotal, &
        statistics_total
     use scale_atmos_bottom, only: &
        bottom_estimate => atmos_bottom_estimate
     use scale_atmos_hydrometeor, only: &
        atmos_hydrometeor_dry, &
        lhv, &
        i_qv
     use scale_atmos_phy_sf_bulk, only: &
        atmos_phy_sf_bulk_flux
     use scale_atmos_phy_sf_const, only: &
        atmos_phy_sf_const_flux
     use scale_bulkflux, only: &
        bulkflux_diagnose_scales
     use mod_atmos_admin, only: &
        atmos_phy_sf_type
     use mod_atmos_vars, only: &
        dens   => dens_av, &
        rhot   => rhot_av, &
        pott,              &
        temp,              &
        pres,              &
        w,                 &
        u,                 &
        v,                 &
        qv,                &
        cptot,             &
        cvtot,             &
        dens_t => dens_tp, &
        momz_t => momz_tp, &
        rhou_t => rhou_tp, &
        rhov_t => rhov_tp, &
        rhoh   => rhoh_p,  &
        rhoq_t => rhoq_tp
     use mod_atmos_phy_rd_vars, only: &
        sflx_lw_dn => atmos_phy_rd_sflx_lw_dn, &
        sflx_sw_dn => atmos_phy_rd_sflx_sw_dn
     use mod_atmos_phy_bl_vars, only: &
        pbl_zi => atmos_phy_bl_zi
     use mod_atmos_phy_sf_vars, only: &
        dens_t_sf => atmos_phy_sf_dens_t,    &
        momz_t_sf => atmos_phy_sf_momz_t,    &
        rhou_t_sf => atmos_phy_sf_rhou_t,    &
        rhov_t_sf => atmos_phy_sf_rhov_t,    &
        rhoh_sf   => atmos_phy_sf_rhoh,      &
        rhoq_t_sf => atmos_phy_sf_rhoq_t,    &
        sfc_dens  => atmos_phy_sf_sfc_dens,  &
        sfc_pres  => atmos_phy_sf_sfc_pres,  &
        sfc_temp  => atmos_phy_sf_sfc_temp,  &
        sfc_z0m   => atmos_phy_sf_sfc_z0m,   &
        sfc_z0h   => atmos_phy_sf_sfc_z0h,   &
        sfc_z0e   => atmos_phy_sf_sfc_z0e,   &
        sflx_mw   => atmos_phy_sf_sflx_mw,   &
        sflx_mu   => atmos_phy_sf_sflx_mu,   &
        sflx_mv   => atmos_phy_sf_sflx_mv,   &
        sflx_sh   => atmos_phy_sf_sflx_sh,   &
        sflx_lh   => atmos_phy_sf_sflx_lh,   &
        sflx_shex => atmos_phy_sf_sflx_shex, &
        sflx_qvex => atmos_phy_sf_sflx_qvex, &
        sflx_qtrc => atmos_phy_sf_sflx_qtrc, &
        sflx_engi => atmos_phy_sf_sflx_engi, &
        ustar     => atmos_phy_sf_ustar,     &
        tstar     => atmos_phy_sf_tstar,     &
        qstar     => atmos_phy_sf_qstar,     &
        wstar     => atmos_phy_sf_wstar,     &
        rlmo      => atmos_phy_sf_rlmo,      &
        u10       => atmos_phy_sf_u10,       &
        v10       => atmos_phy_sf_v10,       &
        t2        => atmos_phy_sf_t2,        &
        q2        => atmos_phy_sf_q2
     use mod_cpl_admin, only: &
        cpl_sw
     implicit none
  
     logical, intent(in) :: update_flag
  
     real(RP) :: ATM_W   (IA,JA)
     real(RP) :: ATM_U   (IA,JA)
     real(RP) :: ATM_V   (IA,JA)
     real(RP) :: ATM_DENS(IA,JA)
     real(RP) :: ATM_TEMP(IA,JA)
     real(RP) :: ATM_PRES(IA,JA)
     real(RP) :: ATM_QV  (IA,JA)
     real(RP) :: SFLX_SH2(IA,JA)
     real(RP) :: SFLX_QV (IA,JA)
     real(RP) :: CP_t, CV_t
     real(RP) :: ENGI_t
     real(RP) :: rdz
     real(RP) :: work
  
     integer  :: i, j, iq
     !---------------------------------------------------------------------------
  
     if ( update_flag ) then
  
        ! update surface density, surface pressure
        call bottom_estimate( ka, ks,  ke, ia, is, ie, ja, js, je, &
                              dens(:,:,:), pres(:,:,:), qv(:,:,:), & ! [IN]
                              sfc_temp(:,:),                       & ! [IN]
                              fz(:,:,:),                           & ! [IN]
                              sfc_dens(:,:), sfc_pres(:,:)         ) ! [OUT]
  
        !$omp parallel do
        do j = js, je
        do i = is, ie
           atm_dens(i,j) = dens(ks,i,j)
           atm_temp(i,j) = temp(ks,i,j)
           atm_pres(i,j) = pres(ks,i,j)
        end do
        end do
  
        if ( cpl_sw ) then
  
           !$omp parallel do
           do j = js, je
           do i = is, ie
              sflx_sh2(i,j) = sflx_sh(i,j) - sflx_shex(i,j)
           end do
           end do
  
           if ( atmos_hydrometeor_dry ) then
              !$omp parallel do
              do j = js, je
              do i = is, ie
                 sflx_qv(i,j) = 0.0_rp
              end do
              end do
           else
              !$omp parallel do
              do j = js, je
              do i = is, ie
                 sflx_qv(i,j) = sflx_qtrc(i,j,i_qv) - sflx_qvex(i,j)
              end do
              end do
           end if
  
           call bulkflux_diagnose_scales( ia, is, ie, ja, js, je, &
                                          sflx_mw(:,:), sflx_mu(:,:), sflx_mv(:,:),  & ! [IN]
                                          sflx_sh2(:,:), sflx_qv(:,:),               & ! [IN]
                                          sfc_dens(:,:), sfc_temp(:,:), pbl_zi(:,:), & ! [IN]
                                          ustar(:,:), tstar(:,:), qstar(:,:),        & ! [OUT]
                                          wstar(:,:), rlmo(:,:)                      ) ! [OUT]
        else
  
           !$omp parallel do
           do j = js, je
           do i = is, ie
              atm_u(i,j) = u(ks,i,j)
              atm_v(i,j) = v(ks,i,j)
              atm_w(i,j) = atm_u(i,j) * tansl_x(i,j) + atm_v(i,j) * tansl_y(i,j)
              atm_qv(i,j) = qv(ks,i,j)
           enddo
           enddo
  
           select case ( atmos_phy_sf_type )
           case ( 'BULK' )
  
              call atmos_phy_sf_bulk_flux( ia, is, ie, ja, js, je,                      & ! [IN]
                                           atm_w(:,:), atm_u(:,:), atm_v(:,:),          & ! [IN]
                                           atm_temp(:,:), atm_pres(:,:), atm_qv(:,:),   & ! [IN]
                                           sfc_dens(:,:), sfc_temp(:,:), sfc_pres(:,:), & ! [IN]
                                           sfc_z0m(:,:), sfc_z0h(:,:), sfc_z0e(:,:),    & ! [IN]
                                           pbl_zi(:,:), z1(:,:),                        & ! [IN]
                                           sflx_mw(:,:), sflx_mu(:,:), sflx_mv(:,:),    & ! [OUT]
                                           sflx_sh(:,:), sflx_lh(:,:), sflx_qv(:,:),    & ! [OUT]
                                           ustar(:,:), tstar(:,:), qstar(:,:),          & ! [OUT]
                                           wstar(:,:),                                  & ! [OUT]
                                           rlmo(:,:),                                   & ! [OUT]
                                           u10(:,:), v10(:,:), t2(:,:), q2(:,:)         ) ! [OUT]
  
           case ( 'CONST' )
  
              call atmos_phy_sf_const_flux( ia, is, ie, ja, js, je,                            & ! [IN]
                                            atm_w(:,:), atm_u(:,:), atm_v(:,:), sfc_temp(:,:), & ! [IN]
                                            z1(:,:), sfc_dens(:,:),                            & ! [IN]
                                            sflx_mw(:,:), sflx_mu(:,:), sflx_mv(:,:),          & ! [OUT]
                                            sflx_sh(:,:), sflx_lh(:,:), sflx_qv(:,:),          & ! [OUT]
                                            u10(:,:), v10(:,:)                                 ) ! [OUT]
              ustar(:,:) = undef
              tstar(:,:) = undef
              qstar(:,:) = undef
              rlmo(:,:) = undef
              t2(:,:) = atm_temp(:,:)
              q2(:,:) = atm_qv(:,:)
  
           end select
  
           if ( .NOT. atmos_hydrometeor_dry ) then
              sflx_qtrc(:,:,i_qv) = sflx_qv(:,:)
              sflx_engi(:,:)      = sflx_qv(:,:) * ( tracer_cv(i_qv) * sfc_temp(:,:) + lhv )
           endif
  
        endif
  
        call history_output
  
 !OCL XFILL
        !$omp parallel do &
        !$omp private(rdz)
        do j = js, je
        do i = is, ie
           rdz = 1.0_rp / ( fz(ks,i,j) - fz(ks-1,i,j) )
           momz_t_sf(i,j) = sflx_mw(i,j) / ( cz(ks+1,i,j) - cz(ks,i,j) )
           rhou_t_sf(i,j) = sflx_mu(i,j) * rdz
           rhov_t_sf(i,j) = sflx_mv(i,j) * rdz
        enddo
        enddo
  
        !$omp parallel do &
        !$omp private(work,rdz,CP_t,CV_t,ENGI_t)
        do j = js, je
        do i = is, ie
           rdz = 1.0_rp / ( fz(ks,i,j) - fz(ks-1,i,j) )
           dens_t_sf(i,j) = 0.0_rp
           cp_t = 0.0_rp
           cv_t = 0.0_rp
           engi_t = sflx_engi(i,j) * rdz
           do iq = 1, qa
              work = sflx_qtrc(i,j,iq) * rdz
  
              rhoq_t_sf(i,j,iq) = work
              dens_t_sf(i,j)    = dens_t_sf(i,j) + work * tracer_mass(iq)
              cp_t              = cp_t + work * tracer_cp(iq)
              cv_t              = cv_t + work * tracer_cv(iq)
              engi_t            = engi_t - tracer_engi0(iq) * work
           end do
           cp_t = ( cp_t - cptot(ks,i,j) * dens_t_sf(i,j) ) / atm_dens(i,j)
           cv_t = ( cv_t - cvtot(ks,i,j) * dens_t_sf(i,j) ) / atm_dens(i,j)
  
           rhoh_sf(i,j) = sflx_sh(i,j) * rdz + engi_t &
                        - ( cp_t + log( atm_pres(i,j) / pre00 ) * ( cvtot(ks,i,j) / cptot(ks,i,j) * cp_t - cv_t ) ) * atm_dens(i,j) * atm_temp(i,j)
        enddo
        enddo
  
     endif
  
     !$omp parallel do
     do j = js, je
     do i = is, ie
        momz_t(ks,i,j) = momz_t(ks,i,j) + momz_t_sf(i,j)
        rhou_t(ks,i,j) = rhou_t(ks,i,j) + rhou_t_sf(i,j)
        rhov_t(ks,i,j) = rhov_t(ks,i,j) + rhov_t_sf(i,j)
        rhoh(ks,i,j) = rhoh(ks,i,j) + rhoh_sf(i,j)
        dens_t(ks,i,j) = dens_t(ks,i,j) + dens_t_sf(i,j)
     enddo
     enddo
  
     !$omp parallel
     do iq = 1, qa
     !$omp do
     do j = js, je
     do i = is, ie
        rhoq_t(ks,i,j,iq) = rhoq_t(ks,i,j,iq) + rhoq_t_sf(i,j,iq)
     enddo
     enddo
     !$omp end do nowait
     enddo
     !$omp end parallel
  
     if ( statistics_checktotal ) then
  
        if ( .NOT. atmos_hydrometeor_dry ) then
           do iq = 1, qa
              call statistics_total( ia, is, ie, ja, js, je, &
                                     sflx_qtrc(:,:,iq), 'SFLX_'//trim(tracer_name(iq)), &
                                     atmos_grid_cartesc_real_area(:,:),                 &
                                     atmos_grid_cartesc_real_totarea                    )
           enddo
        endif
  
        call statistics_total( ia, is, ie, ja, js, je, &
                               dens_t_sf(:,:), 'DENS_t_SF',       &
                               atmos_grid_cartesc_real_area(:,:), &
                               atmos_grid_cartesc_real_totarea    )
        call statistics_total( ia, is, ie, ja, js, je, &
                               momz_t_sf(:,:), 'MOMZ_t_SF',       &
                               atmos_grid_cartesc_real_area(:,:), &
                               atmos_grid_cartesc_real_totarea    )
        call statistics_total( ia, is, ie, ja, js, je, &
                               rhou_t_sf(:,:), 'RHOU_t_SF',       &
                               atmos_grid_cartesc_real_area(:,:), &
                               atmos_grid_cartesc_real_totarea    )
        call statistics_total( ia, is, ie, ja, js, je, &
                               rhov_t_sf(:,:), 'RHOV_t_SF',       &
                               atmos_grid_cartesc_real_area(:,:), &
                               atmos_grid_cartesc_real_totarea    )
        call statistics_total( ia, is, ie, ja, js, je, &
                               rhoh_sf(:,:), 'RHOH_SF',         &
                               atmos_grid_cartesc_real_area(:,:), &
                               atmos_grid_cartesc_real_totarea    )
  
        do iq = 1, qa
           call statistics_total( ia, is, ie, ja, js, je, &
                                  rhoq_t_sf(:,:,iq), trim(tracer_name(iq))//'_t_SF', &
                                  atmos_grid_cartesc_real_area(:,:),                 &
                                  atmos_grid_cartesc_real_totarea                    )
        enddo
  
     endif
  
     return

Referenced by mod_atmos_driver::atmos_driver_calc_tendency(), and mod_atmos_driver::atmos_driver_calc_tendency_from_sflux().

Here is the call graph for this function:

Here is the caller graph for this function:

◆ history_output()

subroutine mod_atmos_phy_sf_driver::history_output

Definition at line 451 of file mod_atmos_phy_sf_driver.F90.

     use scale_const, only: &
        undef => const_undef
     use scale_file_history, only: &
        file_history_in
     use scale_atmos_hydrostatic, only: &
        barometric_law_mslp => atmos_hydrostatic_barometric_law_mslp
     use scale_atmos_grid_cartesc_real, only: &
        real_cz => atmos_grid_cartesc_real_cz
     use scale_atmos_grid_cartesc_metric, only: &
        rotc => atmos_grid_cartesc_metric_rotc
     use scale_atmos_hydrometeor, only: &
        atmos_hydrometeor_dry, &
        i_qv
     use mod_atmos_vars, only: &
        temp, &
        pres, &
        qv
     use mod_atmos_phy_sf_vars, only: &
        sfc_dens   => atmos_phy_sf_sfc_dens,   &
        sfc_pres   => atmos_phy_sf_sfc_pres,   &
        sfc_temp   => atmos_phy_sf_sfc_temp,   &
        sfc_albedo => atmos_phy_sf_sfc_albedo, &
        sfc_z0m    => atmos_phy_sf_sfc_z0m,    &
        sfc_z0h    => atmos_phy_sf_sfc_z0h,    &
        sfc_z0e    => atmos_phy_sf_sfc_z0e,    &
        sflx_mw    => atmos_phy_sf_sflx_mw,    &
        sflx_mu    => atmos_phy_sf_sflx_mu,    &
        sflx_mv    => atmos_phy_sf_sflx_mv,    &
        sflx_sh    => atmos_phy_sf_sflx_sh,    &
        sflx_lh    => atmos_phy_sf_sflx_lh,    &
        sflx_gh    => atmos_phy_sf_sflx_gh,    &
        sflx_qtrc  => atmos_phy_sf_sflx_qtrc,  &
        sflx_engi  => atmos_phy_sf_sflx_engi,  &
        ustar      => atmos_phy_sf_ustar,      &
        tstar      => atmos_phy_sf_tstar,      &
        qstar      => atmos_phy_sf_qstar,      &
        wstar      => atmos_phy_sf_wstar,      &
        rlmo       => atmos_phy_sf_rlmo,       &
        u10        => atmos_phy_sf_u10,        &
        v10        => atmos_phy_sf_v10,        &
        t2         => atmos_phy_sf_t2,         &
        q2         => atmos_phy_sf_q2
     implicit none
  
     real(RP) :: MSLP  (IA,JA) ! mean sea-level pressure [Pa]
     real(RP) :: Uabs10(IA,JA) ! 10m absolute wind [m/s]
     real(RP) :: U10m  (IA,JA) ! eastward 10m wind
     real(RP) :: V10m  (IA,JA) ! northward 10m wind
  
     integer :: i, j, iq
     !---------------------------------------------------------------------------
  
 !OCL XFILL
     !$omp parallel do
     do j = js, je
     do i = is, ie
        uabs10(i,j) = sqrt( u10(i,j)**2 + v10(i,j)**2 )
        u10m(i,j) = u10(i,j) * rotc(i,j,1) - v10(i,j) * rotc(i,j,2)
        v10m(i,j) = u10(i,j) * rotc(i,j,2) + v10(i,j) * rotc(i,j,1)
     enddo
     enddo
  
  
     call barometric_law_mslp( ka, ks, ke, ia, is, ie, ja, js, je,  & ! [IN]
                               pres(:,:,:), temp(:,:,:), qv(:,:,:), & ! [IN]
                               real_cz(:,:,:),                      & ! [IN]
                               mslp(:,:)                            ) ! [OUT]
  
     call file_history_in( sfc_dens(:,:),                     'SFC_DENS',        'surface atmospheric density',          'kg/m3'   )
     call file_history_in( sfc_pres(:,:),                     'SFC_PRES',        'surface atmospheric pressure',         'Pa'      )
     call file_history_in( sfc_temp(:,:),                     'SFC_TEMP',        'surface skin temperature',             'K'       )
     call file_history_in( sfc_albedo(:,:,i_r_direct ,i_r_ir ), 'SFC_ALB_IR_dir' , 'surface albedo (IR; direct',           '1'       , fill_halo=.true. )
     call file_history_in( sfc_albedo(:,:,i_r_diffuse,i_r_ir ), 'SFC_ALB_IR_dif' , 'surface albedo (IR; diffuse)',         '1'       , fill_halo=.true. )
     call file_history_in( sfc_albedo(:,:,i_r_direct ,i_r_nir), 'SFC_ALB_NIR_dir', 'surface albedo (NIR; direct',          '1'       , fill_halo=.true. )
     call file_history_in( sfc_albedo(:,:,i_r_diffuse,i_r_nir), 'SFC_ALB_NIR_dif', 'surface albedo (NIR; diffuse',         '1'       , fill_halo=.true. )
     call file_history_in( sfc_albedo(:,:,i_r_direct ,i_r_vis), 'SFC_ALB_VIS_dir', 'surface albedo (VIS; direct',          '1'       , fill_halo=.true. )
     call file_history_in( sfc_albedo(:,:,i_r_diffuse,i_r_vis), 'SFC_ALB_VIS_dif', 'surface albedo (VIS; diffuse',         '1'       , fill_halo=.true. )
     call file_history_in( sfc_z0m(:,:),                     'SFC_Z0M',         'roughness length (momentum)',           'm'       , fill_halo=.true. )
     call file_history_in( sfc_z0h(:,:),                     'SFC_Z0H',         'roughness length (heat)',               'm'       , fill_halo=.true. )
     call file_history_in( sfc_z0e(:,:),                     'SFC_Z0E',         'roughness length (vapor)',              'm'       , fill_halo=.true. )
     call file_history_in( sflx_mw(:,:),                     'MWFLX',           'w-momentum flux',                       'kg/m/s2' )
     call file_history_in( sflx_mu(:,:),                     'MUFLX',           'u-momentum flux',                       'kg/m/s2' )
     call file_history_in( sflx_mv(:,:),                     'MVFLX',           'v-momentum flux',                       'kg/m/s2' )
     call file_history_in( sflx_sh(:,:),                     'SHFLX',           'sensible heat flux',                    'W/m2'    , fill_halo=.true. )
     call file_history_in( sflx_lh(:,:),                     'LHFLX',           'latent heat flux',                      'W/m2'    , fill_halo=.true. )
     call file_history_in( sflx_gh(:,:),                     'GHFLX',           'ground heat flux (downward)',           'W/m2'    , fill_halo=.true. )
     do iq = 1, qa
        call file_history_in( sflx_qtrc(:,:,iq), 'SFLX_'//trim(tracer_name(iq)), &
                              'surface '//trim(tracer_name(iq))//' flux',        &
                              'kg/m2/s' , fill_halo=.true.                       )
     enddo
     call file_history_in( sflx_engi(:,:),                     'SFLX_ENGI',        'ground internal energy flux (merged)', 'W/m2'    , fill_halo=.true. )
  
     call file_history_in( ustar(:,:), 'Ustar',  'friction velocity',         'm/s'  , fill_halo=.true. )
     call file_history_in( tstar(:,:), 'Tstar',  'temperature scale',         'K'    , fill_halo=.true. )
     call file_history_in( qstar(:,:), 'Qstar',  'moisuter scale',            'kg/kg', fill_halo=.true. )
     call file_history_in( wstar(:,:), 'Wstar',  'convective velocity scale', 'm/s',   fill_halo=.true. )
     call file_history_in( rlmo(:,:), 'RLmo',   'inverse of Obukhov length', '1/m'  , fill_halo=.true. )
     call file_history_in( uabs10(:,:), 'Uabs10', '10m absolute wind',         'm/s'  , fill_halo=.true. )
     call file_history_in( u10(:,:), 'U10',    '10m x-wind',                'm/s'  , fill_halo=.true. )
     call file_history_in( v10(:,:), 'V10',    '10m y-wind',                'm/s'  , fill_halo=.true. )
     call file_history_in( u10m(:,:), 'U10m',   '10m eastward wind',         'm/s'  , fill_halo=.true. )
     call file_history_in( v10m(:,:), 'V10m',   '10m northward wind',        'm/s'  , fill_halo=.true. )
     call file_history_in( t2(:,:), 'T2 ',    '2m air temperature',        'K'    , fill_halo=.true. )
     call file_history_in( q2(:,:), 'Q2 ',    '2m specific humidity',      'kg/kg', fill_halo=.true. )
     call file_history_in( mslp(:,:), 'MSLP',   'mean sea-level pressure',   'Pa'   , fill_halo=.true., standard_name='air_pressure_at_mean_sea_level' )
  
     return

Referenced by atmos_phy_sf_driver_calc_tendency().

Here is the caller graph for this function:

Functions/Subroutines

Detailed Description

Function/Subroutine Documentation

◆ atmos_phy_sf_driver_setup()

◆ atmos_phy_sf_driver_calc_tendency()

◆ history_output()