scale_ocean_phy_roughness_moon07.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_ocean_phy_roughness_moon07
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: ocean_phy_roughness_moon07_setup
  public :: ocean_phy_roughness_moon07
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,  private :: OCEAN_PHY_ROUGHNESS_moon07_itelim  = 10        ! maximum iteration number
 
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine ocean_phy_roughness_moon07_setup
    use scale_prc, only: &
       prc_abort
    use scale_ocean_phy_roughness, only: &
       ocean_phy_roughness_setup
    implicit none
 
    namelist / param_ocean_phy_roughness_moon07 / &
       ocean_phy_roughness_moon07_itelim
 
    integer :: ierr
    !---------------------------------------------------------------------------
 
    ! common setup
    call ocean_phy_roughness_setup
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_ocean_phy_roughness_moon07,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("OCEAN_PHY_ROUGHNESS_moon07_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("OCEAN_PHY_ROUGHNESS_moon07_setup",*) 'Not appropriate names in namelist PARAM_OCEAN_PHY_ROUGHNESS_MOON07. Check!'
       call prc_abort
    endif
    log_nml(param_ocean_phy_roughness_moon07)
 
    return
  end subroutine ocean_phy_roughness_moon07_setup
 
  !-----------------------------------------------------------------------------
  subroutine ocean_phy_roughness_moon07( &
       OIA, OIS, OIE, OJA, OJS, OJE, &
       Uabs, Z1,     &
       mask,         &
       Z0M, Z0H, Z0E )
    use scale_const, only: &
       undef  => const_undef,  &
       grav   => const_grav,   &
       karman => const_karman
    use scale_ocean_phy_roughness, only: &
       ocean_phy_roughness_visck, &
       ocean_phy_roughness_ustar_min, &
       ocean_phy_roughness_z0m_min, &
       ocean_phy_roughness_z0h_min, &
       ocean_phy_roughness_z0e_min
    implicit none
    integer, intent(in) :: oia, ois, oie
    integer, intent(in) :: oja, ojs, oje
 
    real(rp), intent(in) :: uabs(oia,oja) ! velocity at the lowest atomspheric layer [m/s]
    real(rp), intent(in) :: z1  (oia,oja) ! cell center height at the lowest atmospheric layer [m]
    logical,  intent(in) :: mask(oia,oja)
 
    real(rp), intent(inout) :: z0m(oia,oja) ! roughness length for momentum [m]
    real(rp), intent(out)   :: z0h(oia,oja) ! roughness length for heat [m]
    real(rp), intent(out)   :: z0e(oia,oja) ! roughness length for vapor [m]
 
    ! works
    real(rp) :: ustar
    real(rp) :: u10m
 
    integer  :: ite
    integer  :: i, j
    !---------------------------------------------------------------------------
 
    !$omp parallel do default(none) OMP_SCHEDULE_ &
    !$omp shared(OJS,OJE,OIS,OIE, &
    !$omp        GRAV,UNDEF, &
    !$omp        OCEAN_PHY_ROUGHNESS_Z0M_min,OCEAN_PHY_ROUGHNESS_Z0H_min,OCEAN_PHY_ROUGHNESS_Z0E_min, &
    !$omp        OCEAN_PHY_ROUGHNESS_Ustar_min,OCEAN_PHY_ROUGHNESS_visck,OCEAN_PHY_ROUGHNESS_moon07_itelim, &
    !$omp        Z0M,Z0H,Z0E,Uabs,Z1,mask) &
    !$omp private(i,j,ite,U10M,Ustar)
    do j = ojs, oje
    do i = ois, oie
       if ( mask(i,j) ) then
 
          z0m(i,j) = max( z0m(i,j), ocean_phy_roughness_z0m_min )
 
          do ite = 1, ocean_phy_roughness_moon07_itelim
             ustar = max( karman * uabs(i,j) / log( z1(i,j)/z0m(i,j) ), ocean_phy_roughness_ustar_min )
             u10m = ustar / karman * log( 10.0_rp/z0m(i,j) )
 
             if ( u10m <= 12.5_rp ) then
                z0m(i,j) = 0.0185_rp * ustar**2 / grav
             else
                z0m(i,j) = ( 0.085_rp * ( -  0.56_rp  * ustar**2   &
                                          + 20.255_rp * ustar      &
                                          +  2.458_rp            ) &
                           - 0.58_rp ) *  1.0e-3_rp
             end if
             z0m(i,j) = max( z0m(i,j), ocean_phy_roughness_z0m_min )
          enddo
 
          !  Fairall et al. TOGA V3.0
          !  Fairall et al. (2003) JCLI, vol. 16, 571-591. Eq. (28)
          z0h(i,j) = min( 5.5e-5_rp / ( z0m(i,j) * ustar / ocean_phy_roughness_visck )**0.6_rp, &
                          1.1e-4_rp )
          z0e(i,j) = z0h(i,j)
          z0h(i,j) = max( z0h(i,j), ocean_phy_roughness_z0h_min )
          z0e(i,j) = max( z0e(i,j), ocean_phy_roughness_z0e_min )
 
       else
          z0h(i,j) = undef
          z0e(i,j) = undef
       end if
    enddo
    enddo
 
    return
  end subroutine ocean_phy_roughness_moon07
 
end module scale_ocean_phy_roughness_moon07