mod_atmos_dyn_vars.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "inc_openmp.h"
module mod_atmos_dyn_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_dyn_vars_setup
  public :: atmos_dyn_vars_fillhalo
  public :: atmos_dyn_vars_restart_read
  public :: atmos_dyn_vars_restart_write

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,               public :: atmos_dyn_restart_output       = .false.             

  character(len=H_LONG), public :: atmos_dyn_restart_in_basename  = ''
  character(len=H_LONG), public :: atmos_dyn_restart_out_basename = ''
  character(len=H_MID),  public :: atmos_dyn_restart_out_title    = 'ATMOS_DYN restart'
  character(len=H_MID),  public :: atmos_dyn_restart_out_dtype    = 'DEFAULT'

  ! prognostic variables
  real(RP), public, allocatable :: prog(:,:,:,:)

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,                private, parameter :: vmax = 100
  integer,                private            :: va   = 0
  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_setup
    use scale_process, only: &
       prc_mpistop
    use scale_const, only: &
       undef => const_undef
    use mod_atmos_admin, only: &
       atmos_dyn_type
    use scale_atmos_dyn_tstep_short, only: &
       atmos_dyn_tstep_short_regist
    implicit none

    namelist / param_atmos_dyn_vars / &
       atmos_dyn_restart_in_basename,  &
       atmos_dyn_restart_output,       &
       atmos_dyn_restart_out_basename, &
       atmos_dyn_restart_out_title,    &
       atmos_dyn_restart_out_dtype

    integer :: ierr
    integer :: iv
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[VARS] / Categ[ATMOS DYN] / Origin[SCALE-RM]'

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_dyn_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       if( io_l ) write(io_fid_log,*) '*** Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       write(*,*) 'xxx Not appropriate names in namelist PARAM_ATMOS_DYN_VARS. Check!'
       call prc_mpistop
    endif
    if( io_lnml ) write(io_fid_log,nml=param_atmos_dyn_vars)

    call atmos_dyn_tstep_short_regist( atmos_dyn_type, & ! [IN]
                                       va,             & ! [OUT]
                                       var_name,       & ! [OUT]
                                       var_desc,       & ! [OUT]
                                       var_unit        ) ! [OUT]

    if ( va > 0 ) then ! additional prognostic variables

       if ( va > vmax ) then
          write(*,*) 'xxx number of the prognostic variables is exceed the limit', va, ' > ', vmax
          call prc_mpistop
       endif
       allocate( prog(ka,ia,ja,va) )
       prog(:,:,:,:) = undef

       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** [ATMOS_DYN] prognostic/diagnostic variables'
       if( io_l ) write(io_fid_log,'(1x,A,A15,A,A32,3(A))') &
                  '***       |','VARNAME        ','|', 'DESCRIPTION                     ','[', 'UNIT            ',']'
       do iv = 1, va
          if( io_l ) write(io_fid_log,'(1x,A,i3,A,A15,A,A32,3(A))') &
                     '*** NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
       enddo

       if( io_l ) write(io_fid_log,*)

       if ( atmos_dyn_restart_in_basename /= '' ) then
          if( io_l ) write(io_fid_log,*) '*** Restart input?  : ', trim(atmos_dyn_restart_in_basename)
       else
          if( io_l ) write(io_fid_log,*) '*** Restart input?  : NO'
       endif

       if (       atmos_dyn_restart_output             &
            .AND. atmos_dyn_restart_out_basename /= '' ) then
          if( io_l ) write(io_fid_log,*) '*** Restart output? : ', trim(atmos_dyn_restart_out_basename)
       else
          if( io_l ) write(io_fid_log,*) '*** Restart output? : NO'
          atmos_dyn_restart_output = .false.
       endif

    else ! no additional prognostic variables

       allocate( prog(ka,ia,ja,1) ) ! for safety
       prog(:,:,:,:) = undef
       atmos_dyn_restart_output = .false.

    endif

    return
  end subroutine atmos_dyn_vars_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_fillhalo
    use scale_comm, only: &
       comm_vars8, &
       comm_wait
    implicit none

    integer :: i, j, iv
    !---------------------------------------------------------------------------

    do iv = 1, va
       do j  = js, je
       do i  = is, ie
          prog(   1:ks-1,i,j,iv) = prog(ks,i,j,iv)
          prog(ke+1:ka,  i,j,iv) = prog(ke,i,j,iv)
       enddo
       enddo

       call comm_vars8( prog(:,:,:,iv), iv )
    enddo

    do iv = 1, va
       call comm_wait ( prog(:,:,:,iv), iv )
    enddo

    return
  end subroutine atmos_dyn_vars_fillhalo

  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_restart_read
    use scale_fileio, only: &
       fileio_read
    use scale_rm_statistics, only: &
       stat_total
    implicit none

    real(RP) :: total
    integer :: iv
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Input restart file (ATMOS_DYN) ***'

    if ( atmos_dyn_restart_in_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(atmos_dyn_restart_in_basename)

       do iv = 1, va
          call fileio_read( prog(:,:,:,iv),                                            & ! [OUT]
                            atmos_dyn_restart_in_basename, var_name(iv), 'ZXY', step=1 ) ! [IN]

       enddo

       call atmos_dyn_vars_fillhalo

       do iv = 1, va
          call stat_total( total, prog(:,:,:,iv), var_name(iv) )
       enddo
    else
       if( io_l ) write(io_fid_log,*) '*** restart file for ATMOS_DYN is not specified.'
    endif

    return
  end subroutine atmos_dyn_vars_restart_read

  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_restart_write
    use scale_time, only: &
       time_gettimelabel
    use scale_fileio, only: &
       fileio_write
    implicit none

    character(len=20)     :: timelabel
    character(len=H_LONG) :: basename
    integer :: iv
    !---------------------------------------------------------------------------

    if ( atmos_dyn_restart_out_basename /= '' ) then

       call time_gettimelabel( timelabel )
       write(basename,'(A,A,A)') trim(atmos_dyn_restart_out_basename), '_', trim(timelabel)

       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Output restart file (ATMOS_DYN) ***'
       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(basename)

       do iv = 1, va
          call fileio_write( prog(:,:,:,iv), basename,                       atmos_dyn_restart_out_title, & ! [IN]
                             var_name(iv), var_desc(iv), var_unit(iv), 'ZXY', atmos_dyn_restart_out_dtype ) ! [IN]
       enddo

    endif

    return
  end subroutine atmos_dyn_vars_restart_write

end module mod_atmos_dyn_vars