mod_atmos_phy_ae_driver.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module mod_atmos_phy_ae_driver
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_atmos_grid_cartesc_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_ae_driver_tracer_setup
  public :: atmos_phy_ae_driver_setup
  public :: atmos_phy_ae_driver_adjustment
  public :: atmos_phy_ae_driver_calc_tendency
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_driver_tracer_setup
    use mod_atmos_admin, only: &
       atmos_phy_ae_type, &
       atmos_sw_phy_ae
    use scale_tracer, only: &
       tracer_regist
    use scale_atmos_phy_ae_kajino13, only: &
       atmos_phy_ae_kajino13_tracer_setup, &
       atmos_phy_ae_kajino13_name, &
       atmos_phy_ae_kajino13_desc, &
       atmos_phy_ae_kajino13_unit
    use scale_prc, only: &
       prc_abort
    use mod_atmos_phy_ae_vars, only: &
       qa_ae, &
       qs_ae, &
       qe_ae
    implicit none
 
    log_newline
    log_info("ATMOS_PHY_AE_driver_tracer_setup",*) 'Setup'
 
    if ( atmos_sw_phy_ae ) then
       select case ( atmos_phy_ae_type )
       case ( 'OFF', 'NONE' )
          log_info("ATMOS_PHY_AE_driver_tracer_setup",*) 'this component is never called.'
       case ( 'KAJINO13' )
          call atmos_phy_ae_kajino13_tracer_setup( qa_ae ) ! [OUT]
 
          call tracer_regist( qs_ae,                         & ! [OUT]
                              qa_ae,                         & ! [IN]
                              atmos_phy_ae_kajino13_name(:), & ! [IN]
                              atmos_phy_ae_kajino13_desc(:), & ! [IN]
                              atmos_phy_ae_kajino13_unit(:)  ) ! [IN]
       case ( 'OFFLINE' )
          log_info("ATMOS_PHY_AE_driver_tracer_setup",*) 'offline aerosol module has no tracers'
       case default
          log_error("ATMOS_PHY_AE_driver_tracer_setup",*) 'invalid aerosol type(', atmos_phy_ae_type, '). CHECK!'
          call prc_abort
       end select
 
       qe_ae = qs_ae + qa_ae - 1
 
    else
       qa_ae = 0
       qs_ae = -1
       qe_ae = -2
    end if
 
    return
  end subroutine atmos_phy_ae_driver_tracer_setup
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_driver_setup
    use mod_atmos_admin, only: &
       atmos_phy_ae_type, &
       atmos_sw_phy_ae
    use scale_atmos_phy_ae_kajino13, only: &
        atmos_phy_ae_kajino13_setup
    use scale_atmos_phy_ae_offline, only: &
        atmos_phy_ae_offline_setup
    use scale_prc, only: &
       prc_abort
    implicit none
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_PHY_AE_driver_setup",*) 'Setup'
 
    if ( atmos_sw_phy_ae ) then
 
       select case ( atmos_phy_ae_type )
       case ( 'KAJINO13' )
          call atmos_phy_ae_kajino13_setup
       case ( 'OFFLINE' )
          call atmos_phy_ae_offline_setup
       case default
          log_error("ATMOS_PHY_AE_driver_setup",*) 'invalid aerosol type(', atmos_phy_ae_type, '). CHECK!'
          call prc_abort
       end select
 
    endif
 
    return
  end subroutine atmos_phy_ae_driver_setup
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_driver_adjustment
    use mod_atmos_vars, only: &
       qtrc
    use mod_atmos_phy_ae_vars, only: &
       qa_ae, &
       qs_ae, &
       qe_ae
    use mod_atmos_admin, only: &
       atmos_phy_ae_type, &
       atmos_sw_phy_ae
    use scale_atmos_phy_ae_kajino13, only: &
        atmos_phy_ae_kajino13_negative_fixer
    implicit none
 
    if ( atmos_sw_phy_ae ) then
 
       select case ( atmos_phy_ae_type )
       case ( 'KAJINO13' )
          call atmos_phy_ae_kajino13_negative_fixer( ka, ks, ke, ia, is, ie, ja, js, je, qa_ae, &
                                                     qtrc(:,:,:,qs_ae:qe_ae) ) ! [INOUT]
       end select
 
    end if
 
    return
  end subroutine atmos_phy_ae_driver_adjustment
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_driver_calc_tendency( update_flag )
    use scale_tracer, only: &
       tracer_name
    use scale_prc, only: &
       prc_abort
    use scale_time, only: &
       dt_ae => time_dtsec_atmos_phy_ae, &
       time_nowdaysec
    use scale_statistics, only: &
       statistics_checktotal, &
       statistics_total
    use scale_atmos_grid_cartesc_real, only: &
       atmos_grid_cartesc_real_vol, &
       atmos_grid_cartesc_real_totvol
    use scale_file_history, only: &
       file_history_in
    use mod_atmos_vars, only: &
       dens => dens_av, &
       qtrc => qtrc_av, &
       qdry, &
       pres, &
       temp, &
       qv,   &
       rhoq_t => rhoq_tp
    use mod_atmos_phy_ae_vars, only: &
       qa_ae, &
       qs_ae, &
       qe_ae, &
       rhoq_t_ae => atmos_phy_ae_rhoq_t, &
       ccn       => atmos_phy_ae_ccn,   &
       ccn_t     => atmos_phy_ae_ccn_t, &
       ae_emit   => atmos_phy_ae_emit
    use mod_atmos_phy_mp_vars, only: &
       evaporate => atmos_phy_mp_evaporate
    use mod_atmos_admin, only: &
       atmos_phy_ae_type
    use scale_atmos_phy_ae_kajino13, only: &
       atmos_phy_ae_kajino13_tendency
    use scale_atmos_phy_ae_offline, only: &
       atmos_phy_ae_offline_tendency
    implicit none
 
    logical, intent(in) :: update_flag
 
    real(rp) :: cn(ka,ia,ja)
    real(rp) :: nreg(ka,ia,ja)
 
    integer  :: k, i, j, iq
    !---------------------------------------------------------------------------
 
    if ( update_flag ) then
 
!OCL XFILL
       ccn(:,:,:)   = 0.0_rp ! reset
!OCL XFILL
       rhoq_t_ae(:,:,:,:) = 0.0_rp ! reset
 
       do j  = js, je
       do i  = is, ie
       do k  = ks, ke
          nreg(k,i,j) = evaporate(k,i,j) * dt_ae
       enddo
       enddo
       enddo
 
       select case ( atmos_phy_ae_type )
       case ( 'KAJINO13' )
          call atmos_phy_ae_kajino13_tendency( ka, ks, ke, ia, is, ie, ja, js, je, qa_ae, &
                                               temp(:,:,:),             & ! [IN]
                                               pres(:,:,:),             & ! [IN]
                                               qdry(:,:,:),             & ! [IN]
                                               nreg(:,:,:),             & ! [IN]
                                               dens(:,:,:),             & ! [IN]
                                               qv(:,:,:),             & ! [IN]
                                               qtrc(:,:,:,qs_ae:qe_ae), & ! [IN]
                                               ae_emit(:,:,:,qs_ae:qe_ae), & ! [IN]
                                               dt_ae,                        & ! [IN]
                                               rhoq_t_ae(:,:,:,qs_ae:qe_ae), & ! [OUT]
                                               cn(:,:,:),             & ! [OUT]
                                               ccn(:,:,:)              ) ! [OUT]
       case ( 'OFFLINE' )
          call atmos_phy_ae_offline_tendency ( ka, ks, ke, ia, is, ie, ja, js, je, &
                                               time_nowdaysec,               & ! [IN]
                                               ccn(:,:,:)              ) ! [OUT]
          cn(:,:,:) = 0.0_rp ! not supported
       end select
 
       ccn_t(:,:,:) = ccn(:,:,:) / dt_ae
 
       call file_history_in( cn(:,:,:)*1.e-6_rp, 'CN',  'condensation nucrei',       'num/cc' )
       call file_history_in( ccn(:,:,:)*1.e-6_rp, 'CCN', 'cloud condensation nucrei', 'num/cc' )
 
    endif
 
    do iq = qs_ae, qe_ae
       !$omp parallel do private(i,j,k) OMP_SCHEDULE_
       do j  = js, je
       do i  = is, ie
       do k  = ks, ke
          rhoq_t(k,i,j,iq) = rhoq_t(k,i,j,iq) + rhoq_t_ae(k,i,j,iq)
       enddo
       enddo
       enddo
    enddo
 
    if ( statistics_checktotal ) then
       do iq = qs_ae, qe_ae
          call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                                 rhoq_t_ae(:,:,:,iq), trim(tracer_name(iq))//'_t_AE', &
                                 atmos_grid_cartesc_real_vol(:,:,:),                  &
                                 atmos_grid_cartesc_real_totvol                       )
       enddo
    endif
 
    return
  end subroutine atmos_phy_ae_driver_calc_tendency
 
end module mod_atmos_phy_ae_driver