mod_atmos_phy_ae_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module mod_atmos_phy_ae_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_atmos_grid_cartesc_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_ae_vars_setup
  public :: atmos_phy_ae_vars_fillhalo
  public :: atmos_phy_ae_vars_restart_read
  public :: atmos_phy_ae_vars_restart_write

  public :: atmos_phy_ae_vars_restart_create
  public :: atmos_phy_ae_vars_restart_open
  public :: atmos_phy_ae_vars_restart_def_var
  public :: atmos_phy_ae_vars_restart_enddef
  public :: atmos_phy_ae_vars_restart_close

  public :: atmos_phy_ae_vars_history

  public :: atmos_phy_ae_vars_get_diagnostic
  public :: atmos_phy_ae_vars_reset_diagnostics

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,                public :: atmos_phy_ae_restart_output                = .false.                

  character(len=H_LONG),  public :: atmos_phy_ae_restart_in_basename           = ''
  logical,                public :: atmos_phy_ae_restart_in_aggregate
  logical,                public :: atmos_phy_ae_restart_in_postfix_timelabel  = .false.                
  character(len=H_LONG),  public :: atmos_phy_ae_restart_out_basename          = ''
  logical,                public :: atmos_phy_ae_restart_out_aggregate
  logical,                public :: atmos_phy_ae_restart_out_postfix_timelabel = .true.                 
  character(len=H_MID),   public :: atmos_phy_ae_restart_out_title             = 'ATMOS_PHY_AE restart'
  character(len=H_SHORT), public :: atmos_phy_ae_restart_out_dtype             = 'DEFAULT'

  real(RP), public, allocatable :: atmos_phy_ae_rhoq_t(:,:,:,:)                               ! tendency rho*QTRC [kg/kg/s]

  real(RP), public, allocatable :: atmos_phy_ae_ccn(:,:,:)                                    ! cloud condensation nuclei [/m3]
  real(RP), public, allocatable :: atmos_phy_ae_ccn_t(:,:,:)                                  ! tendency CCN [/m3/s]
  real(RP), public, allocatable :: atmos_phy_ae_emit(:,:,:,:)                                 ! emission of aerosol and gas

  integer, public :: qa_ae = 0
  integer, public :: qs_ae = -1
  integer, public :: qe_ae = -2

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,                private, parameter :: vmax  = 1
  integer,                private, parameter :: i_ccn = 1

  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)
  integer,                private            :: var_id(vmax)
  integer,                private            :: restart_fid = -1  ! file ID

  data var_name / 'CCN' /
  data var_desc / 'cloud condensation nuclei' /
  data var_unit / 'num/m3' /


  ! for diagnostics
  real(RP), private, allocatable :: atmos_phy_ae_re(:,:,:,:)
  real(RP), private, allocatable :: atmos_phy_ae_qe(:,:,:,:)
  logical, private :: diag_re
  logical, private :: diag_qe

  ! for history
  integer, private,allocatable :: hist_re_id(:)
  logical, private             :: hist_re

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_setup
    use scale_prc, only: &
       prc_abort
    use scale_const, only: &
       undef => const_undef
    use scale_atmos_aerosol, only: &
       n_ae, &
       ae_name, &
       ae_desc
    use scale_file_history, only: &
       file_history_reg
    implicit none

    namelist / param_atmos_phy_ae_vars / &
       atmos_phy_ae_restart_in_basename,           &
       atmos_phy_ae_restart_in_aggregate,          &
       atmos_phy_ae_restart_in_postfix_timelabel,  &
       atmos_phy_ae_restart_output,                &
       atmos_phy_ae_restart_out_basename,          &
       atmos_phy_ae_restart_out_aggregate,         &
       atmos_phy_ae_restart_out_postfix_timelabel, &
       atmos_phy_ae_restart_out_title,             &
       atmos_phy_ae_restart_out_dtype

    integer :: ierr
    integer :: iv
    !---------------------------------------------------------------------------

    log_newline
    log_info("ATMOS_PHY_AE_vars_setup",*) 'Setup'

    allocate( atmos_phy_ae_rhoq_t(ka,ia,ja,qs_ae:qe_ae) )
    atmos_phy_ae_rhoq_t(:,:,:, :) = undef

    allocate( atmos_phy_ae_ccn(ka,ia,ja) )
    atmos_phy_ae_ccn(:,:,:) = undef

    allocate( atmos_phy_ae_ccn_t(ka,ia,ja) )
    atmos_phy_ae_ccn_t(:,:,:) = undef

    allocate( atmos_phy_ae_emit(ka,ia,ja,qs_ae:qe_ae) )
    atmos_phy_ae_emit(:,:,:,:) = 0.0_rp

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_ae_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("ATMOS_PHY_AE_vars_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("ATMOS_PHY_AE_vars_setup",*) 'Not appropriate names in namelist PARAM_ATMOS_PHY_AE_VARS. Check!'
       call prc_abort
    endif
    log_nml(param_atmos_phy_ae_vars)

    log_newline
    log_info("ATMOS_PHY_AE_vars_setup",*) '[ATMOS_PHY_AE] prognostic/diagnostic variables'
    log_info_cont('(1x,A,A24,A,A48,A,A12,A)') &
               '      |', 'VARNAME                 ','|', &
               'DESCRIPTION                                     ', '[', 'UNIT        ', ']'
    do iv = 1, vmax
       log_info_cont('(1x,A,I3,A,A24,A,A48,A,A12,A)') &
                  'NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
    enddo

    log_newline
    if ( atmos_phy_ae_restart_in_basename /= '' ) then
       log_info("ATMOS_PHY_AE_vars_setup",*) 'Restart input?  : YES, file = ', trim(atmos_phy_ae_restart_in_basename)
       log_info("ATMOS_PHY_AE_vars_setup",*) 'Add timelabel?  : ', atmos_phy_ae_restart_in_postfix_timelabel
    else
       log_info("ATMOS_PHY_AE_vars_setup",*) 'Restart input?  : NO'
    endif
    if (       atmos_phy_ae_restart_output             &
         .AND. atmos_phy_ae_restart_out_basename /= '' ) then
       log_info("ATMOS_PHY_AE_vars_setup",*) 'Restart output? : YES, file = ', trim(atmos_phy_ae_restart_out_basename)
       log_info("ATMOS_PHY_AE_vars_setup",*) 'Add timelabel?  : ', atmos_phy_ae_restart_out_postfix_timelabel
    else
       log_info("ATMOS_PHY_AE_vars_setup",*) 'Restart output? : NO'
       atmos_phy_ae_restart_output = .false.
    endif

    ! diagnostices
    allocate( atmos_phy_ae_re(ka,ia,ja,n_ae) )
    allocate( atmos_phy_ae_qe(ka,ia,ja,n_ae) )
!OCL XFILL
    atmos_phy_ae_re(:,:,:,:) = undef
!OCL XFILL
    atmos_phy_ae_qe(:,:,:,:) = undef
    diag_re = .false.
    diag_qe = .false.

    ! history
    hist_re = .false.
    allocate( hist_re_id(n_ae) )
    do iv = 1, n_ae
       call file_history_reg( 'Re_'//trim(ae_name(iv)), 'effective radius of '//trim(ae_desc(iv)), 'cm', hist_re_id(iv), fill_halo=.true., dim_type='ZXY' )
       if ( hist_re_id(iv) > 0 ) hist_re = .true.
    end do

    return
  end subroutine atmos_phy_ae_vars_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_fillhalo
    use scale_comm_cartesc, only: &
       comm_vars8, &
       comm_wait
    implicit none

    integer :: i, j
    !---------------------------------------------------------------------------

    do j  = js, je
    do i  = is, ie
       atmos_phy_ae_ccn(   1:ks-1,i,j) = atmos_phy_ae_ccn(ks,i,j)
       atmos_phy_ae_ccn(ke+1:ka,  i,j) = atmos_phy_ae_ccn(ke,i,j)
    enddo
    enddo

    call comm_vars8( atmos_phy_ae_ccn(:,:,:), 1 )
    call comm_wait ( atmos_phy_ae_ccn(:,:,:), 1 )

    return
  end subroutine atmos_phy_ae_vars_fillhalo

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_open
    use scale_time, only: &
       time_gettimelabel
    use scale_file_cartesc, only: &
       file_cartesc_open
    implicit none

    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    log_newline
    log_info("ATMOS_PHY_AE_vars_restart_open",*) 'Open restart file (ATMOS_PHY_AE) '

    if ( atmos_phy_ae_restart_in_basename /= '' ) then

       if ( atmos_phy_ae_restart_in_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_ae_restart_in_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_ae_restart_in_basename)
       endif

       log_info("ATMOS_PHY_AE_vars_restart_open",*) 'basename: ', trim(basename)

       call file_cartesc_open( basename, restart_fid, aggregate=atmos_phy_ae_restart_in_aggregate )
    else
       log_info("ATMOS_PHY_AE_vars_restart_open",*) 'restart file for ATMOS_PHY_AE is not specified.'
    endif

    return
  end subroutine atmos_phy_ae_vars_restart_open

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_read
    use scale_statistics, only: &
       statistics_checktotal, &
       statistics_total
    use scale_atmos_grid_cartesc_real, only: &
       atmos_grid_cartesc_real_vol, &
       atmos_grid_cartesc_real_totvol
    use scale_file, only: &
       file_get_aggregate
    use scale_file_cartesc, only: &
       file_cartesc_read, &
       file_cartesc_flush
    implicit none

    integer  :: i, j
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       log_newline
       log_info("ATMOS_PHY_AE_vars_restart_read",*) 'Read from restart file (ATMOS_PHY_AE) '

       call file_cartesc_read( restart_fid, var_name(1), 'ZXY', & ! [IN]
                               atmos_phy_ae_ccn(:,:,:)          ) ! [OUT]

       if ( file_get_aggregate(restart_fid) ) then
          call file_cartesc_flush( restart_fid ) ! X/Y halos have been read from file

          ! fill K halos
          do j  = 1, ja
          do i  = 1, ia
             atmos_phy_ae_ccn(   1:ks-1,i,j) = atmos_phy_ae_ccn(ks,i,j)
             atmos_phy_ae_ccn(ke+1:ka,  i,j) = atmos_phy_ae_ccn(ke,i,j)
          enddo
          enddo
       else
          call atmos_phy_ae_vars_fillhalo
       end if

       if ( statistics_checktotal ) then
          call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                                 atmos_phy_ae_ccn(:,:,:), var_name(1), &
                                 atmos_grid_cartesc_real_vol(:,:,:),   & ! (in)
                                 atmos_grid_cartesc_real_totvol        ) ! (in)
       end if
    else
       log_info("ATMOS_PHY_AE_vars_restart_read",*) 'invlaid restart file ID for ATMOS_PHY_AE.'
    endif

    return
  end subroutine atmos_phy_ae_vars_restart_read

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_create
    use scale_time, only: &
       time_gettimelabel
    use scale_file_cartesc, only: &
       file_cartesc_create
    implicit none

    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    if ( atmos_phy_ae_restart_out_basename /= '' ) then

       log_newline
       log_info("ATMOS_PHY_AE_vars_restart_create",*) 'Create restart file (ATMOS_PHY_AE) '

       if ( atmos_phy_ae_restart_out_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_ae_restart_out_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_ae_restart_out_basename)
       endif

       log_info("ATMOS_PHY_AE_vars_restart_create",*) 'basename: ', trim(basename)

       call file_cartesc_create( &
            basename, atmos_phy_ae_restart_out_title, atmos_phy_ae_restart_out_dtype, & ! [IN]
            restart_fid,                                                              & ! [OUT]
            aggregate=atmos_phy_ae_restart_out_aggregate                              ) ! [IN]

    endif

    return
  end subroutine atmos_phy_ae_vars_restart_create

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_enddef
    use scale_file_cartesc, only: &
       file_cartesc_enddef
    implicit none

    if ( restart_fid /= -1 ) then
       call file_cartesc_enddef( restart_fid ) ! [IN]
    endif

    return
  end subroutine atmos_phy_ae_vars_restart_enddef

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_close
    use scale_file_cartesc, only: &
       file_cartesc_close
    implicit none
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       log_newline
       log_info("ATMOS_PHY_AE_vars_restart_close",*) 'Close restart file (ATMOS_PHY_AE) '

       call file_cartesc_close( restart_fid ) ! [IN]

       restart_fid = -1
    endif

    return
  end subroutine atmos_phy_ae_vars_restart_close

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_def_var
    use scale_file_cartesc, only: &
       file_cartesc_def_var
    implicit none
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then
       call file_cartesc_def_var( restart_fid, var_name(1), var_desc(1), var_unit(1), 'ZXY', atmos_phy_ae_restart_out_dtype, &
                                  var_id(1) )
    endif

    return
  end subroutine atmos_phy_ae_vars_restart_def_var

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_vars_restart_write
    use scale_statistics, only: &
       statistics_checktotal, &
       statistics_total
    use scale_atmos_grid_cartesc_real, only: &
       atmos_grid_cartesc_real_vol, &
       atmos_grid_cartesc_real_totvol
    use scale_file_cartesc, only: &
       file_cartesc_write_var
    implicit none
    !---------------------------------------------------------------------------

    if ( restart_fid /= -1 ) then

       call atmos_phy_ae_vars_fillhalo

       if ( statistics_checktotal ) then
          call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                                 atmos_phy_ae_ccn(:,:,:), var_name(1), &
                                 atmos_grid_cartesc_real_vol(:,:,:),   & ! (in)
                                 atmos_grid_cartesc_real_totvol        ) ! (in)
       end if

       call file_cartesc_write_var( restart_fid, var_id(1), atmos_phy_ae_ccn(:,:,:), var_name(1), 'ZXY' ) ! [IN]

    endif

    return
  end subroutine atmos_phy_ae_vars_restart_write

  subroutine atmos_phy_ae_vars_history( &
       QTRC, RH )
    use scale_tracer, only: &
       qa
    use scale_atmos_aerosol, only: &
       n_ae
    use scale_file_history, only: &
       file_history_put
    real(RP), intent(in) :: QTRC(ka,ia,ja,qa)
    real(RP), intent(in) :: RH(ka,ia,ja)

    real(RP) :: WORK(ka,ia,ja,n_ae)
    integer  :: iv

    if ( hist_re ) then
       call atmos_phy_ae_vars_get_diagnostic( &
            qtrc(:,:,:,:), rh(:,:,:), & ! [IN]
            re=work(:,:,:,:)          ) ! [OUT]
       do iv = 1, n_ae
          if ( hist_re_id(iv) > 0 ) &
               call file_history_put( hist_re_id(iv), work(:,:,:,iv) )
       end do
    end if

    return
  end subroutine atmos_phy_ae_vars_history

  subroutine atmos_phy_ae_vars_get_diagnostic( &
       QTRC, RH, &
       Re, Qe   )
    use scale_tracer, only: &
       qa
    use scale_atmos_aerosol, only: &
       n_ae
    use scale_atmos_phy_ae_kajino13, only: &
       atmos_phy_ae_kajino13_effective_radius
    use mod_atmos_admin, only: &
       atmos_phy_ae_type

    real(RP), intent(in) :: QTRC(ka,ia,ja,qa)
    real(RP), intent(in) :: RH(ka,ia,ja)
    real(RP), intent(out), optional :: Re(ka,ia,ja,n_ae)
    real(RP), intent(out), optional :: Qe(ka,ia,ja,n_ae)

    if ( present(re) ) then
       if ( .not. diag_re ) then
          select case ( atmos_phy_ae_type )
          case ( 'KAJINO13' )
             call atmos_phy_ae_kajino13_effective_radius( &
                     ka, ia, ja, qa_ae, &
                     qtrc(:,:,:,qs_ae:qe_ae), rh(:,:,:), & ! [IN]
                     atmos_phy_ae_re(:,:,:,:)            ) ! [OUT]
          case default
             atmos_phy_ae_re(:,:,:,:) = 0.0_rp
          end select
          diag_re = .true.
       end if
!OCL XFILL
       re(:,:,:,:) = atmos_phy_ae_re(:,:,:,:)
    end if

    if ( present(qe) ) then
       if ( .not. diag_qe ) then
          select case ( atmos_phy_ae_type )
          case default
             atmos_phy_ae_qe(:,:,:,:) = 0.0_rp
          end select
          diag_qe = .true.
       end if
!OCL XFILL
       qe(:,:,:,:) = atmos_phy_ae_qe(:,:,:,:)
    end if

    return
  end subroutine atmos_phy_ae_vars_get_diagnostic

  subroutine atmos_phy_ae_vars_reset_diagnostics
    diag_re      = .false.
    diag_qe      = .false.

    return
  end subroutine atmos_phy_ae_vars_reset_diagnostics

end module mod_atmos_phy_ae_vars