mod_atmos_driver.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
module mod_atmos_driver
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_driver_setup
  public :: atmos_driver_resume1
  public :: atmos_driver_resume2
  public :: atmos_driver
  public :: atmos_driver_finalize
  public :: atmos_surface_get
  public :: atmos_surface_set

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_driver_setup
    use scale_time, only: &
       time_nowdate
    use scale_atmos_solarins, only: &
       atmos_solarins_setup
    use scale_atmos_refstate, only: &
       atmos_refstate_setup
    use scale_atmos_boundary, only: &
       atmos_boundary_setup
    use mod_atmos_dyn_driver, only: &
       atmos_dyn_driver_setup
    use mod_atmos_phy_mp_driver, only: &
       atmos_phy_mp_driver_setup
    use mod_atmos_phy_rd_driver, only: &
       atmos_phy_rd_driver_setup
    use mod_atmos_phy_ch_driver, only: &
       atmos_phy_ch_driver_setup
    use mod_atmos_phy_ae_driver, only: &
       atmos_phy_ae_driver_setup
    use mod_atmos_phy_cp_driver, only: &
       atmos_phy_cp_driver_setup
    use mod_atmos_phy_sf_driver, only: &
       atmos_phy_sf_driver_setup
    use mod_atmos_phy_tb_driver, only: &
       atmos_phy_tb_driver_setup
    implicit none
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[DRIVER] / Categ[ATMOS] / Origin[SCALE-RM]'

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Setup each atmospheric components ...'

    !--- setup solar insolation
    call atmos_solarins_setup( time_nowdate(1) )

    call prof_rapstart('ATM_Refstate', 2)
    call atmos_refstate_setup
    call prof_rapend  ('ATM_Refstate', 2)

    call prof_rapstart('ATM_Boundary', 2)
    call atmos_boundary_setup
    call prof_rapend  ('ATM_Boundary', 2)

    ! setup each components
    call atmos_dyn_driver_setup
    call atmos_phy_mp_driver_setup
    call atmos_phy_ae_driver_setup
    call atmos_phy_ch_driver_setup
    call atmos_phy_rd_driver_setup
    call atmos_phy_sf_driver_setup
    call atmos_phy_tb_driver_setup
    call atmos_phy_cp_driver_setup

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Finish setup of each atmospheric components.'

    return
  end subroutine atmos_driver_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_driver_resume1
    use mod_atmos_vars, only: &
       atmos_vars_diagnostics, &
       dens,                   &
       momz,                   &
       momx,                   &
       momy,                   &
       rhot,                   &
       qtrc,                   &
       dens_tp,                &
       momz_tp,                &
       momx_tp,                &
       momy_tp,                &
       rhot_tp,                &
       rhoq_tp
    use scale_atmos_refstate, only: &
       atmos_refstate_resume
    use scale_atmos_boundary, only: &
       atmos_boundary_resume
    use mod_atmos_phy_mp_driver, only: &
       atmos_phy_mp_driver_resume
    use mod_atmos_phy_rd_driver, only: &
       atmos_phy_rd_driver_resume
    use mod_atmos_phy_ch_driver, only: &
       atmos_phy_ch_driver_resume
    use mod_atmos_phy_ae_driver, only: &
       atmos_phy_ae_driver_resume
    implicit none
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[DRIVER] / Categ[ATMOS] / Origin[SCALE-RM]'

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Resume each atmospheric components 1 ...'

    call prof_rapstart('ATM_Refstate', 2)
    call atmos_refstate_resume( dens, rhot, qtrc )
    call prof_rapend  ('ATM_Refstate', 2)

    call prof_rapstart('ATM_Boundary', 2)
    call atmos_boundary_resume( dens, momz, momx, momy, rhot, qtrc )
    call prof_rapend  ('ATM_Boundary', 2)

    !########## Get Surface Boundary Condition ##########
    call prof_rapstart('ATM_SfcExch', 2)
    call atmos_surface_get
    call prof_rapend  ('ATM_SfcExch', 2)

    !########## initialize tendencies ##########
!OCL XFILL
    dens_tp(:,:,:)   = 0.0_rp
!OCL XFILL
    momz_tp(:,:,:)   = 0.0_rp
!OCL XFILL
    momx_tp(:,:,:)   = 0.0_rp
!OCL XFILL
    momy_tp(:,:,:)   = 0.0_rp
!OCL XFILL
    rhot_tp(:,:,:)   = 0.0_rp
!OCL XFILL
    rhoq_tp(:,:,:,:) = 0.0_rp

    ! setup each components
    call atmos_phy_mp_driver_resume
    call atmos_phy_ae_driver_resume
    call atmos_phy_ch_driver_resume
    call atmos_phy_rd_driver_resume

    !########## Calculate diagnostic variables ##########
    call atmos_vars_diagnostics

    !########## Set Surface Boundary Condition ##########
    call prof_rapstart('ATM_SfcExch', 2)
    call atmos_surface_set( countup = .false. )
    call prof_rapend  ('ATM_SfcExch', 2)

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Finish resume of each atmospheric components 1.'

    return
  end subroutine atmos_driver_resume1

  !-----------------------------------------------------------------------------
  subroutine atmos_driver_resume2
    use mod_atmos_vars, only: &
       atmos_vars_history
    use mod_atmos_phy_cp_driver, only: &
       atmos_phy_cp_driver_resume
    use mod_atmos_phy_sf_driver, only: &
       atmos_phy_sf_driver_resume
    use mod_atmos_phy_tb_driver, only: &
       atmos_phy_tb_driver_resume
    implicit none
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[DRIVER] / Categ[ATMOS] / Origin[SCALE-RM]'

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Resume each atmospheric components 2 ...'

    !########## Get Surface Boundary Condition ##########
    call prof_rapstart('ATM_SfcExch', 2)
    call atmos_surface_get
    call prof_rapend  ('ATM_SfcExch', 2)

    ! setup each components
    call atmos_phy_sf_driver_resume
    call atmos_phy_tb_driver_resume
    call atmos_phy_cp_driver_resume

    !########## Set Surface Boundary Condition ##########
    call prof_rapstart('ATM_SfcExch', 2)
    call atmos_surface_set( countup = .true. )
    call prof_rapend  ('ATM_SfcExch', 2)

    !########## History & Monitor ##########
    call prof_rapstart('ATM_History', 1)
    call atmos_vars_history
    call prof_rapend  ('ATM_History', 1)

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Finish resume of each atmospheric components 2.'

    return
  end subroutine atmos_driver_resume2

  !-----------------------------------------------------------------------------
  subroutine atmos_driver
    use mod_admin_time, only: &
       do_dyn    => time_doatmos_dyn,    &
       do_phy_mp => time_doatmos_phy_mp, &
       do_phy_ae => time_doatmos_phy_ae, &
       do_phy_ch => time_doatmos_phy_ch, &
       do_phy_rd => time_doatmos_phy_rd, &
       do_phy_sf => time_doatmos_phy_sf, &
       do_phy_tb => time_doatmos_phy_tb, &
       do_phy_cp => time_doatmos_phy_cp
    use scale_atmos_refstate, only: &
       atmos_refstate_update_flag, &
       atmos_refstate_update
    use scale_atmos_boundary, only: &
       atmos_boundary_update_flag, &
       atmos_boundary_update
    use mod_atmos_admin, only: &
       atmos_sw_dyn,    &
       atmos_sw_phy_mp, &
       atmos_sw_phy_ae, &
       atmos_sw_phy_ch, &
       atmos_sw_phy_rd, &
       atmos_sw_phy_sf, &
       atmos_sw_phy_tb, &
       atmos_sw_phy_cp
    use mod_atmos_vars, only: &
       atmos_vars_diagnostics, &
       atmos_vars_history,     &
       atmos_vars_monitor,     &
       dens,                   &
       momz,                   &
       momx,                   &
       momy,                   &
       rhot,                   &
       qtrc,                   &
       dens_tp,                &
       momz_tp,                &
       momx_tp,                &
       momy_tp,                &
       rhot_tp,                &
       rhoq_tp
    use mod_atmos_dyn_driver, only: &
       atmos_dyn_driver
    use mod_atmos_phy_mp_driver, only: &
       atmos_phy_mp_driver
    use mod_atmos_phy_ae_driver, only: &
       atmos_phy_ae_driver
    use mod_atmos_phy_ch_driver, only: &
       atmos_phy_ch_driver
    use mod_atmos_phy_rd_driver, only: &
       atmos_phy_rd_driver
    use mod_atmos_phy_sf_driver, only: &
       atmos_phy_sf_driver
    use mod_atmos_phy_tb_driver, only: &
       atmos_phy_tb_driver
    use mod_atmos_phy_cp_driver, only: &
       atmos_phy_cp_driver
    implicit none
    !---------------------------------------------------------------------------

    !########## Get Surface Boundary Condition ##########
    call prof_rapstart('ATM_SfcExch', 2)
    call atmos_surface_get
    call prof_rapend  ('ATM_SfcExch', 2)

    !########## Dynamics ##########
    if ( atmos_sw_dyn ) then
       call prof_rapstart('ATM_Dynamics', 1)
       call atmos_dyn_driver( do_dyn )
       call prof_rapend  ('ATM_Dynamics', 1)
    endif

    !########## Reference State ###########
    if ( atmos_refstate_update_flag ) then
       call prof_rapstart('ATM_Refstate', 2)
       call atmos_refstate_update( dens, rhot, qtrc ) ! [IN]
       call prof_rapend  ('ATM_Refstate', 2)
    endif

    !########## Lateral/Top Boundary Condition ###########
    if ( atmos_boundary_update_flag ) then
       call prof_rapstart('ATM_Boundary', 2)
       call atmos_boundary_update( dens, momz, momx, momy, rhot, qtrc ) ! [INOUT]
       call prof_rapend  ('ATM_Boundary', 2)
    endif

    !########## reset tendencies ##########
!OCL XFILL
    dens_tp(:,:,:)   = 0.0_rp
!OCL XFILL
    momz_tp(:,:,:)   = 0.0_rp
!OCL XFILL
    momx_tp(:,:,:)   = 0.0_rp
!OCL XFILL
    momy_tp(:,:,:)   = 0.0_rp
!OCL XFILL
    rhot_tp(:,:,:)   = 0.0_rp
!OCL XFILL
    rhoq_tp(:,:,:,:) = 0.0_rp

    !########## Calculate diagnostic variables ##########
    call prof_rapstart('ATM_History', 1)
    call atmos_vars_diagnostics
    call prof_rapend  ('ATM_History', 1)

    !########## Microphysics ##########
    if ( atmos_sw_phy_mp ) then
       call prof_rapstart('ATM_Microphysics', 1)
       call atmos_phy_mp_driver( update_flag = do_phy_mp )
       call prof_rapend  ('ATM_Microphysics', 1)
    endif

    !########## Aerosol ##########
    if ( atmos_sw_phy_ae ) then
       call prof_rapstart('ATM_Aerosol', 1)
       call atmos_phy_ae_driver( update_flag = do_phy_ae )
       call prof_rapend  ('ATM_Aerosol', 1)
    endif

    !########## Chemistry ##########
    if ( atmos_sw_phy_ch ) then
       call prof_rapstart('ATM_Chemistry', 1)
       call atmos_phy_ch_driver( update_flag = do_phy_ch )
       call prof_rapend  ('ATM_Chemistry', 1)
    endif

    !########## Radiation ##########
    if ( atmos_sw_phy_rd ) then
       call prof_rapstart('ATM_Radiation', 1)
       call atmos_phy_rd_driver( update_flag = do_phy_rd )
       call prof_rapend  ('ATM_Radiation', 1)
    endif

    !########## Surface Flux ##########
    if ( atmos_sw_phy_sf ) then
       call prof_rapstart('ATM_SurfaceFlux', 1)
       call atmos_phy_sf_driver( update_flag = do_phy_sf )
       call prof_rapend  ('ATM_SurfaceFlux', 1)
    endif

    !########## Turbulence ##########
    if ( atmos_sw_phy_tb ) then
       call prof_rapstart('ATM_Turbulence', 1)
       call atmos_phy_tb_driver( update_flag = do_phy_tb )
       call prof_rapend  ('ATM_Turbulence', 1)
    endif

    !########## Cumulus ##########
    if ( atmos_sw_phy_cp ) then
       call prof_rapstart('ATM_Cumulus', 1)
       call atmos_phy_cp_driver( update_flag = do_phy_cp )
       call prof_rapend  ('ATM_Cumulus', 1)
    endif

    !########## Set Surface Boundary Condition ##########
    call prof_rapstart('ATM_SfcExch', 2)
    call atmos_surface_set( countup = .true. )
    call prof_rapend  ('ATM_SfcExch', 2)

    !########## History & Monitor ##########
    call prof_rapstart('ATM_History', 1)
    call atmos_vars_history
    call atmos_vars_monitor
    call prof_rapend  ('ATM_History', 1)

    return
  end subroutine atmos_driver

  !-----------------------------------------------------------------------------
  subroutine atmos_driver_finalize
    use scale_atmos_boundary, only: &
       atmos_boundary_update_flag, &
       atmos_boundary_finalize
    use scale_grid_nest, only: &
       nest_comm_disconnect
    implicit none
    !---------------------------------------------------------------------------

    !########## Lateral/Top Boundary Condition ###########
    if ( atmos_boundary_update_flag ) then
       ! If this run is parent of online nesting, boundary data must be sent
       call atmos_boundary_finalize

       ! Finialize Inter-Communicators
       call nest_comm_disconnect
    endif

    return
  end subroutine atmos_driver_finalize

  !-----------------------------------------------------------------------------
  subroutine atmos_surface_get
    use mod_atmos_phy_sf_vars, only: &
       sfc_temp   => atmos_phy_sf_sfc_temp,   &
       sfc_albedo => atmos_phy_sf_sfc_albedo, &
       sfc_z0m    => atmos_phy_sf_sfc_z0m,    &
       sfc_z0h    => atmos_phy_sf_sfc_z0h,    &
       sfc_z0e    => atmos_phy_sf_sfc_z0e,    &
       sflx_mw    => atmos_phy_sf_sflx_mw,    &
       sflx_mu    => atmos_phy_sf_sflx_mu,    &
       sflx_mv    => atmos_phy_sf_sflx_mv,    &
       sflx_sh    => atmos_phy_sf_sflx_sh,    &
       sflx_lh    => atmos_phy_sf_sflx_lh,    &
       sflx_gh    => atmos_phy_sf_sflx_gh,    &
       sflx_qtrc  => atmos_phy_sf_sflx_qtrc,  &
       u10        => atmos_phy_sf_u10,        &
       v10        => atmos_phy_sf_v10,        &
       t2         => atmos_phy_sf_t2,         &
       q2         => atmos_phy_sf_q2
    use mod_cpl_admin, only: &
       cpl_sw
    use mod_cpl_vars, only: &
       cpl_getsfc_atm
    implicit none
    !---------------------------------------------------------------------------

    if ( cpl_sw ) then
       call cpl_getsfc_atm( sfc_temp(:,:),   & ! [OUT]
                            sfc_albedo(:,:,:), & ! [OUT]
                            sfc_z0m(:,:),   & ! [OUT]
                            sfc_z0h(:,:),   & ! [OUT]
                            sfc_z0e(:,:),   & ! [OUT]
                            sflx_mw(:,:),   & ! [OUT]
                            sflx_mu(:,:),   & ! [OUT]
                            sflx_mv(:,:),   & ! [OUT]
                            sflx_sh(:,:),   & ! [OUT]
                            sflx_lh(:,:),   & ! [OUT]
                            sflx_gh(:,:),   & ! [OUT]
                            sflx_qtrc(:,:,:), & ! [OUT]
                            u10(:,:),   & ! [OUT]
                            v10(:,:),   & ! [OUT]
                            t2(:,:),   & ! [OUT]
                            q2(:,:)    ) ! [OUT]
    endif

    return
  end subroutine atmos_surface_get

  !-----------------------------------------------------------------------------
  subroutine atmos_surface_set( countup )
    use scale_grid_real, only: &
       real_cz, &
       real_z1
    use scale_topography, only: &
       topo_zsfc
    use scale_atmos_bottom, only: &
       bottom_estimate => atmos_bottom_estimate
    use mod_atmos_vars, only: &
       dens, &
       qtrc, &
       temp, &
       pres, &
       w,    &
       u,    &
       v
    use mod_atmos_phy_mp_vars, only: &
       sflx_rain => atmos_phy_mp_sflx_rain, &
       sflx_snow => atmos_phy_mp_sflx_snow
    use mod_atmos_phy_rd_vars, only: &
       sflx_rad_dn => atmos_phy_rd_sflx_downall, &
       cossza      => atmos_phy_rd_cossza
    use mod_cpl_admin, only: &
       cpl_sw
    use mod_cpl_vars, only: &
       cpl_putatm
    implicit none

    ! arguments
    logical, intent(in) :: countup

    ! works
    real(RP) :: SFC_DENS(ia,ja)
    real(RP) :: SFC_PRES(ia,ja)
    real(RP) :: ATM_PBL (ia,ja)
    !---------------------------------------------------------------------------

    if ( cpl_sw ) then
       ! planetary boundary layer
       atm_pbl(:,:) = 100.0_rp ! tentative

       call bottom_estimate( dens(:,:,:), & ! [IN]
                             pres(:,:,:), & ! [IN]
                             real_cz(:,:,:), & ! [IN]
                             topo_zsfc(:,:),   & ! [IN]
                             real_z1(:,:),   & ! [IN]
                             sfc_dens(:,:),   & ! [OUT]
                             sfc_pres(:,:)    ) ! [OUT]

       call cpl_putatm( temp(ks,:,:),   & ! [IN]
                        pres(ks,:,:),   & ! [IN]
                        w(ks,:,:),   & ! [IN]
                        u(ks,:,:),   & ! [IN]
                        v(ks,:,:),   & ! [IN]
                        dens(ks,:,:),   & ! [IN]
                        qtrc(ks,:,:,:), & ! [IN]
                        atm_pbl(:,:),      & ! [IN]
                        sfc_pres(:,:),      & ! [IN]
                        sflx_rad_dn(:,:,:,:),  & ! [IN]
                        cossza(:,:),      & ! [IN]
                        sflx_rain(:,:),      & ! [IN]
                        sflx_snow(:,:),      & ! [IN]
                        countup                ) ! [IN]
    endif

    return
  end subroutine atmos_surface_set

end module mod_atmos_driver