mod_atmos_phy_ae_driver.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "inc_openmp.h"
module mod_atmos_phy_ae_driver
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_ae_driver_setup
  public :: atmos_phy_ae_driver_resume
  public :: atmos_phy_ae_driver

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_driver_setup
    use scale_atmos_phy_ae, only: &
       atmos_phy_ae_setup
    use mod_atmos_admin, only: &
       atmos_phy_ae_type!, &
!       ATMOS_sw_phy_ae
    implicit none
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[DRIVER] / Categ[ATMOS PHY_AE] / Origin[SCALE-RM]'

    ! note: tentatively, aerosol module should be called at all time. we need dummy subprogram.
!    if ( ATMOS_sw_phy_ae ) then

       ! setup library component
       call atmos_phy_ae_setup( atmos_phy_ae_type )

!    else
!       if( IO_L ) write(IO_FID_LOG,*) '*** this component is never called.'
!    endif

    return
  end subroutine atmos_phy_ae_driver_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_driver_resume
!     use mod_atmos_admin, only: &
!        ATMOS_sw_phy_ae
    implicit none

    ! note: tentatively, aerosol module should be called at all time. we need dummy subprogram.
!    if ( ATMOS_sw_phy_ae ) then

       ! run once (only for the diagnostic value)
       call prof_rapstart('ATM_Aerosol', 1)
       call atmos_phy_ae_driver( update_flag = .true. )
       call prof_rapend  ('ATM_Aerosol', 1)

!    endif

    return
  end subroutine atmos_phy_ae_driver_resume

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_driver( update_flag )
    use scale_time, only: &
       dt_ae => time_dtsec_atmos_phy_ae
    use scale_rm_statistics, only: &
       statistics_checktotal, &
       stat_total
    use scale_history, only: &
       hist_in
    use scale_atmos_phy_ae, only: &
       atmos_phy_ae
    use mod_atmos_vars, only: &
       dens,              &
       momz,              &
       momx,              &
       momy,              &
       rhot,              &
       qtrc,              &
       rhoq_t => rhoq_tp
    use mod_atmos_phy_ae_vars, only: &
       rhoq_t_ae => atmos_phy_ae_rhoq_t, &
       ccn       => atmos_phy_ae_ccn,   &
       ccn_t     => atmos_phy_ae_ccn_t, &
       ae_emit   => atmos_phy_ae_emit
    use mod_atmos_phy_mp_vars, only: &
       evaporate => atmos_phy_mp_evaporate
    implicit none

    logical, intent(in) :: update_flag

    real(RP) :: CN(ka,ia,ja)
    real(RP) :: NREG(ka,ia,ja)

    real(RP) :: total ! dummy

    integer  :: k, i, j, iq
    !---------------------------------------------------------------------------

    if ( update_flag ) then

!OCL XFILL
       ccn(:,:,:)   = 0.0_rp ! reset
!OCL XFILL
       ccn_t(:,:,:)   = 0.0_rp ! reset
!OCL XFILL
       rhoq_t_ae(:,:,:,:) = 0.0_rp ! reset

       nreg(:,:,:) = evaporate(:,:,:) * dt_ae

       call atmos_phy_ae( dens,     & ! [IN]
                          momz,     & ! [IN]
                          momx,     & ! [IN]
                          momy,     & ! [IN]
                          rhot,     & ! [IN]
                          ae_emit,  & ! [IN]
                          nreg,     & ! [IN]
                          qtrc,     & ! [INOUT]
                          cn ,      & ! [OUT]
                          ccn,      & ! [OUT]
                          rhoq_t_ae ) ! [INOUT]

       ccn_t(:,:,:) = ccn(:,:,:) / dt_ae

       call hist_in( cn(:,:,:)*1.e-6_rp, 'CN',  'condensation nucrei',       'num/cc' )
       call hist_in( ccn(:,:,:)*1.e-6_rp, 'CCN', 'cloud condensation nucrei', 'num/cc' )

    endif

    !$omp parallel do private(i,j,k) OMP_SCHEDULE_ collapse(3)
    do iq = 1, qa
    do j  = js, je
    do i  = is, ie
    do k  = ks, ke
       rhoq_t(k,i,j,iq) = rhoq_t(k,i,j,iq) + rhoq_t_ae(k,i,j,iq)
    enddo
    enddo
    enddo
    enddo

    if ( statistics_checktotal ) then
       do iq = 1, qa
          call stat_total( total, rhoq_t_ae(:,:,:,iq), trim(aq_name(iq))//'_t_AE' )
       enddo
    endif

    return
  end subroutine atmos_phy_ae_driver

end module mod_atmos_phy_ae_driver