scale_urban_grid_icoA.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_urban_grid_icoa
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_atmos_grid_icoa_index
  use scale_urban_grid_icoa_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: urban_grid_icoa_setup
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  real(rp), public, allocatable :: urban_grid_icoa_cz  (:)
  real(rp), public, allocatable :: urban_grid_icoa_fz  (:)
  real(rp), public, allocatable :: urban_grid_icoa_cdz (:)
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  private :: urban_grid_icoa_read
  private :: urban_grid_icoa_generate
 
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  real(rp), private :: udz(200)
 
  character(len=H_LONG) :: urban_grid_icoa_in_basename  = ''
  logical               :: urban_grid_icoa_in_aggregate
 
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine urban_grid_icoa_setup
    use scale_prc, only: &
       prc_abort
    use scale_file, only: &
       file_aggregate
    implicit none
 
    namelist / param_urban_grid_icoa / &
       urban_grid_icoa_in_basename,  &
       urban_grid_icoa_in_aggregate, &
       udz
 
    integer :: ierr
    integer :: k
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("URBAN_GRID_ICOA_setup",*) 'Setup'
 
    if ( ukmax < 1 ) then
       log_info("URBAN_GRID_ICOA_setup",*) 'Skip because UKMAX < 1'
       return
    end if
 
    udz(:) = 0.0_rp
 
    urban_grid_icoa_in_aggregate = file_aggregate
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_urban_grid_icoa,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("URBAN_GRID_ICOA_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("URBAN_GRID_ICOA_setup",*) 'Not appropriate names in namelist PARAM_URBAN_GRID_ICOA. Check!'
       call prc_abort
    endif
    log_nml(param_urban_grid_icoa)
 
    allocate( urban_grid_icoa_cz(uks  :uke) )
    allocate( urban_grid_icoa_fz(uks-1:uke) )
    allocate( urban_grid_icoa_cdz(uks  :uke) )
 
    log_newline
    log_info("URBAN_GRID_ICOA_setup",*) 'Urban grid information '
 
    if ( urban_grid_icoa_in_basename /= '' ) then
       call urban_grid_icoa_read
    else
       log_info("URBAN_GRID_ICOA_setup",*) 'Not found input grid file. Grid position is calculated.'
 
       call urban_grid_icoa_generate
    endif
 
    if ( uke == uks ) then
       log_newline
       log_info("URBAN_GRID_ICOA_setup",*) 'Single layer. LDZ = ', udz(1)
    else
       log_newline
       log_info("URBAN_GRID_ICOA_setup",'(1x,A)') 'Vertical Coordinate'
       log_info_cont('(1x,A)')                  '|   k       z      zh      dz   k |'
       log_info_cont('(1x,A)')                  '|         [m]     [m]     [m]     |'
       k = uks-1
       log_info_cont('(1x,A,F8.3,A,I4,A)')      '|            ',urban_grid_icoa_fz(k),'        ',k,' | Atmosphere interface'
       do k = uks, uke-1
       log_info_cont('(1x,A,I4,F8.3,A,F8.3,A)') '|',k,urban_grid_icoa_cz(k),'        ',urban_grid_icoa_cdz(k),'     | '
       log_info_cont('(1x,A,F8.3,A,I4,A)')      '|            ',urban_grid_icoa_fz(k),'       |',k,' | '
       enddo
       k = uke
       log_info_cont('(1x,A,I4,F8.3,A,F8.3,A)') '|',k,urban_grid_icoa_cz(k),'        ',urban_grid_icoa_cdz(k),'     | '
       log_info_cont('(1x,A,F8.3,A,I4,A)')      '|            ',urban_grid_icoa_fz(k),'        ',k,' | bedrock'
       log_info_cont('(1x,A)')                  '|=================================|'
    endif
 
    return
  end subroutine urban_grid_icoa_setup
 
  !-----------------------------------------------------------------------------
  subroutine urban_grid_icoa_read
    use scale_file, only: &
       file_open, &
       file_read
    use scale_prc, only: &
       prc_myrank
    implicit none
 
    integer :: fid
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("URBAN_GRID_ICOA_read",*) 'Input urban grid file '
 
    call file_open( urban_grid_icoa_in_basename, fid, rankid=prc_myrank, aggregate=urban_grid_icoa_in_aggregate )
 
    call file_read( fid, 'UCZ',  urban_grid_icoa_cz(:)  )
    call file_read( fid, 'UCDZ', urban_grid_icoa_cdz(:) )
    call file_read( fid, 'UFZ',  urban_grid_icoa_fz(:)  )
 
    return
  end subroutine urban_grid_icoa_read
 
  !-----------------------------------------------------------------------------
  subroutine urban_grid_icoa_generate
    implicit none
 
    integer :: k
    !---------------------------------------------------------------------------
 
    do k = uks, uke
       urban_grid_icoa_cdz(k) = udz(k)
    enddo
 
    urban_grid_icoa_fz(uks-1) = 0.0_rp
 
    do k = uks, uke
       urban_grid_icoa_cz(k) = urban_grid_icoa_cdz(k) / 2.0_rp + urban_grid_icoa_fz(k-1)
       urban_grid_icoa_fz(k) = urban_grid_icoa_cdz(k)          + urban_grid_icoa_fz(k-1)
    enddo
 
    return
  end subroutine urban_grid_icoa_generate
 
end module scale_urban_grid_icoa