mod_cnvlanduse.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module mod_cnvlanduse
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_atmos_grid_cartesc_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: cnvlanduse_setup
  public :: cnvlanduse

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical, public :: cnvlanduse_donothing
  logical, public :: cnvlanduse_useglccv2 = .false.
  logical, public :: cnvlanduse_uselu100m = .false.
  logical, public :: cnvlanduse_usejibis  = .false.

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  private :: cnvlanduse_glccv2
  private :: cnvlanduse_lu100m
  private :: cnvlanduse_jibis

  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  real(RP), private :: cnvlanduse_limit_urban_fraction = 1.0_rp 

  real(RP), private :: domain_lats, domain_late
  real(RP), private :: domain_lons, domain_lone
  real(RP), private :: domain_dlat
  real(RP), private, allocatable :: domain_dxy(:,:)

  real(RP), private, parameter :: d_large = 1e20_rp
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine cnvlanduse_setup
    use scale_prc, only: &
       prc_abort
    implicit none

    character(len=H_SHORT) :: CNVLANDUSE_name = 'NONE' ! keep backward compatibility

    namelist / param_cnvlanduse / &
       cnvlanduse_name,                &
       cnvlanduse_useglccv2,           &
       cnvlanduse_uselu100m,           &
!       CNVLANDUSE_UseJIBIS
       cnvlanduse_limit_urban_fraction

    integer  :: ierr
    !---------------------------------------------------------------------------

    log_newline
    log_info("CNVLANDUSE_setup",*) 'Setup'
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_cnvlanduse,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("CNVLANDUSE_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("CNVLANDUSE_setup",*) 'Not appropriate names in namelist PARAM_CNVLANDUSE. Check!'
       call prc_abort
    endif
    log_nml(param_cnvlanduse)

    select case(cnvlanduse_name)
    case('NONE')
       ! do nothing
    case('GLCCv2')
       cnvlanduse_useglccv2 = .true.
       cnvlanduse_uselu100m = .false.
       cnvlanduse_usejibis  = .false.
    case('LU100M')
       cnvlanduse_useglccv2 = .false.
       cnvlanduse_uselu100m = .true.
       cnvlanduse_usejibis  = .false.
    case('COMBINE')
       cnvlanduse_useglccv2 = .true.
       cnvlanduse_uselu100m = .true.
       cnvlanduse_usejibis  = .true.
    case default
       log_error("CNVLANDUSE_setup",*) 'Unsupported TYPE: ', trim(cnvlanduse_name)
       call prc_abort
    endselect

    cnvlanduse_donothing = .true.

    if ( cnvlanduse_useglccv2 ) then
       cnvlanduse_donothing = .false.
       log_info("CNVLANDUSE_setup",*) 'Use GLCC ver.2, global 30 arcsec. data'
       if ( cnvlanduse_uselu100m ) then
          log_info("CNVLANDUSE_setup",*) 'Use KSJ landuse 100m data for Japan region'
          log_info("CNVLANDUSE_setup",*) 'Overwrite Japan region'
          if ( cnvlanduse_usejibis ) then
             log_info("CNVLANDUSE_setup",*) 'Use J-IBIS map 100m data for Japan region'
             log_info("CNVLANDUSE_setup",*) 'Overwrite Japan region (PFT only)'
          endif
       endif
    elseif ( cnvlanduse_uselu100m ) then
       cnvlanduse_donothing = .false.
       log_info("CNVLANDUSE_setup",*) 'Use KSJ landuse 100m data, Japan region only'
       if ( cnvlanduse_usejibis ) then
          log_info("CNVLANDUSE_setup",*) 'Use J-IBIS map 100m data for Japan region'
          log_info("CNVLANDUSE_setup",*) 'Overwrite Japan region (PFT only)'
       endif
    endif

    if ( cnvlanduse_donothing ) then
       log_info("CNVLANDUSE_setup",*) 'Do nothing for landuse index'
    endif

    return
  end subroutine cnvlanduse_setup

  !-----------------------------------------------------------------------------
  subroutine cnvlanduse
    use scale_const, only: &
       eps => const_eps, &
       d2r => const_d2r
    use scale_prc, only: &
       prc_abort
    use scale_sort, only: &
       sort_exec
    use scale_landuse, only: &
       landuse_frac_land,  &
       landuse_frac_lake,  &
       landuse_frac_urban, &
       landuse_pft_mosaic, &
       landuse_pft_nmax,   &
       landuse_frac_pft,   &
       landuse_index_pft,  &
       landuse_calc_fact,  &
       landuse_fillhalo,   &
       landuse_write
    use scale_atmos_grid_cartesc_real, only: &
       latxv => atmos_grid_cartesc_real_latxv, &
       lonuy => atmos_grid_cartesc_real_lonuy, &
       dlat  => atmos_grid_cartesc_real_dlat,  &
       area  => atmos_grid_cartesc_real_area
    implicit none

    real(RP) :: PFT_weight(-2:landuse_pft_nmax,ia,ja)
    integer  :: PFT_idx(landuse_pft_nmax)
    real(RP) :: lake_wgt, ocean_wgt, urban_wgt, land_wgt
    real(RP) :: allsum
    real(RP) :: zerosw

    integer :: i, j, p
    !---------------------------------------------------------------------------

    if ( cnvlanduse_donothing ) then
       log_newline
       log_progress(*) 'skip  convert landuse data'
    else
       log_newline
       log_progress(*) 'start convert landuse data'

       domain_lats = minval( latxv(:,:) )
       domain_late = maxval( latxv(:,:) )
       domain_lons = minval( lonuy(:,:) )
       domain_lone = maxval( lonuy(:,:) )
       domain_dlat = maxval( dlat(:,:) )

       allocate( domain_dxy(ia,ja) )
       do j = 1, ja
       do i = 1, ia
          domain_dxy(i,j) = sqrt( area(i,j) )
       end do
       end do

       log_info("CNVLANDUSE",*) 'Domain Information'
       log_info_cont(*) 'Domain (LAT)    :', domain_lats/d2r, domain_late/d2r
       log_info_cont(*) '       (LON)    :', domain_lons/d2r, domain_lone/d2r


       !$omp parallel do
!OCL XFILL
       do j = 1, ja
       do i = 1, ia
          pft_weight(:,i,j) = 0.0_rp
       end do
       end do

       if ( cnvlanduse_useglccv2 ) then
          call cnvlanduse_glccv2( pft_weight(:,:,:) ) ! [INOUT]
       endif

       if ( cnvlanduse_uselu100m ) then
          call cnvlanduse_lu100m( pft_weight(:,:,:) ) ! [INOUT]
       endif

       if ( cnvlanduse_usejibis ) then
          call cnvlanduse_jibis( pft_weight(:,:,:) ) ! [INOUT]
       endif

       deallocate( domain_dxy )

       !$omp parallel do &
       !$omp private(lake_wgt,ocean_wgt,urban_wgt,land_wgt,allsum,zerosw,PFT_idx)
       do j = js, je
       do i = is, ie

          lake_wgt  = pft_weight(-2,i,j)
          ocean_wgt = pft_weight(-1,i,j)
          urban_wgt = pft_weight( 0,i,j)
          land_wgt  = sum( pft_weight(1:,i,j) )

          do p = 1, landuse_pft_nmax
             pft_idx(p) = p
          end do
          call sort_exec( landuse_pft_nmax, pft_weight(1:,i,j), pft_idx(:) )


          ! total = ocean + lake + urban + land

          ! land fraction : total - ocean / total
          allsum = lake_wgt + ocean_wgt + urban_wgt + land_wgt
          zerosw = 0.5_rp - sign( 0.5_rp, allsum-eps )
          landuse_frac_land(i,j) = ( allsum-ocean_wgt ) * ( 1.0_rp-zerosw ) / ( allsum-zerosw )

          ! lake fraction : lake / ( lake + urban + land )
          allsum = lake_wgt + urban_wgt + land_wgt
          zerosw = 0.5_rp - sign( 0.5_rp, allsum-eps )
          landuse_frac_lake(i,j) = lake_wgt * ( 1.0_rp-zerosw ) / ( allsum-zerosw )

          ! urban fraction : urban / ( urban + land )
          allsum = urban_wgt + land_wgt
          zerosw = 0.5_rp - sign( 0.5_rp, allsum-eps )
          landuse_frac_urban(i,j) = urban_wgt * ( 1.0_rp-zerosw ) / ( allsum-zerosw )

          ! PFT fraction : PFT / sum( PFT(1:mosaic) )
          allsum = sum( pft_weight(landuse_pft_nmax-landuse_pft_mosaic+1:,i,j) )
          if ( allsum > eps ) then
             do p = 1, landuse_pft_mosaic
                landuse_frac_pft(i,j,p) = pft_weight(landuse_pft_nmax-p+1,i,j) / allsum
                landuse_index_pft(i,j,p) = pft_idx(landuse_pft_nmax-p+1)
             enddo
             ! if no second PFT, set to same as PFT1
             if ( abs(landuse_frac_pft(i,j,1)-1.0_rp) <= eps ) then
                landuse_frac_pft(i,j,:) = 0.0_rp
                landuse_frac_pft(i,j,1) = 1.0_rp
                landuse_index_pft(i,j,:) = pft_idx(landuse_pft_nmax)
             endif
          else ! if no PFT, set to bare ground
             landuse_frac_pft(i,j,:) = 0.0_rp
             landuse_frac_pft(i,j,1) = 1.0_rp
             landuse_index_pft(i,j,:) = 1
          endif

       enddo
       enddo

       if ( cnvlanduse_limit_urban_fraction < 1.0_rp ) then
          !$omp parallel do
          do j = js, je
          do i = is, ie
             if ( landuse_frac_urban(i,j) == 1.0_rp ) then ! if no PFT, set to grassland
                landuse_frac_pft(i,j,:) = 0.0_rp
                landuse_frac_pft(i,j,1) = 1.0_rp
                landuse_index_pft(i,j,:) = 2     ! Grassland
             endif
             landuse_frac_urban(i,j) = min( landuse_frac_urban(i,j), cnvlanduse_limit_urban_fraction )
          enddo
          enddo
       endif

       ! calculate landuse factors
       call landuse_fillhalo( fill_bnd=.true. )
       call landuse_calc_fact

       log_progress(*) 'end   convert landuse data'

       ! output landuse file
       call landuse_write

    endif

    return
  end subroutine cnvlanduse

  !-----------------------------------------------------------------------------
  subroutine cnvlanduse_glccv2( PFT_weight )
    use scale_prc, only: &
       prc_abort
    use scale_const, only: &
       radius => const_radius, &
       d2r    => const_d2r
    use scale_atmos_grid_cartesc, only: &
       fx => atmos_grid_cartesc_fx, &
       fy => atmos_grid_cartesc_fy, &
       cx => atmos_grid_cartesc_cx, &
       cy => atmos_grid_cartesc_cy
    use scale_file_tiledata, only: &
       file_tiledata_get_info, &
       file_tiledata_get_data
    use scale_mapprojection, only: &
       mapprojection_lonlat2xy
    use scale_landuse, only: &
       landuse_pft_nmax
    implicit none

    real(RP), intent(inout) :: PFT_weight(-2:landuse_pft_nmax,ia,ja)

    character(len=H_LONG) :: GLCCv2_IN_DIR        = '.'
    character(len=H_LONG) :: GLCCv2_IN_CATALOGUE  = ''

    namelist / param_cnvlanduse_glccv2 / &
       glccv2_in_dir,       &
       glccv2_in_catalogue

    ! GLCCv2 data
    integer,  parameter :: categ_nmax = 25
    real(RP), parameter :: GLCCv2_DLAT = 30.0_rp / 60.0_rp / 60.0_rp ! 30 arc sec.
    real(RP), parameter :: GLCCv2_DLON = 30.0_rp / 60.0_rp / 60.0_rp ! 30 arc sec.

    integer  :: lookuptable(1:categ_nmax)
    data lookuptable /  0, & !   1 Urban and Built-Up Land        ->  0 urban
                        7, & !   2 Dryland Cropland and Pasture   ->  7 Dryland Cropland and Pasture
                        8, & !   3 Irrigated Cropland and Pasture ->  8 Irrigated Cropland and Pasture
                        9, & !   4 Mixed Cropland and Pasture     ->  9 Mixed Cropland and Pasture
                        5, & !   5 Cropland/Grassland Mosaic      ->  5 Cropland/Grassland Mosaic
                        6, & !   6 Cropland/Woodland Mosaic       ->  6 Cropland/Woodland Mosaic
                        2, & !   7 Grassland                      ->  2 Grassland
                        3, & !   8 Shrubland                      ->  3 Shrubland
                        4, & !   9 Mixed Shrubland/Grassland      ->  4 Mixed Shrubland/Grassland
                        4, & !  10 Savanna                        ->  4 Mixed Shrubland/Grassland
                       11, & !  11 Deciduous Broadleaf Forest     -> 11 Deciduous Broadleaf Forest
                       12, & !  12 Deciduous Needleleaf Forest    -> 12 Deciduous Needleleaf Forest
                       13, & !  13 Evergreen Broadleaf Forest     -> 13 Deciduous Broadleaf Forest
                       14, & !  14 Evergreen Needleleaf Forest    -> 14 Deciduous Needleleaf Forest
                       15, & !  15 Mixed Forest                   -> 15 Mixed Forest
                       -2, & !  16 Water Bodies                   -> -2 Lake/River
                       10, & !  17 Herbaceous Wetland             -> 10 Paddy
                       10, & !  18 Wooded Wetland                 -> 10 Paddy
                        1, & !  19 Barren or Sparsely Vegetated   ->  1 Dessert
                       16, & !  20 Herbaceous Tundra              -> 16 Tundra
                       16, & !  21 Wooded Tundra                  -> 16 Tundra
                       16, & !  22 Mixed Tundra                   -> 16 Tundra
                       16, & !  23 Bare Ground Tundra             -> 16 Tundra
                       17, & !  24 Snow or Ice                    -> 17 Gracier
                       -1  / !  25+ Sea Surface                   -> -1 Sea Surface

    !---------------------------------------------------------------------------

    ! data catalogue list
    integer, parameter    :: TILE_nlim = 100
    integer               :: TILE_nmax
    character(len=H_LONG) :: TILE_fname(tile_nlim)
    logical               :: TILE_hit  (tile_nlim)
    integer               :: TILE_JS   (tile_nlim)
    integer               :: TILE_JE   (tile_nlim)
    integer               :: TILE_IS   (tile_nlim)
    integer               :: TILE_IE   (tile_nlim)
    real(RP)              :: TILE_DLAT, TILE_DLON

    integer,  allocatable :: LANDUSE(:,:)
    real(RP), allocatable :: LATH(:,:), LONH(:,:)
    real(RP), allocatable :: XH(:,:), YH(:,:)
    integer               :: nLONH, nLATH

    integer  :: GLOBAL_IA

    character(len=H_LONG) :: fname

    logical  :: hit, no_hit_x
    real(RP) :: dmin, d
    integer  :: min_i, min_j
    real(RP) :: limit

    integer :: ish, ieh, jsh, jeh
    integer :: lu
    integer :: ierr
    integer :: i, j, ii, jj, p
    !---------------------------------------------------------------------------

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_cnvlanduse_glccv2,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("CNVLANDUSE_GLCCv2",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("CNVLANDUSE_GLCCv2",*) 'Not appropriate names in namelist PARAM_CNVLANDUSE_GLCCv2. Check!'
       call prc_abort
    endif
    log_nml(param_cnvlanduse_glccv2)


    tile_dlat = glccv2_dlat * d2r
    tile_dlon = glccv2_dlon * d2r

    ! catalogue file
    fname = trim(glccv2_in_dir)//'/'//trim(glccv2_in_catalogue)

    call file_tiledata_get_info( tile_nlim,                                          & ! [IN]
                                 tile_dlat, tile_dlon,                               & ! [IN]
                                 domain_lats, domain_late, domain_lons, domain_lone, & ! [IN]
                                 fname,                                              & ! [IN]
                                 global_ia,                                          & ! [OUT]
                                 tile_nmax,                                          & ! [OUT]
                                 tile_fname(:), tile_hit(:),                         & ! [OUT]
                                 tile_js(:), tile_je(:), tile_is(:), tile_ie(:),     & ! [OUT]
                                 nlath, nlonh, jsh, jeh, ish, ieh                    ) ! [OUT]

    allocate( landuse(nlonh,nlath) )
    allocate( lath(nlonh,nlath) )
    allocate( lonh(nlonh,nlath) )
    allocate( yh(nlonh,nlath) )
    allocate( xh(nlonh,nlath) )

    call file_tiledata_get_data( nlath, nlonh,                                   & ! [IN]
                                 glccv2_in_dir,                                  & ! [IN]
                                 global_ia,                                      & ! [IN]
                                 tile_nmax,                                      & ! [IN]
                                 tile_dlat, tile_dlon,                           & ! [IN]
                                 tile_fname(:), tile_hit(:),                     & ! [IN]
                                 tile_js(:), tile_je(:), tile_is(:), tile_ie(:), & ! [IN]
                                 jsh, jeh, ish, ieh,                             & ! [IN]
                                 "INT1",                                         & ! [IN]
                                 landuse(:,:), lath(:,:), lonh(:,:)              ) ! [OUT]

    call mapprojection_lonlat2xy( nlonh, 1, nlonh, nlath, 1, nlath, &
                                  lonh(:,:), lath(:,:), & ! [IN]
                                  xh(:,:), yh(:,:)      ) ! [OUT]

    limit = ( tile_dlat * radius * 1.5_rp )**2
    !$omp parallel do collapse(2) &
    !$omp private(hit,no_hit_x,lu,p,dmin,min_i,min_j,d)
    do j = 1, ja
    do i = 1, ia
       hit = .false.
       dmin = d_large
       min_i = -1
       min_j = -1
       do jj = 1, nlath
          no_hit_x = .true.
          do ii = 1, nlonh
             if (       fx(i-1) <= xh(ii,jj) .and. xh(ii,jj) < fx(i) &
                  .and. fy(j-1) <= yh(ii,jj) .and. yh(ii,jj) < fy(j) ) then
                no_hit_x = .false.
                lu = min( landuse(ii,jj), categ_nmax )
                if ( 1 <= lu ) then
                   p = lookuptable(lu)
                   pft_weight(p,i,j) = pft_weight(p,i,j) + cos(lath(ii,jj)) ! area weight
                   hit = .true.
                   cycle
                end if
             end if
             d = ( xh(ii,jj)-cx(i) )**2 + ( yh(ii,jj)-cy(j) )**2
             lu = min( landuse(ii,jj), categ_nmax )
             if ( d < dmin .and. 1 <= lu ) then
                dmin = d
                min_i = ii
                min_j = jj
             end if
          end do
          if ( hit .and. no_hit_x ) exit
       end do
       if ( ( .not. hit ) .and. dmin < limit ) then
          lu = min( landuse(min_i,min_j), categ_nmax )
          p = lookuptable(lu)
          pft_weight(p,i,j) = 1.0_rp
       end if
    end do
    end do

    deallocate( landuse, lath, lonh, yh, xh )

    return
  end subroutine cnvlanduse_glccv2

  !-----------------------------------------------------------------------------
  subroutine cnvlanduse_lu100m( PFT_weight )
    use scale_prc, only: &
       prc_abort
    use scale_const, only: &
       undef2 => const_undef2, &
       radius => const_radius, &
       d2r    => const_d2r
    use scale_atmos_grid_cartesc, only: &
       fx => atmos_grid_cartesc_fx, &
       fy => atmos_grid_cartesc_fy, &
       cx => atmos_grid_cartesc_cx, &
       cy => atmos_grid_cartesc_cy
    use scale_file_tiledata, only: &
       file_tiledata_get_info, &
       file_tiledata_get_data
    use scale_mapprojection, only: &
       mapprojection_lonlat2xy
    use scale_landuse, only: &
       landuse_pft_nmax
    implicit none

    real(RP), intent(inout) :: PFT_weight(-2:landuse_pft_nmax,ia,ja)

    character(len=H_LONG) :: LU100M_IN_DIR       = '.'
    character(len=H_LONG) :: LU100M_IN_CATALOGUE = ''

    namelist / param_cnvlanduse_lu100m / &
       lu100m_in_dir,       &
       lu100m_in_catalogue

    ! LU100M data
    integer,  parameter :: categ_nmax = 16
    real(RP), parameter :: LU100M_DLAT = 5.0_rp / 60.0_rp / 100.0_rp
    real(RP), parameter :: LU100M_DLON = 7.5_rp / 60.0_rp / 100.0_rp

    integer  :: lookuptable(0:16)
    data lookuptable / -1, & ! -999 missing      -> -1 Sea Surface
                       10, & !  1 paddy          -> 10 Paddy
                        9, & !  2 cropland       ->  9 Mixed Cropland and Pasture
                        1, & !  3 UNDEF          ->  1 Dessert
                        1, & !  4 UNDEF          ->  1 Dessert
                       11, & !  5 forest         -> 11 Deciduous Broadleaf Forest
                        1, & !  6 bareground     ->  1 Dessert
                        0, & !  7 urban building ->  0 Urban and Built-up Land
                        1, & !  8 UNDEF          ->  1 Dessert
                        0, & !  9 motorway       ->  0 Urban and Built-up Land
                        0, & ! 10 urban ground   ->  0 Urban and Built-up Land
                       -2, & ! 11 lake,river     -> -2 Lake/River
                        1, & ! 12 UNDEF          ->  1 Dessert
                        1, & ! 13 UNDEF          ->  1 Dessert
                        1, & ! 14 seashore       ->  1 Dessert
                       -1, & ! 15 ocean          -> -1 Sea Surface
                        2  / ! 16 golf course    ->  2 Grassland

    !---------------------------------------------------------------------------

    ! data catalogue list
    integer, parameter    :: TILE_nlim = 1000
    integer               :: TILE_nmax
    character(len=H_LONG) :: TILE_fname(tile_nlim)
    logical               :: TILE_hit  (tile_nlim)
    integer               :: TILE_JS   (tile_nlim)
    integer               :: TILE_JE   (tile_nlim)
    integer               :: TILE_IS   (tile_nlim)
    integer               :: TILE_IE   (tile_nlim)
    real(RP)              :: TILE_DLAT, TILE_DLON

    integer,  allocatable :: LANDUSE(:,:)
    real(RP), allocatable :: LATH   (:,:)
    real(RP), allocatable :: LONH   (:,:)
    real(RP), allocatable :: XH(:,:), YH(:,:)
    integer               :: nLONH, nLATH

    integer  :: GLOBAL_IA

    character(len=H_LONG) :: fname

    logical  :: hit, no_hit_x
    real(RP) :: dmin, d
    integer  :: min_i, min_j
    real(RP) :: limit

    integer :: ish, ieh, jsh, jeh
    integer :: lu
    integer :: ierr
    integer :: i, j, ii, jj, p
    !---------------------------------------------------------------------------

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_cnvlanduse_lu100m,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("CNVLANDUSE_LU100M",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("CNVLANDUSE_LU100M",*) 'Not appropriate names in namelist PARAM_CNVLANDUSE_LU100M. Check!'
       call prc_abort
    endif
    log_nml(param_cnvlanduse_lu100m)


    tile_dlat = lu100m_dlat * d2r
    tile_dlon = lu100m_dlon * d2r

    ! catalogue file
    fname = trim(lu100m_in_dir)//'/'//trim(lu100m_in_catalogue)

    call file_tiledata_get_info( tile_nlim,                                          & ! [IN]
                                 tile_dlat, tile_dlon,                               & ! [IN]
                                 domain_lats, domain_late, domain_lons, domain_lone, & ! [IN]
                                 fname,                                              & ! [IN]
                                 global_ia,                                          & ! [OUT]
                                 tile_nmax,                                          & ! [OUT]
                                 tile_fname(:), tile_hit(:),                         & ! [OUT]
                                 tile_js(:), tile_je(:), tile_is(:), tile_ie(:),     & ! [OUT]
                                 nlath, nlonh, jsh, jeh, ish, ieh                    ) ! [OUT]

    if ( .not. any(tile_hit(1:tile_nmax) ) ) return

    allocate( landuse(nlonh,nlath) )
    allocate( lath(nlonh,nlath) )
    allocate( lonh(nlonh,nlath) )
    allocate( yh(nlonh,nlath) )
    allocate( xh(nlonh,nlath) )

    call file_tiledata_get_data( nlath, nlonh,                                   & ! [IN]
                                 lu100m_in_dir,                                  & ! [IN]
                                 global_ia,                                      & ! [IN]
                                 tile_nmax,                                      & ! [IN]
                                 tile_dlat, tile_dlon,                           & ! [IN]
                                 tile_fname(:), tile_hit(:),                     & ! [IN]
                                 tile_js(:), tile_je(:), tile_is(:), tile_ie(:), & ! [IN]
                                 jsh, jeh, ish, ieh,                             & ! [IN]
                                 "REAL4",                                        & ! [IN]
                                 landuse(:,:), lath(:,:), lonh(:,:),             & ! [OUT]
                                 min_value = -999                                ) ! [IN]

    call mapprojection_lonlat2xy( nlonh, 1, nlonh, nlath, 1, nlath, &
                                  lonh(:,:), lath(:,:), & ! [IN]
                                  xh(:,:), yh(:,:)      ) ! [OUT]

    limit = ( tile_dlat * radius * 1.5_rp )**2
    !$omp parallel do collapse(2) &
    !$omp private(hit,no_hit_x,lu,p,dmin,min_i,min_j,d)
    do j = 1, ja
    do i = 1, ia
       hit = .false.
       dmin = d_large
       min_i = -1
       min_j = -1
       do jj = 1, nlath
          no_hit_x = .true.
          do ii = 1, nlonh
             if (       fx(i-1) <= xh(ii,jj) .and. xh(ii,jj) < fx(i) &
                  .and. fy(j-1) <= yh(ii,jj) .and. yh(ii,jj) < fy(j) ) then
                no_hit_x = .false.
                lu = landuse(ii,jj)
                if ( lu /= undef2 ) then
                   p = lookuptable( max(0,lu) ) ! -999 to 0
                   pft_weight(p,i,j) = pft_weight(p,i,j) + 1.0_rp
                   hit = .true.
                   cycle
                end if
             end if
             d = ( xh(ii,jj)-cx(i) )**2 + ( yh(ii,jj)-cy(j) )**2
             lu = landuse(ii,jj)
             if ( d < dmin .and. lu /= undef2 ) then
                dmin = d
                min_i = ii
                min_j = jj
             end if
          end do
          if ( hit .and. no_hit_x ) exit
       end do
       if ( ( .not. hit ) .and. dmin < limit ) then
          lu = landuse(min_i,min_j)
          if ( lu /= undef2 ) then
             p = lookuptable( max(0,lu) ) ! -999 to 0
             pft_weight(p,i,j) = 1.0_rp
          end if
       end if
    end do
    end do

    deallocate( landuse, lath, lonh, yh, xh )

    return
  end subroutine cnvlanduse_lu100m

  !-----------------------------------------------------------------------------
  subroutine cnvlanduse_jibis( PFT_weight )
    use scale_landuse, only: &
       landuse_pft_nmax
    implicit none

    real(RP), intent(inout) :: PFT_weight(-2:landuse_pft_nmax,ia,ja)
    !---------------------------------------------------------------------------

    return
  end subroutine cnvlanduse_jibis

end module mod_cnvlanduse