scale_ocean_dyn_offline.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_ocean_dyn_offline
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_debug
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: ocean_dyn_offline_setup
  public :: ocean_dyn_offline
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine ocean_dyn_offline_setup
    use scale_prc, only: &
       prc_abort
    use scale_const, only: &
       undef => const_undef
    use scale_file_external_input, only: &
       file_external_input_regist
    implicit none
 
    character(len=H_LONG)  :: ocean_dyn_offline_basename              = ''
    logical                :: ocean_dyn_offline_basename_add_num      = .false.
    integer                :: ocean_dyn_offline_number_of_files       = 1
    logical                :: ocean_dyn_offline_enable_periodic_year  = .false.
    logical                :: ocean_dyn_offline_enable_periodic_month = .false.
    logical                :: ocean_dyn_offline_enable_periodic_day   = .false.
    integer                :: ocean_dyn_offline_step_fixed            = 0
    real(rp)               :: ocean_dyn_offline_offset                = 0.0_rp
    real(rp)               :: ocean_dyn_offline_defval               != UNDEF
    logical                :: ocean_dyn_offline_check_coordinates     = .true.
    integer                :: ocean_dyn_offline_step_limit            = 0
 
    namelist / param_ocean_dyn_offline / &
       ocean_dyn_offline_basename,              &
       ocean_dyn_offline_basename_add_num,      &
       ocean_dyn_offline_number_of_files,       &
       ocean_dyn_offline_enable_periodic_year,  &
       ocean_dyn_offline_enable_periodic_month, &
       ocean_dyn_offline_enable_periodic_day,   &
       ocean_dyn_offline_step_fixed,            &
       ocean_dyn_offline_offset,                &
       ocean_dyn_offline_defval,                &
       ocean_dyn_offline_check_coordinates,     &
       ocean_dyn_offline_step_limit
 
    integer :: ierr
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("OCEAN_DYN_OFFLINE_setup",*) 'Setup'
 
    ocean_dyn_offline_defval = undef
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_ocean_dyn_offline,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("OCEAN_DYN_OFFLINE_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("OCEAN_DYN_OFFLINE_setup",*) 'Not appropriate names in namelist PARAM_OCEAN_DYN_OFFLINE. Check!'
       call prc_abort
    endif
    log_nml(param_ocean_dyn_offline)
 
    log_info("OCEAN_DYN_OFFLINE_setup",*) 'Use offline ocean'
 
    if ( ocean_dyn_offline_basename == '' ) then
       log_error("OCEAN_DYN_OFFLINE_setup",*) 'OCEAN_DYN_OFFLINE_basename is necessary !!'
       call prc_abort
    endif
 
    call file_external_input_regist( ocean_dyn_offline_basename,              & ! [IN]
                                     ocean_dyn_offline_basename_add_num,      & ! [IN]
                                     ocean_dyn_offline_number_of_files,       & ! [IN]
                                     'OCEAN_TEMP',                            & ! [IN]
                                     'OXY',                                   & ! [IN]
                                     ocean_dyn_offline_enable_periodic_year,  & ! [IN]
                                     ocean_dyn_offline_enable_periodic_month, & ! [IN]
                                     ocean_dyn_offline_enable_periodic_day,   & ! [IN]
                                     ocean_dyn_offline_step_fixed,            & ! [IN]
                                     ocean_dyn_offline_offset,                & ! [IN]
                                     ocean_dyn_offline_defval,                & ! [IN]
                                     check_coordinates = ocean_dyn_offline_check_coordinates, & ! [IN]
                                     step_limit        = ocean_dyn_offline_step_limit         ) ! [IN]
 
    return
  end subroutine ocean_dyn_offline_setup
 
  !-----------------------------------------------------------------------------
  subroutine ocean_dyn_offline( &
       OKMAX, OKS, OKE,  &
       OIA,   OIS, OIE,  &
       OJA,   OJS, OJE,  &
       calc_flag,        &
       dt, NOWDAYSEC,    &
       OCEAN_TEMP        )
    use scale_prc, only: &
       prc_abort
    use scale_file_external_input, only: &
       file_external_input_update
    implicit none
 
    integer,  intent(in)    :: okmax, oks, oke
    integer,  intent(in)    :: oia,   ois, oie
    integer,  intent(in)    :: oja,   ojs, oje
    logical,  intent(in)    :: calc_flag (oia,oja) ! to decide calculate or not
    real(dp), intent(in)    :: dt
    real(dp), intent(in)    :: nowdaysec
    real(rp), intent(inout) :: ocean_temp(okmax,oia,oja)
 
    real(rp) :: ocean_temp_ref(okmax,oia,oja)
 
    logical  :: error
    integer  :: i, j
    !---------------------------------------------------------------------------
 
    log_progress(*) 'ocean / dynamics / offline'
 
    call file_external_input_update( 'OCEAN_TEMP', nowdaysec, ocean_temp_ref(:,:,:), error )
 
    if ( error ) then
       log_error("OCEAN_DYN_OFFLINE",*) 'Requested data is not found!'
       call prc_abort
    endif
 
    do j = ojs, oje
    do i = ois, oie
       if ( calc_flag(i,j) ) then
          ocean_temp(oks,i,j) = ocean_temp_ref(oks,i,j)
       endif
    enddo
    enddo
 
    return
  end subroutine ocean_dyn_offline
 
end module scale_ocean_dyn_offline