mod_atmos_phy_sf_vars.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
module mod_atmos_phy_sf_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_sf_vars_setup
  public :: atmos_phy_sf_vars_fillhalo
  public :: atmos_phy_sf_vars_restart_read
  public :: atmos_phy_sf_vars_restart_write
  public :: atmos_phy_sf_vars_external_in

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,               public :: atmos_phy_sf_restart_output       = .false.                

  character(len=H_LONG), public :: atmos_phy_sf_restart_in_basename  = ''
  character(len=H_LONG), public :: atmos_phy_sf_restart_out_basename = ''
  character(len=H_MID),  public :: atmos_phy_sf_restart_out_title    = 'ATMOS_PHY_SF restart'
  character(len=H_MID),  public :: atmos_phy_sf_restart_out_dtype    = 'DEFAULT'

  real(RP), public, allocatable :: atmos_phy_sf_dens_t(:,:)   ! tendency DENS [    kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_sf_momz_t(:,:)   ! tendency MOMZ [m/s*kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_sf_momx_t(:,:)   ! tendency MOMX [m/s*kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_sf_momy_t(:,:)   ! tendency MOMY [m/s*kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_sf_rhot_t(:,:)   ! tendency RHOT [K  *kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_sf_rhoq_t(:,:,:) ! tendency rho*QTRC [    kg/kg/s]

  real(RP), public, allocatable :: atmos_phy_sf_sfc_temp  (:,:)   ! surface skin temperature             [K]
  real(RP), public, allocatable :: atmos_phy_sf_sfc_albedo(:,:,:) ! surface albedo                       [0-1]
  real(RP), public, allocatable :: atmos_phy_sf_sfc_z0m   (:,:)   ! surface roughness length, ocean only [m]
  real(RP), public, allocatable :: atmos_phy_sf_sfc_z0h   (:,:)   ! surface roughness length, ocean only [m]
  real(RP), public, allocatable :: atmos_phy_sf_sfc_z0e   (:,:)   ! surface roughness length, ocean only [m]

  ! surface diagnostic variables
  real(RP), public, allocatable :: atmos_phy_sf_sfc_dens  (:,:)   ! surface atmosphere density  [kg/m3]
  real(RP), public, allocatable :: atmos_phy_sf_sfc_pres  (:,:)   ! surface atmosphere pressure [Pa]

  real(RP), public, allocatable :: atmos_phy_sf_sflx_mw   (:,:)   ! z-momentum flux (area center) [m/s*kg/m2/s]
  real(RP), public, allocatable :: atmos_phy_sf_sflx_mu   (:,:)   ! x-momentum flux (area center) [m/s*kg/m2/s]
  real(RP), public, allocatable :: atmos_phy_sf_sflx_mv   (:,:)   ! y-momentum flux (area center) [m/s*kg/m2/s]
  real(RP), public, allocatable :: atmos_phy_sf_sflx_sh   (:,:)   ! sensible heat flux [J/m2/s]
  real(RP), public, allocatable :: atmos_phy_sf_sflx_lh   (:,:)   ! latent heat flux [J/m2/s]
  real(RP), public, allocatable :: atmos_phy_sf_sflx_gh   (:,:)   ! ground heat flux [J/m2/s]
  real(RP), public, allocatable :: atmos_phy_sf_sflx_qtrc (:,:,:) ! tracer mass flux [kg/m2/s]

  real(RP), public, allocatable :: atmos_phy_sf_u10       (:,:)   ! 10m x-wind [m/s]
  real(RP), public, allocatable :: atmos_phy_sf_v10       (:,:)   ! 10m y-wind [m/s]
  real(RP), public, allocatable :: atmos_phy_sf_t2        (:,:)   ! 2m temperature [K]
  real(RP), public, allocatable :: atmos_phy_sf_q2        (:,:)   ! 2m specific humidity [kg/kg]

!  real(RP), public, allocatable :: ATMOS_PHY_SF_SFLX_QEMIS(:,:,:) ! tracer emission   flux [kg/m2/s]
!  real(RP), public, allocatable :: ATMOS_PHY_SF_SFLX_QDEP (:,:,:) ! tracer deposition flux [kg/m2/s]
!  real(RP), public, allocatable :: ATMOS_PHY_SF_SFLX_VDEP (:,:,:) ! tracer deposition velocity [m/s]

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,                private, parameter :: vmax            = 6
  integer,                private, parameter :: i_sfc_temp      = 1
  integer,                private, parameter :: i_sfc_albedo_lw = 2
  integer,                private, parameter :: i_sfc_albedo_sw = 3
  integer,                private, parameter :: i_sfc_z0m       = 4
  integer,                private, parameter :: i_sfc_z0h       = 5
  integer,                private, parameter :: i_sfc_z0e       = 6

  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)

  data var_name / 'SFC_TEMP',   &
                  'SFC_ALB_LW', &
                  'SFC_ALB_SW', &
                  'SFC_Z0M',    &
                  'SFC_Z0H',    &
                  'SFC_Z0E'     /

  data var_desc / 'surface skin temperature',            &
                  'surface albedo for longwave',         &
                  'surface albedo for shortwave',        &
                  'surface roughness length (momentum)', &
                  'surface roughness length (heat)',     &
                  'surface roughness length (vapor)'     /

  data var_unit / 'K',   &
                  '0-1', &
                  '0-1', &
                  'm',   &
                  'm',   &
                  'm'    /

  real(RP), private :: atmos_phy_sf_default_sfc_temp   = 300.0_rp
  real(RP), private :: atmos_phy_sf_default_sfc_albedo = 0.4_rp
  real(RP), private :: atmos_phy_sf_default_sfc_z0     = 1e-4_rp

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_sf_vars_setup
    use scale_process, only: &
       prc_mpistop
    use scale_const, only: &
       undef => const_undef
    implicit none

    namelist / param_atmos_phy_sf_vars / &
       atmos_phy_sf_restart_in_basename,  &
       atmos_phy_sf_restart_output,       &
       atmos_phy_sf_restart_out_basename, &
       atmos_phy_sf_restart_out_title,    &
       atmos_phy_sf_restart_out_dtype,    &
       atmos_phy_sf_default_sfc_temp,     &
       atmos_phy_sf_default_sfc_albedo,   &
       atmos_phy_sf_default_sfc_z0

    integer :: ierr
    integer :: iv
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[VARS] / Categ[ATMOS PHY_SF] / Origin[SCALE-RM]'

    allocate( atmos_phy_sf_dens_t(ia,ja)    )
    allocate( atmos_phy_sf_momz_t(ia,ja)    )
    allocate( atmos_phy_sf_momx_t(ia,ja)    )
    allocate( atmos_phy_sf_momy_t(ia,ja)    )
    allocate( atmos_phy_sf_rhot_t(ia,ja)    )
    allocate( atmos_phy_sf_rhoq_t(ia,ja,qa) )
    atmos_phy_sf_dens_t(:,:)   = undef
    atmos_phy_sf_momz_t(:,:)   = undef
    atmos_phy_sf_momx_t(:,:)   = undef
    atmos_phy_sf_momy_t(:,:)   = undef
    atmos_phy_sf_rhot_t(:,:)   = undef
    atmos_phy_sf_rhoq_t(:,:,:) = undef

    allocate( atmos_phy_sf_sfc_temp(ia,ja)    )
    allocate( atmos_phy_sf_sfc_albedo(ia,ja,2)  )
    allocate( atmos_phy_sf_sfc_z0m(ia,ja)    )
    allocate( atmos_phy_sf_sfc_z0h(ia,ja)    )
    allocate( atmos_phy_sf_sfc_z0e(ia,ja)    )
!   ATMOS_PHY_SF_SFC_TEMP  (:,:)   = UNDEF ! [del] 2014/8/28 A.Noda
!   ATMOS_PHY_SF_SFC_albedo(:,:,:) = UNDEF ! [del] 2014/8/28 A.Noda
    atmos_phy_sf_sfc_z0m(:,:)   = undef
    atmos_phy_sf_sfc_z0h(:,:)   = undef
    atmos_phy_sf_sfc_z0e(:,:)   = undef

    allocate( atmos_phy_sf_sfc_dens(ia,ja)    )
    allocate( atmos_phy_sf_sfc_pres(ia,ja)    )
    atmos_phy_sf_sfc_dens(:,:)   = undef
    atmos_phy_sf_sfc_pres(:,:)   = undef

    allocate( atmos_phy_sf_sflx_mw(ia,ja)    )
    allocate( atmos_phy_sf_sflx_mu(ia,ja)    )
    allocate( atmos_phy_sf_sflx_mv(ia,ja)    )
    allocate( atmos_phy_sf_sflx_sh(ia,ja)    )
    allocate( atmos_phy_sf_sflx_lh(ia,ja)    )
    allocate( atmos_phy_sf_sflx_gh(ia,ja)    )
    allocate( atmos_phy_sf_sflx_qtrc(ia,ja,qa) )
    atmos_phy_sf_sflx_mw(:,:)   = undef
    atmos_phy_sf_sflx_mu(:,:)   = undef
    atmos_phy_sf_sflx_mv(:,:)   = undef
    atmos_phy_sf_sflx_sh(:,:)   = undef
    atmos_phy_sf_sflx_lh(:,:)   = undef
    atmos_phy_sf_sflx_gh(:,:)   = undef
    atmos_phy_sf_sflx_qtrc(:,:,:) = undef

    allocate( atmos_phy_sf_u10(ia,ja)    )
    allocate( atmos_phy_sf_v10(ia,ja)    )
    allocate( atmos_phy_sf_t2(ia,ja)    )
    allocate( atmos_phy_sf_q2(ia,ja)    )
    atmos_phy_sf_u10(:,:)   = undef
    atmos_phy_sf_v10(:,:)   = undef
    atmos_phy_sf_t2(:,:)   = undef
    atmos_phy_sf_q2(:,:)   = undef

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_sf_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       if( io_l ) write(io_fid_log,*) '*** Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       write(*,*) 'xxx Not appropriate names in namelist PARAM_ATMOS_PHY_SF_VARS. Check!'
       call prc_mpistop
    endif
    if( io_lnml ) write(io_fid_log,nml=param_atmos_phy_sf_vars)

    ! [add] 2014/08/28 A.Noda
    atmos_phy_sf_sfc_temp(:,:)   = atmos_phy_sf_default_sfc_temp
    atmos_phy_sf_sfc_albedo(:,:,:) = atmos_phy_sf_default_sfc_albedo
    atmos_phy_sf_sfc_z0m(:,:)   = atmos_phy_sf_default_sfc_z0
    atmos_phy_sf_sfc_z0h(:,:)   = atmos_phy_sf_default_sfc_z0
    atmos_phy_sf_sfc_z0e(:,:)   = atmos_phy_sf_default_sfc_z0

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** [ATMOS_PHY_SF] prognostic/diagnostic variables'
    if( io_l ) write(io_fid_log,'(1x,A,A15,A,A32,3(A))') &
               '***       |','VARNAME        ','|', 'DESCRIPTION                     ','[', 'UNIT            ',']'
    do iv = 1, vmax
       if( io_l ) write(io_fid_log,'(1x,A,i3,A,A15,A,A32,3(A))') &
                  '*** NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
    enddo

    if( io_l ) write(io_fid_log,*)
    if ( atmos_phy_sf_restart_in_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** Restart input?  : ', trim(atmos_phy_sf_restart_in_basename)
    else
       if( io_l ) write(io_fid_log,*) '*** Restart input?  : NO'
    endif
    if (       atmos_phy_sf_restart_output             &
         .AND. atmos_phy_sf_restart_out_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** Restart output? : ', trim(atmos_phy_sf_restart_out_basename)
    else
       if( io_l ) write(io_fid_log,*) '*** Restart output? : NO'
       atmos_phy_sf_restart_output = .false.
    endif

    return
  end subroutine atmos_phy_sf_vars_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_sf_vars_fillhalo
    use scale_const, only: &
       i_sw => const_i_sw, &
       i_lw => const_i_lw
    use scale_comm, only: &
       comm_vars8, &
       comm_wait
    implicit none
    !---------------------------------------------------------------------------

    call comm_vars8( atmos_phy_sf_sfc_temp(:,:),       1 )
    call comm_vars8( atmos_phy_sf_sfc_albedo(:,:,i_lw),  2 )
    call comm_vars8( atmos_phy_sf_sfc_albedo(:,:,i_sw),  3 )
    call comm_vars8( atmos_phy_sf_sfc_z0m(:,:),       4 )
    call comm_vars8( atmos_phy_sf_sfc_z0h(:,:),       5 )
    call comm_vars8( atmos_phy_sf_sfc_z0e(:,:),       6 )

    call comm_wait ( atmos_phy_sf_sfc_temp(:,:),       1 )
    call comm_wait ( atmos_phy_sf_sfc_albedo(:,:,i_lw),  2 )
    call comm_wait ( atmos_phy_sf_sfc_albedo(:,:,i_sw),  3 )
    call comm_wait ( atmos_phy_sf_sfc_z0m(:,:),       4 )
    call comm_wait ( atmos_phy_sf_sfc_z0h(:,:),       5 )
    call comm_wait ( atmos_phy_sf_sfc_z0e(:,:),       6 )

    return
  end subroutine atmos_phy_sf_vars_fillhalo

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_sf_vars_restart_read
    use scale_const, only: &
       i_sw => const_i_sw, &
       i_lw => const_i_lw
    use scale_fileio, only: &
       fileio_read
    use scale_rm_statistics, only: &
       stat_total
    implicit none

    real(RP) :: total
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Input restart file (ATMOS_PHY_SF) ***'

    if ( atmos_phy_sf_restart_in_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(atmos_phy_sf_restart_in_basename)

       call fileio_read( atmos_phy_sf_sfc_temp(:,:),                               & ! [OUT]
                         atmos_phy_sf_restart_in_basename, var_name(1), 'XY', step=1 ) ! [IN]
       call fileio_read( atmos_phy_sf_sfc_albedo(:,:,i_lw),                          & ! [OUT]
                         atmos_phy_sf_restart_in_basename, var_name(2), 'XY', step=1 ) ! [IN]
       call fileio_read( atmos_phy_sf_sfc_albedo(:,:,i_sw),                          & ! [OUT]
                         atmos_phy_sf_restart_in_basename, var_name(3), 'XY', step=1 ) ! [IN]
       call fileio_read( atmos_phy_sf_sfc_z0m(:,:),                               & ! [OUT]
                         atmos_phy_sf_restart_in_basename, var_name(4), 'XY', step=1 ) ! [IN]
       call fileio_read( atmos_phy_sf_sfc_z0h(:,:),                               & ! [OUT]
                         atmos_phy_sf_restart_in_basename, var_name(5), 'XY', step=1 ) ! [IN]
       call fileio_read( atmos_phy_sf_sfc_z0e(:,:),                               & ! [OUT]
                         atmos_phy_sf_restart_in_basename, var_name(6), 'XY', step=1 ) ! [IN]

       call atmos_phy_sf_vars_fillhalo

       call stat_total( total, atmos_phy_sf_sfc_temp(:,:),      var_name(1) )
       call stat_total( total, atmos_phy_sf_sfc_albedo(:,:,i_lw), var_name(2) )
       call stat_total( total, atmos_phy_sf_sfc_albedo(:,:,i_sw), var_name(3) )
       call stat_total( total, atmos_phy_sf_sfc_z0m(:,:),      var_name(4) )
       call stat_total( total, atmos_phy_sf_sfc_z0h(:,:),      var_name(5) )
       call stat_total( total, atmos_phy_sf_sfc_z0e(:,:),      var_name(6) )
    else
       if( io_l ) write(io_fid_log,*) '*** restart file for ATMOS_PHY_SF is not specified.'
       atmos_phy_sf_sfc_temp(:,:)   = atmos_phy_sf_default_sfc_temp
       atmos_phy_sf_sfc_albedo(:,:,:) = atmos_phy_sf_default_sfc_albedo
       atmos_phy_sf_sfc_z0m(:,:)   = atmos_phy_sf_default_sfc_z0
       atmos_phy_sf_sfc_z0h(:,:)   = atmos_phy_sf_default_sfc_z0
       atmos_phy_sf_sfc_z0e(:,:)   = atmos_phy_sf_default_sfc_z0
    endif

    return
  end subroutine atmos_phy_sf_vars_restart_read

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_sf_vars_restart_write
    use scale_const, only: &
       i_sw => const_i_sw, &
       i_lw => const_i_lw
    use scale_time, only: &
       time_gettimelabel
    use scale_fileio, only: &
       fileio_write
    use scale_rm_statistics, only: &
       stat_total
    implicit none

    character(len=20)     :: timelabel
    character(len=H_LONG) :: basename

    real(RP) :: total
    !---------------------------------------------------------------------------

    if ( atmos_phy_sf_restart_out_basename /= '' ) then

       call time_gettimelabel( timelabel )
       write(basename,'(A,A,A)') trim(atmos_phy_sf_restart_out_basename), '_', trim(timelabel)

       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Output restart file (ATMOS_PHY_SF) ***'
       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(basename)

       call atmos_phy_sf_vars_fillhalo

       call stat_total( total, atmos_phy_sf_sfc_temp(:,:),      var_name(1) )
       call stat_total( total, atmos_phy_sf_sfc_albedo(:,:,i_lw), var_name(2) )
       call stat_total( total, atmos_phy_sf_sfc_albedo(:,:,i_sw), var_name(3) )
       call stat_total( total, atmos_phy_sf_sfc_z0m(:,:),      var_name(4) )
       call stat_total( total, atmos_phy_sf_sfc_z0h(:,:),      var_name(5) )
       call stat_total( total, atmos_phy_sf_sfc_z0e(:,:),      var_name(6) )

       call fileio_write( atmos_phy_sf_sfc_temp(:,:),      basename, atmos_phy_sf_restart_out_title, & ! [IN]
                          var_name(1), var_desc(1), var_unit(1), 'XY', atmos_phy_sf_restart_out_dtype  ) ! [IN]
       call fileio_write( atmos_phy_sf_sfc_albedo(:,:,i_lw), basename, atmos_phy_sf_restart_out_title, & ! [IN]
                          var_name(2), var_desc(2), var_unit(2), 'XY', atmos_phy_sf_restart_out_dtype  ) ! [IN]
       call fileio_write( atmos_phy_sf_sfc_albedo(:,:,i_sw), basename, atmos_phy_sf_restart_out_title, & ! [IN]
                          var_name(3), var_desc(3), var_unit(3), 'XY', atmos_phy_sf_restart_out_dtype  ) ! [IN]
       call fileio_write( atmos_phy_sf_sfc_z0m(:,:),      basename, atmos_phy_sf_restart_out_title, & ! [IN]
                          var_name(4), var_desc(4), var_unit(4), 'XY', atmos_phy_sf_restart_out_dtype  ) ! [IN]
       call fileio_write( atmos_phy_sf_sfc_z0h(:,:),      basename, atmos_phy_sf_restart_out_title, & ! [IN]
                          var_name(5), var_desc(5), var_unit(5), 'XY', atmos_phy_sf_restart_out_dtype  ) ! [IN]
       call fileio_write( atmos_phy_sf_sfc_z0e(:,:),      basename, atmos_phy_sf_restart_out_title, & ! [IN]
                          var_name(6), var_desc(6), var_unit(6), 'XY', atmos_phy_sf_restart_out_dtype  ) ! [IN]
    endif

    return
  end subroutine atmos_phy_sf_vars_restart_write

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_sf_vars_external_in( &
      sfc_temp_in,   &
      albedo_lw_in,  &
      albedo_sw_in,  &
      sfc_z0m_in,    &
      sfc_z0h_in,    &
      sfc_z0e_in     )
    use scale_const, only: &
       i_sw => const_i_sw, &
       i_lw => const_i_lw
    implicit none

    real(RP), intent(in) :: sfc_temp_in (:,:)
    real(RP), intent(in) :: albedo_lw_in(:,:)
    real(RP), intent(in) :: albedo_sw_in(:,:)
    real(RP), intent(in) :: sfc_z0m_in  (:,:)
    real(RP), intent(in) :: sfc_z0h_in  (:,:)
    real(RP), intent(in) :: sfc_z0e_in  (:,:)
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** External Input (PHY_SF) ***'

    atmos_phy_sf_sfc_temp(:,:)      = sfc_temp_in(:,:)
    atmos_phy_sf_sfc_albedo(:,:,i_lw) = albedo_lw_in(:,:)
    atmos_phy_sf_sfc_albedo(:,:,i_sw) = albedo_sw_in(:,:)
    atmos_phy_sf_sfc_z0m(:,:)      = sfc_z0m_in(:,:)
    atmos_phy_sf_sfc_z0h(:,:)      = sfc_z0h_in(:,:)
    atmos_phy_sf_sfc_z0e(:,:)      = sfc_z0e_in(:,:)

    call atmos_phy_sf_vars_fillhalo

    return
  end subroutine atmos_phy_sf_vars_external_in

end module mod_atmos_phy_sf_vars