scale_ocean_phy_roughness_moon07 Module Reference

module ocean / physics / surface roughness length / moon07 More...

Functions/Subroutines
subroutine, public	ocean_phy_roughness_moon07_setup
subroutine, public	ocean_phy_roughness_moon07 (OIA, OIS, OIE, OJA, OJS, OJE, Uabs, Z1, Z0M, Z0H, Z0E)

Detailed Description

module ocean / physics / surface roughness length / moon07

Description

surface roughness length Moon07 scheme IL-JU MOON, ISAAC GINIS, TETSU HARA, AND BIJU THOMAS, 2007: A Physics-Based Parameterization of Air-Sea Momentum Flux at High Wind Speeds and Its Impact on Hurricane Intensity Predictions, Mon. Wea. Rev., 135, 2869-2878

Author

Team SCALE

NAMELIST

• PARAM_OCEAN_PHY_ROUGHNESS_MOON07

  name	type	default value	comment
  OCEAN_PHY_ROUGHNESS_MOON07_ITELIM	integer	10	maximum iteration number

  
  

History Output

No history output

Function/Subroutine Documentation

ocean_phy_roughness_moon07_setup()

subroutine, public scale_ocean_phy_roughness_moon07::ocean_phy_roughness_moon07_setup

(

)

Definition at line 51 of file scale_ocean_phy_roughness_moon07.F90.

References scale_io::io_fid_conf, scale_ocean_phy_roughness::ocean_phy_roughness_setup(), and scale_prc::prc_abort().

Referenced by mod_ocean_driver::ocean_driver_setup().

    use scale_prc, only: &
       prc_abort
    use scale_ocean_phy_roughness, only: &
       ocean_phy_roughness_setup
    implicit none

    namelist / param_ocean_phy_roughness_moon07 / &
       ocean_phy_roughness_moon07_itelim

    integer :: ierr
    !---------------------------------------------------------------------------

    ! common setup
    call ocean_phy_roughness_setup

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_ocean_phy_roughness_moon07,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("OCEAN_PHY_ROUGHNESS_moon07_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("OCEAN_PHY_ROUGHNESS_moon07_setup",*) 'Not appropriate names in namelist PARAM_OCEAN_PHY_ROUGHNESS_MOON07. Check!'
       call prc_abort
    endif
    log_nml(param_ocean_phy_roughness_moon07)

    return

Here is the call graph for this function:

Here is the caller graph for this function:

ocean_phy_roughness_moon07()

subroutine, public scale_ocean_phy_roughness_moon07::ocean_phy_roughness_moon07	(	integer, intent(in)	OIA,
		integer, intent(in)	OIS,
		integer, intent(in)	OIE,
		integer, intent(in)	OJA,
		integer, intent(in)	OJS,
		integer, intent(in)	OJE,
		real(rp), dimension(oia,oja), intent(in)	Uabs,
		real(rp), dimension (oia,oja), intent(in)	Z1,
		real(rp), dimension(oia,oja), intent(inout)	Z0M,
		real(rp), dimension(oia,oja), intent(out)	Z0H,
		real(rp), dimension(oia,oja), intent(out)	Z0E
	)

Definition at line 85 of file scale_ocean_phy_roughness_moon07.F90.

References scale_const::const_grav, scale_const::const_karman, scale_ocean_phy_roughness::ocean_phy_roughness_ustar_min, scale_ocean_phy_roughness::ocean_phy_roughness_visck, scale_ocean_phy_roughness::ocean_phy_roughness_z0e_min, scale_ocean_phy_roughness::ocean_phy_roughness_z0h_min, and scale_ocean_phy_roughness::ocean_phy_roughness_z0m_min.

Referenced by mod_ocean_driver::ocean_driver_calc_tendency().

    use scale_const, only: &
       grav   => const_grav,   &
       karman => const_karman
    use scale_ocean_phy_roughness, only: &
       ocean_phy_roughness_visck, &
       ocean_phy_roughness_ustar_min, &
       ocean_phy_roughness_z0m_min, &
       ocean_phy_roughness_z0h_min, &
       ocean_phy_roughness_z0e_min
    implicit none
    integer, intent(in) :: oia, ois, oie
    integer, intent(in) :: oja, ojs, oje

    real(RP), intent(in) :: uabs(oia,oja) ! velocity at the lowest atomspheric layer [m/s]
    real(RP), intent(in) :: z1  (oia,oja) ! cell center height at the lowest atmospheric layer [m]

    real(RP), intent(inout) :: z0m(oia,oja) ! roughness length for momentum [m]
    real(RP), intent(out)   :: z0h(oia,oja) ! roughness length for heat [m]
    real(RP), intent(out)   :: z0e(oia,oja) ! roughness length for vapor [m]

    ! works
    real(RP) :: ustar(oia,oja)
    real(RP) :: u10m

    integer  :: ite
    integer  :: i, j
    !---------------------------------------------------------------------------

    !$omp parallel do default(none) OMP_SCHEDULE_ &
    !$omp shared(OJS,OJE,OIS,OIE,Z0M,OCEAN_PHY_ROUGHNESS_Z0M_min)
    do j = ojs, oje
    do i = ois, oie
       z0m(i,j) = max( z0m(i,j), ocean_phy_roughness_z0m_min )
    enddo
    enddo

    do ite = 1, ocean_phy_roughness_moon07_itelim
       !$omp parallel do default(none) OMP_SCHEDULE_ &
       !$omp shared(OJS,OJE,OIS,OIE,Ustar,Z0M,Uabs,Z1,OCEAN_PHY_ROUGHNESS_Ustar_min,GRAV,OCEAN_PHY_ROUGHNESS_Z0M_min) &
       !$omp private(i,j,U10M)
       do j = ojs, oje
       do i = ois, oie
          ustar(i,j) = max( karman * uabs(i,j) / log( z1(i,j)/z0m(i,j) ), ocean_phy_roughness_ustar_min )
          u10m = ustar(i,j) / karman * log( 10.0_rp/z0m(i,j) )

          if ( u10m <= 12.5_rp ) then
             z0m(i,j) = max( 0.0185_rp * ustar(i,j)**2 / grav, ocean_phy_roughness_z0m_min )
          else
             z0m(i,j) = max( 1.0e-3_rp * ( 0.085_rp * (  -0.56_rp*ustar(i,j)**2 &
                                                      + 20.255_rp*ustar(i,j)    &
                                                      +  2.458_rp               ) - 0.58_rp ), &
                             ocean_phy_roughness_z0m_min )
          end if
       enddo
       enddo
    enddo

    !  Fairall et al. TOGA V3.0
    !  Fairall et al. (2003) JCLI, vol. 16, 571-591. Eq. (28)
    !$omp parallel do default(none) OMP_SCHEDULE_ &
    !$omp shared(OJS,OJE,OIS,OIE, &
    !$omp        Z0H,Z0E,Z0M,Ustar,OCEAN_PHY_ROUGHNESS_visck,OCEAN_PHY_ROUGHNESS_Z0H_min,OCEAN_PHY_ROUGHNESS_Z0E_min)
    do j = ojs, oje
    do i = ois, oie
       z0h(i,j) = min( 5.5e-5_rp / ( z0m(i,j) * ustar(i,j) / ocean_phy_roughness_visck )**0.6_rp, 1.1e-4_rp )
       z0e(i,j) = z0h(i,j)
       z0h(i,j) = max( z0h(i,j), ocean_phy_roughness_z0h_min )
       z0e(i,j) = max( z0e(i,j), ocean_phy_roughness_z0e_min )
    enddo
    enddo

    return

Here is the caller graph for this function: