mod_atmos_phy_ae_vars.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "inc_openmp.h"
module mod_atmos_phy_ae_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_ae_vars_setup
  public :: atmos_phy_ae_vars_fillhalo
  public :: atmos_phy_ae_vars_restart_read
  public :: atmos_phy_ae_vars_restart_write

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,               public :: atmos_phy_ae_restart_output       = .false.                

  character(len=H_LONG), public :: atmos_phy_ae_restart_in_basename  = ''
  character(len=H_LONG), public :: atmos_phy_ae_restart_out_basename = ''
  character(len=H_MID),  public :: atmos_phy_ae_restart_out_title    = 'ATMOS_PHY_AE restart'
  character(len=H_MID),  public :: atmos_phy_ae_restart_out_dtype    = 'DEFAULT'

  real(RP), public, allocatable :: atmos_phy_ae_rhoq_t(:,:,:,:)                               ! tendency rho*QTRC [kg/kg/s]

  real(RP), public, allocatable :: atmos_phy_ae_ccn(:,:,:)                                    ! cloud condensation nuclei [/m3]
  real(RP), public, allocatable :: atmos_phy_ae_ccn_t(:,:,:)                                  ! tendency CCN [/m3/s]
  real(RP), public, allocatable :: atmos_phy_ae_emit(:,:,:,:)                                 ! emission of aerosol and gas
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,                private, parameter :: vmax = 1
  integer,                private, parameter :: i_ccn = 1

  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)

  data var_name / 'CCN' /
  data var_desc / 'cloud condensation nuclei' /
  data var_unit / 'num/m3' /

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_setup
    use scale_process, only: &
       prc_mpistop
    use scale_const, only: &
       undef => const_undef
    implicit none

    namelist / param_atmos_phy_ae_vars / &
       atmos_phy_ae_restart_in_basename,  &
       atmos_phy_ae_restart_output,       &
       atmos_phy_ae_restart_out_basename, &
       atmos_phy_ae_restart_out_title,    &
       atmos_phy_ae_restart_out_dtype

    integer :: ierr
    integer :: iv
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[VARS] / Categ[ATMOS PHY_AE] / Origin[SCALE-RM]'

    allocate( atmos_phy_ae_rhoq_t(ka,ia,ja,qa) )
    atmos_phy_ae_rhoq_t(:,:,:, :) = undef

    allocate( atmos_phy_ae_ccn(ka,ia,ja) )
    atmos_phy_ae_ccn(:,:,:) = undef

    allocate( atmos_phy_ae_ccn_t(ka,ia,ja) )
    atmos_phy_ae_ccn_t(:,:,:) = undef

    allocate( atmos_phy_ae_emit(ka,ia,ja,qa_ae) )
    atmos_phy_ae_emit(:,:,:,:) = 0.0_rp

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_ae_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       if( io_l ) write(io_fid_log,*) '*** Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       write(*,*) 'xxx Not appropriate names in namelist PARAM_ATMOS_PHY_AE_VARS. Check!'
       call prc_mpistop
    endif
    if( io_lnml ) write(io_fid_log,nml=param_atmos_phy_ae_vars)

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** [ATMOS_PHY_AE] prognostic/diagnostic variables'
    if( io_l ) write(io_fid_log,'(1x,A,A15,A,A32,3(A))') &
               '***       |','VARNAME        ','|', 'DESCRIPTION                     ','[', 'UNIT            ',']'
    do iv = 1, vmax
       if( io_l ) write(io_fid_log,'(1x,A,i3,A,A15,A,A32,3(A))') &
                  '*** NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
    enddo

    if( io_l ) write(io_fid_log,*)
    if ( atmos_phy_ae_restart_in_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** Restart input?  : ', trim(atmos_phy_ae_restart_in_basename)
    else
       if( io_l ) write(io_fid_log,*) '*** Restart input?  : NO'
    endif
    if (       atmos_phy_ae_restart_output             &
         .AND. atmos_phy_ae_restart_out_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** Restart output? : ', trim(atmos_phy_ae_restart_out_basename)
    else
       if( io_l ) write(io_fid_log,*) '*** Restart output? : NO'
       atmos_phy_ae_restart_output = .false.
    endif

    return
  end subroutine atmos_phy_ae_vars_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_fillhalo
    use scale_comm, only: &
       comm_vars8, &
       comm_wait
    implicit none

    integer :: i, j
    !---------------------------------------------------------------------------

    do j  = js, je
    do i  = is, ie
       atmos_phy_ae_ccn(   1:ks-1,i,j) = atmos_phy_ae_ccn(ks,i,j)
       atmos_phy_ae_ccn(ke+1:ka,  i,j) = atmos_phy_ae_ccn(ke,i,j)
    enddo
    enddo

    call comm_vars8( atmos_phy_ae_ccn(:,:,:), 1 )
    call comm_wait ( atmos_phy_ae_ccn(:,:,:), 1 )

    return
  end subroutine atmos_phy_ae_vars_fillhalo

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_read
    use scale_fileio, only: &
       fileio_read
    use scale_rm_statistics, only: &
       stat_total
    implicit none

    real(RP) :: total
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Input restart file (ATMOS_PHY_AE) ***'

    if ( atmos_phy_ae_restart_in_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(atmos_phy_ae_restart_in_basename)

       call fileio_read( atmos_phy_ae_ccn(:,:,:),                                     & ! [OUT]
                         atmos_phy_ae_restart_in_basename, var_name(1), 'ZXY', step=1 ) ! [IN]

       call atmos_phy_ae_vars_fillhalo

       call stat_total( total, atmos_phy_ae_ccn(:,:,:), var_name(1) )
    else
       if( io_l ) write(io_fid_log,*) '*** restart file for ATMOS_PHY_AE is not specified.'
    endif

    return
  end subroutine atmos_phy_ae_vars_restart_read

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_write
    use scale_time, only: &
       time_gettimelabel
    use scale_fileio, only: &
       fileio_write
    implicit none

    character(len=20)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    if ( atmos_phy_ae_restart_out_basename /= '' ) then

       call time_gettimelabel( timelabel )
       write(basename,'(A,A,A)') trim(atmos_phy_ae_restart_out_basename), '_', trim(timelabel)

       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Output restart file (ATMOS_PHY_AE) ***'
       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(basename)

       call fileio_write( atmos_phy_ae_ccn(:,:,:), basename,            atmos_phy_ae_restart_out_title, & ! [IN]
                          var_name(1), var_desc(1), var_unit(1), 'ZXY', atmos_phy_ae_restart_out_dtype  ) ! [IN]

    endif

    return
  end subroutine atmos_phy_ae_vars_restart_write

end module mod_atmos_phy_ae_vars