scale_ocean_phy_roughness_moon07.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_ocean_phy_roughness_moon07
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: ocean_phy_roughness_moon07_setup
  public :: ocean_phy_roughness_moon07

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,  private :: ocean_phy_roughness_moon07_itelim  = 10        ! maximum iteration number

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine ocean_phy_roughness_moon07_setup
    use scale_prc, only: &
       prc_abort
    use scale_ocean_phy_roughness, only: &
       ocean_phy_roughness_setup
    implicit none

    namelist / param_ocean_phy_roughness_moon07 / &
       ocean_phy_roughness_moon07_itelim

    integer :: ierr
    !---------------------------------------------------------------------------

    ! common setup
    call ocean_phy_roughness_setup

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_ocean_phy_roughness_moon07,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("OCEAN_PHY_ROUGHNESS_moon07_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("OCEAN_PHY_ROUGHNESS_moon07_setup",*) 'Not appropriate names in namelist PARAM_OCEAN_PHY_ROUGHNESS_MOON07. Check!'
       call prc_abort
    endif
    log_nml(param_ocean_phy_roughness_moon07)

    return
  end subroutine ocean_phy_roughness_moon07_setup

  !-----------------------------------------------------------------------------
  subroutine ocean_phy_roughness_moon07( &
       OIA, OIS, OIE, OJA, OJS, OJE, &
       Uabs, Z1,     &
       Z0M, Z0H, Z0E )
    use scale_const, only: &
       grav   => const_grav,   &
       karman => const_karman
    use scale_ocean_phy_roughness, only: &
       ocean_phy_roughness_visck, &
       ocean_phy_roughness_ustar_min, &
       ocean_phy_roughness_z0m_min, &
       ocean_phy_roughness_z0h_min, &
       ocean_phy_roughness_z0e_min
    implicit none
    integer, intent(in) :: OIA, OIS, OIE
    integer, intent(in) :: OJA, OJS, OJE

    real(RP), intent(in) :: Uabs(oia,oja) ! velocity at the lowest atomspheric layer [m/s]
    real(RP), intent(in) :: Z1  (oia,oja) ! cell center height at the lowest atmospheric layer [m]

    real(RP), intent(inout) :: Z0M(oia,oja) ! roughness length for momentum [m]
    real(RP), intent(out)   :: Z0H(oia,oja) ! roughness length for heat [m]
    real(RP), intent(out)   :: Z0E(oia,oja) ! roughness length for vapor [m]

    ! works
    real(RP) :: Ustar(oia,oja)
    real(RP) :: U10M

    integer  :: ite
    integer  :: i, j
    !---------------------------------------------------------------------------

    !$omp parallel do default(none) OMP_SCHEDULE_ &
    !$omp shared(OJS,OJE,OIS,OIE,Z0M,OCEAN_PHY_ROUGHNESS_Z0M_min)
    do j = ojs, oje
    do i = ois, oie
       z0m(i,j) = max( z0m(i,j), ocean_phy_roughness_z0m_min )
    enddo
    enddo

    do ite = 1, ocean_phy_roughness_moon07_itelim
       !$omp parallel do default(none) OMP_SCHEDULE_ &
       !$omp shared(OJS,OJE,OIS,OIE,Ustar,Z0M,Uabs,Z1,OCEAN_PHY_ROUGHNESS_Ustar_min,GRAV,OCEAN_PHY_ROUGHNESS_Z0M_min) &
       !$omp private(i,j,U10M)
       do j = ojs, oje
       do i = ois, oie
          ustar(i,j) = max( karman * uabs(i,j) / log( z1(i,j)/z0m(i,j) ), ocean_phy_roughness_ustar_min )
          u10m = ustar(i,j) / karman * log( 10.0_rp/z0m(i,j) )

          if ( u10m <= 12.5_rp ) then
             z0m(i,j) = max( 0.0185_rp * ustar(i,j)**2 / grav, ocean_phy_roughness_z0m_min )
          else
             z0m(i,j) = max( 1.0e-3_rp * ( 0.085_rp * (  -0.56_rp*ustar(i,j)**2 &
                                                      + 20.255_rp*ustar(i,j)    &
                                                      +  2.458_rp               ) - 0.58_rp ), &
                             ocean_phy_roughness_z0m_min )
          end if
       enddo
       enddo
    enddo

    !  Fairall et al. TOGA V3.0
    !  Fairall et al. (2003) JCLI, vol. 16, 571-591. Eq. (28)
    !$omp parallel do default(none) OMP_SCHEDULE_ &
    !$omp shared(OJS,OJE,OIS,OIE, &
    !$omp        Z0H,Z0E,Z0M,Ustar,OCEAN_PHY_ROUGHNESS_visck,OCEAN_PHY_ROUGHNESS_Z0H_min,OCEAN_PHY_ROUGHNESS_Z0E_min)
    do j = ojs, oje
    do i = ois, oie
       z0h(i,j) = min( 5.5e-5_rp / ( z0m(i,j) * ustar(i,j) / ocean_phy_roughness_visck )**0.6_rp, 1.1e-4_rp )
       z0e(i,j) = z0h(i,j)
       z0h(i,j) = max( z0h(i,j), ocean_phy_roughness_z0h_min )
       z0e(i,j) = max( z0e(i,j), ocean_phy_roughness_z0e_min )
    enddo
    enddo

    return
  end subroutine ocean_phy_roughness_moon07

end module scale_ocean_phy_roughness_moon07