mod_atmos_phy_bl_driver.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module mod_atmos_phy_bl_driver
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_atmos_grid_cartesc_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_bl_driver_tracer_setup
  public :: atmos_phy_bl_driver_setup
  public :: atmos_phy_bl_driver_calc_tendency
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_driver_tracer_setup
    use scale_prc, only: &
       prc_abort
    use scale_tracer, only: &
       tracer_regist
    use scale_atmos_phy_bl_mynn, only: &
       atmos_phy_bl_mynn_tracer_setup, &
       atmos_phy_bl_mynn_ntracer, &
       atmos_phy_bl_mynn_name, &
       atmos_phy_bl_mynn_desc, &
       atmos_phy_bl_mynn_units
    use mod_atmos_admin, only: &
       atmos_phy_bl_type, &
       atmos_sw_phy_bl
    use mod_atmos_phy_bl_vars, only: &
       qs, qe
    implicit none
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_PHY_BL_driver_tracer_setup",*) 'Setup'
 
    if ( atmos_sw_phy_bl ) then
       select case ( atmos_phy_bl_type )
       case ( 'MYNN' )
          call atmos_phy_bl_mynn_tracer_setup
          call tracer_regist( &
               qs, &
               atmos_phy_bl_mynn_ntracer, &
               atmos_phy_bl_mynn_name,    &
               atmos_phy_bl_mynn_desc,    &
               atmos_phy_bl_mynn_units    )
          qe = qs + atmos_phy_bl_mynn_ntracer - 1
       case default
          log_error("ATMOS_PHY_BL_driver_tracer_setup",*) 'ATMOS_PHY_BL_TYPE is invalid: ', trim(atmos_phy_bl_type)
          call prc_abort
       end select
    end if
 
    return
  end subroutine atmos_phy_bl_driver_tracer_setup
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_driver_setup
    use scale_atmos_phy_bl_mynn, only: &
       atmos_phy_bl_mynn_setup
    use mod_atmos_admin, only: &
       atmos_phy_bl_type, &
       atmos_sw_phy_bl
    use mod_atmos_phy_bl_vars, only: &
       atmos_phy_bl_zi
    use scale_bulkflux, only: &
       bulkflux_type
    implicit none
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_PHY_BL_driver_setup",*) 'Setup'
 
    if ( atmos_sw_phy_bl ) then
       select case ( atmos_phy_bl_type )
       case ( 'MYNN' )
          call atmos_phy_bl_mynn_setup( &
               ka, ks, ke, ia, is, ie, ja, js, je, &
               bulkflux_type ) ! (in)
       end select
    else
       log_info("ATMOS_PHY_BL_driver_setup",*) 'this component is never called.'
       atmos_phy_bl_zi(:,:) = 0.0_rp
    endif
 
    return
  end subroutine atmos_phy_bl_driver_setup
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_driver_calc_tendency( update_flag )
    use scale_statistics, only: &
       statistics_checktotal, &
       statistics_total
    use scale_file_history, only: &
       file_history_in
    use scale_time, only: &
       dt_bl => time_dtsec_atmos_phy_bl
    use scale_atmos_phy_bl_mynn, only: &
       atmos_phy_bl_mynn_tendency, &
       atmos_phy_bl_mynn_tendency_tracer
    use scale_atmos_grid_cartesc_real, only: &
       cz => atmos_grid_cartesc_real_cz, &
       fz => atmos_grid_cartesc_real_fz, &
       atmos_grid_cartesc_real_vol, &
       atmos_grid_cartesc_real_totvol
    use scale_atmos_hydrometeor, only: &
       i_qv
    use scale_bulkflux, only: &
       bulkflux_type
    use mod_atmos_admin, only: &
       atmos_phy_bl_type, &
       atmos_sw_phy_bl
    use mod_atmos_vars, only: &
       dens => dens_av, &
       qtrc => qtrc_av, &
       u,     &
       v,     &
       pott,  &
       pres,  &
       exner, &
       qdry,  &
       qv,    &
       qc,    &
       qi,    &
       rhou_t => rhou_tp, &
       rhov_t => rhov_tp, &
       rhot_t => rhot_tp, &
       rhoq_t => rhoq_tp, &
       atmos_vars_get_diagnostic
    use mod_atmos_phy_bl_vars, only: &
       qs, qe, &
       rhou_t_bl => atmos_phy_bl_rhou_t, &
       rhov_t_bl => atmos_phy_bl_rhov_t, &
       rhot_t_bl => atmos_phy_bl_rhot_t, &
       rhoq_t_bl => atmos_phy_bl_rhoq_t, &
       zi        => atmos_phy_bl_zi,     &
       ql        => atmos_phy_bl_ql,     &
       cldfrac   => atmos_phy_bl_cldfrac
    use mod_atmos_phy_sf_vars, only: &
       sfc_dens => atmos_phy_sf_sfc_dens,  &
       sflx_mu  => atmos_phy_sf_sflx_mu,   &
       sflx_mv  => atmos_phy_sf_sflx_mv,   &
       sflx_sh  => atmos_phy_sf_sflx_sh,   &
       sflx_q   => atmos_phy_sf_sflx_qtrc, &
       sflx_qv  => atmos_phy_sf_sflx_qv,   &
       ustar    => atmos_phy_sf_ustar,     &
       tstar    => atmos_phy_sf_tstar,     &
       qstar    => atmos_phy_sf_qstar,     &
       rlmo     => atmos_phy_sf_rlmo
    implicit none
 
    logical, intent(in) :: update_flag
 
    real(rp) :: nu(ka,ia,ja)
    real(rp) :: kh(ka,ia,ja)
 
    real(rp) :: qw(ka,ia,ja)
 
    real(rp) :: n2  (ka,ia,ja)
    real(rp) :: potl(ka,ia,ja)
    real(rp) :: potv(ka,ia,ja)
 
    real(rp), pointer :: rhoqv_t(:,:,:)
 
    integer  :: k, i, j, iq
    !---------------------------------------------------------------------------
 
    if ( update_flag ) then
 
       rhoq_t_bl(:,:,:,:) = 0.0_rp
 
       select case ( atmos_phy_bl_type )
       case ( 'MYNN' )
          call atmos_vars_get_diagnostic( "N2",   n2   )
          call atmos_vars_get_diagnostic( "POTL", potl )
          call atmos_vars_get_diagnostic( "POTV", potv )
          do j = jsb, jeb
          do i = isb, ieb
          do k = ks, ke
             qw(k,i,j) = qv(k,i,j) + qc(k,i,j) + qi(k,i,j)
          end do
          end do
          end do
          if ( i_qv > 0 ) then
             rhoqv_t => rhoq_t_bl(:,:,:,i_qv)
          else
             allocate( rhoqv_t(ka,ia,ja) )
          end if
          call atmos_phy_bl_mynn_tendency( &
               ka, ks, ke, ia, is, ie, ja, js, je, &
               dens(:,:,:), u(:,:,:), v(:,:,:),                        & ! (in)
               pott(:,:,:), qtrc(:,:,:,qs:qe),                         & ! (in)
               pres(:,:,:), exner(:,:,:), n2(:,:,:),                   & ! (in)
               qdry(:,:,:), qv(:,:,:), qw(:,:,:),                      & ! (in)
               potl(:,:,:), potv(:,:,:),                               & ! (in)
               sfc_dens(:,:),                                          & ! (in)
               sflx_mu(:,:), sflx_mv(:,:), sflx_sh(:,:), sflx_qv(:,:), & ! (in)
               ustar(:,:), tstar(:,:), qstar(:,:), rlmo(:,:),          & ! (in)
               cz(:,:,:), fz(:,:,:), dt_bl,                            & ! (in)
               bulkflux_type,                                          & ! (in)
               rhou_t_bl(:,:,:), rhov_t_bl(:,:,:), rhot_t_bl(:,:,:),   & ! (out)
               rhoqv_t(:,:,:), rhoq_t_bl(:,:,:,qs:qe),                 & ! (out)
               nu(:,:,:), kh(:,:,:),                                   & ! (out)
               ql(:,:,:), cldfrac(:,:,:), zi(:,:)                      ) ! (out)
          if ( i_qv <= 0 ) deallocate( rhoqv_t )
          do iq = 1, qa
             if ( ( .not. tracer_advc(iq) ) .or. iq==i_qv .or. (iq>=qs .and. iq<=qe) ) cycle
             call atmos_phy_bl_mynn_tendency_tracer( &
                  ka, ks, ke, ia, is, ie, ja, js, je, &
                  dens(:,:,:), qtrc(:,:,:,iq), & ! (in)
                  sflx_q(:,:,iq),              & ! (in)
                  kh(:,:,:),                   & ! (in)
                  tracer_mass(iq),             & ! (in)
                  cz(:,:,:), fz(:,:,:),        & ! (in)
                  dt_bl, tracer_name(iq),      & ! (in)
                  rhoq_t_bl(:,:,:,iq)          ) ! (out)
          end do
       end select
 
       call file_history_in( nu(:,:,:),     'Nu_BL',     'eddy viscosity',                         'm2/s',      fill_halo=.true., dim_type="ZHXY" )
       call file_history_in( kh(:,:,:),     'Kh_BL',     'eddy diffusion',                         'm2/s',      fill_halo=.true., dim_type="ZHXY" )
 
       call file_history_in( ql(:,:,:),    'QL_BL',      'liquid water content in partial condensation', 'kg/kg', fill_halo=.true. )
       call file_history_in( cldfrac(:,:,:),   'cldfrac_BL', 'cloud fraction in partial condensation',       '1',     fill_halo=.true. )
 
       call file_history_in( zi(:,:),     'Zi_BL',      'depth of the boundary layer', 'm', fill_halo=.true. )
 
       call file_history_in( rhou_t_bl(:,:,:), 'RHOU_t_BL', 'MOMX tendency (BL)',                     'kg/m2/s2',  fill_halo=.true. )
       call file_history_in( rhov_t_bl(:,:,:), 'RHOV_t_BL', 'MOMY tendency (BL)',                     'kg/m2/s2',  fill_halo=.true. )
       call file_history_in( rhot_t_bl(:,:,:), 'RHOT_t_BL', 'RHOT tendency (BL)',                     'K.kg/m3/s', fill_halo=.true. )
 
       do iq = 1, qa
          if ( .not. tracer_advc(iq) ) cycle
          call file_history_in( rhoq_t_bl(:,:,:,iq), trim(tracer_name(iq))//'_t_BL',                      &
                        'RHO*'//trim(tracer_name(iq))//' tendency (BL)', 'kg/m3/s', fill_halo=.true. )
       enddo
 
       if ( statistics_checktotal ) then
          call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                                 rhou_t_bl(:,:,:), 'RHOU_t_BL',      &
                                 atmos_grid_cartesc_real_vol(:,:,:), &
                                 atmos_grid_cartesc_real_totvol      )
          call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                                 rhov_t_bl(:,:,:), 'RHOV_t_BL',      &
                                 atmos_grid_cartesc_real_vol(:,:,:), &
                                 atmos_grid_cartesc_real_totvol      )
          call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                                 rhot_t_bl(:,:,:), 'RHOT_t_BL',      &
                                 atmos_grid_cartesc_real_vol(:,:,:), &
                                 atmos_grid_cartesc_real_totvol      )
          call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                                 nu(:,:,:),        'Nu_BL',          &
                                 atmos_grid_cartesc_real_vol(:,:,:), &
                                 atmos_grid_cartesc_real_totvol      )
          call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                                 kh(:,:,:),         'Kh_BL',         &
                                 atmos_grid_cartesc_real_vol(:,:,:), &
                                 atmos_grid_cartesc_real_totvol      )
 
          do iq = 1, qa
             if ( .not. tracer_advc(iq) ) cycle
             call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                                    rhoq_t_bl(:,:,:,iq), trim(tracer_name(iq))//'_t_BL', &
                                    atmos_grid_cartesc_real_vol(:,:,:),                  &
                                    atmos_grid_cartesc_real_totvol                       )
          enddo
       endif
 
    endif
 
    !$omp parallel do default(none) private(i,j,k) OMP_SCHEDULE_ collapse(2) &
    !$omp shared(JS,JE,IS,IE,KS,KE,RHOU_t,RHOU_t_BL,RHOV_t,RHOV_t_BL,RHOT_t,RHOT_t_BL)
    do j = js, je
    do i = is, ie
    do k = ks, ke
       rhou_t(k,i,j) = rhou_t(k,i,j) + rhou_t_bl(k,i,j)
       rhov_t(k,i,j) = rhov_t(k,i,j) + rhov_t_bl(k,i,j)
       rhot_t(k,i,j) = rhot_t(k,i,j) + rhot_t_bl(k,i,j)
    enddo
    enddo
    enddo
 
    do iq = 1,  qa
       if ( .not. tracer_advc(iq) ) cycle
       !$omp parallel do private(i,j,k) OMP_SCHEDULE_ collapse(3)
       do j  = js, je
       do i  = is, ie
       do k  = ks, ke
          rhoq_t(k,i,j,iq) = rhoq_t(k,i,j,iq) + rhoq_t_bl(k,i,j,iq)
       enddo
       enddo
       enddo
    enddo
 
    return
  end subroutine atmos_phy_bl_driver_calc_tendency
 
end module mod_atmos_phy_bl_driver