scale_filter.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_filter
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: filter_hyperdiff
 
  interface filter_hyperdiff
     module procedure filter_hyperdiff_2d
     module procedure filter_hyperdiff_3d
  end interface filter_hyperdiff
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine filter_hyperdiff_2d( &
       IA, IS, IE, JA, JS, JE, &
       data, order, nite, &
       limiter_sign )
    use scale_comm_cartesc, only: &
       comm_vars8, &
       comm_wait
    use scale_prc, only: &
       prc_abort
    integer, intent(in) :: IA, IS, IE
    integer, intent(in) :: JA, JS, JE
 
    real(RP), intent(inout) :: data(IA,JA)
 
    integer,  intent(in)    :: order
    integer,  intent(in)    :: nite
 
    real(RP), intent(in), optional :: limiter_sign(IA,JA)
 
    real(RP), pointer :: p1(:,:)
    real(RP), pointer :: p2(:,:)
    real(RP), target  :: work1(IA,JA)
    real(RP), target  :: work2(IA,JA)
 
    logical :: limiter
 
    integer :: i, j
    integer :: ite, n
 
    call prof_rapstart('FILTER', 3)
 
    if ( mod(order,2) .ne. 0 ) then
       log_error("FILTER_hyperdiff_2D", *) "order must be even"
       call prc_abort
    end if
 
 
    limiter = present( limiter_sign )
 
    ! reduce grid-scale variation
    do ite = 1, nite
 
       call comm_vars8( data(:,:), 1 )
       call comm_wait ( data(:,:), 1, .false. )
 
       !$omp parallel do
       do j = 1, ja
       do i = 1, ia
          work2(i,j) = data(i,j)
       end do
       end do
 
       p1 => work2
       p2 => work1
       do n = 1, order
          !$omp parallel do
          do j = max(js,2), min(je,ja-1)
          do i = max(is,2), min(ie,ia-1)
             p2(i,j) = ( - p1(i+1,j) + p1(i,j)*2.0_rp - p1(i-1,j) &
                         - p1(i,j+1) + p1(i,j)*2.0_rp - p1(i,j-1) ) / 8.0_rp
          end do
          end do
          if ( js == 1 ) then
             do i = max(is,2), min(ie,ia-1)
                p2(i,js) = ( - p1(i+1,js) + p1(i,js)*2.0_rp - p1(i-1,js) &
                             - p1(i,js+1) + p1(i,js)                     ) / 6.0_rp
             end do
          else
             do i = max(is,2), min(ie,ia-1)
                p2(i,js-1) = p2(i,js)
             end do
          end if
          if ( je == ja ) then
             do i = max(is,2), min(ie,ia-1)
                p2(i,je) = ( - p1(i+1,je) + p1(i,je)*2.0_rp - p1(i-1,je) &
                                          + p1(i,je)        - p1(i,je-1) ) / 6.0_rp
             end do
          else
             do i = max(is,2), min(ie,ia-1)
                p2(i,je+1) = p2(i,je)
             end do
          end if
          if ( is == 1 ) then
             do j = max(js,2), min(je,ja-1)
                p2(is,j) = ( - p1(is+1,j) + p1(is,j)                     &
                             - p1(is,j+1) + p1(is,j)*2.0_rp - p1(is,j-1) ) / 6.0_rp
             end do
             if ( js == 1 ) then
                p2(is,js) = ( - p1(is+1,js) + p1(is,js)               &
                              - p1(is,js+1) + p1(is,js)               ) / 4.0_rp
             end if
             if ( je == ja ) then
                p2(is,je) = ( - p1(is+1,je) + p1(is,je)               &
                                            + p1(is,je) - p1(is,je-1) ) / 4.0_rp
             end if
          else
             do j = max(js-1,1), min(je+1,ja)
                p2(is-1,j) = p2(is,j)
             end do
          end if
          if ( ie == ia ) then
             do j = max(js,2), min(je,ja-1)
                p2(ie,j) = (              + p1(ie,j)        - p1(ie-1,j) &
                             - p1(ie,j+1) + p1(ie,j)*2.0_rp - p1(ie,j-1) ) / 6.0_rp
             end do
             if ( js == 1 ) then
                p2(ie,js) = (               + p1(ie,js) - p1(ie-1,js) &
                              - p1(ie,js+1) + p1(ie,js)               ) / 4.0_rp
             end if
             if ( je == ja ) then
                p2(ie,je) = (               + p1(ie,je) - p1(ie-1,je) &
                                            + p1(ie,je) - p1(ie,je-1) ) / 4.0_rp
             end if
          else
             do j = max(js-1,1), min(je+1,ja)
                p2(ie+1,j) = p2(ie,j)
             end do
          end if
 
          call comm_vars8( p2(:,:), 1 )
          call comm_wait ( p2(:,:), 1, .false. )
 
          if ( mod(n,2) == 0 ) then
             p1 => work2
             p2 => work1
          else
             p1 => work1
             p2 => work2
          end if
       end do
 
       !$omp parallel do
       do j = js, je
       do i = is, ie
          data(i,j) = data(i,j) - p1(i,j)
       end do
       end do
 
       if ( limiter ) then
          !$omp parallel do
          do j = js, je
          do i = is, ie
             data(i,j) = sign( max( data(i,j) * limiter_sign(i,j), 0.0_rp ), limiter_sign(i,j) )
          end do
          end do
       end if
    end do
 
    call prof_rapend('FILTER', 3)
 
    return
  end subroutine filter_hyperdiff_2d
 
  !-----------------------------------------------------------------------------
  subroutine filter_hyperdiff_3d( &
       KA, KS, KE, IA, IS, IE, JA, JS, JE, &
       data, order, nite, &
       limiter_sign )
    use scale_comm_cartesc, only: &
       comm_vars8, &
       comm_wait
    use scale_prc, only: &
       prc_abort
    integer, intent(in) :: KA, KS, KE
    integer, intent(in) :: IA, IS, IE
    integer, intent(in) :: JA, JS, JE
 
    real(RP), intent(inout) :: data(KA,IA,JA)
 
    integer,  intent(in)    :: order
    integer,  intent(in)    :: nite
 
    real(RP), intent(in), optional :: limiter_sign(KA,IA,JA)
 
    real(RP) :: work_data(IA,JA)
    real(RP) :: work_sign(IA,JA)
 
    logical :: flag
 
    integer :: k, i, j
 
    if ( present(limiter_sign) ) then
       flag = .true.
    else
       flag = .false.
    end if
 
    do k = ks, ke
 
       !$omp parallel do
       do j = js, je
       do i = is, ie
          work_data(i,j) = data(k,i,j)
       end do
       end do
       if ( flag ) then
          !$omp parallel do
          do j = js, je
          do i = is, ie
             work_sign(i,j) = limiter_sign(k,i,j)
          end do
          end do
 
          call filter_hyperdiff_2d( ia, is, ie, ja, js, je, &
                                    work_data(:,:), order, nite, &
                                    limiter_sign = work_sign )
 
       else
 
          call filter_hyperdiff_2d( ia, is, ie, ja, js, je, &
                                    work_data(:,:), order, nite )
       end if
 
 
       !$omp parallel do
       do j = 1, ja
       do i = 1, ia
          data(k,i,j) = work_data(i,j)
       end do
       end do
 
    end do
 
 
    return
  end subroutine filter_hyperdiff_3d
 
end module scale_filter