scale_atmos_phy_tb.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
module scale_atmos_phy_tb
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  abstract interface
     subroutine tb( &
       qflx_sgs_momz, qflx_sgs_momx, qflx_sgs_momy, &
       qflx_sgs_rhot, qflx_sgs_rhoq,                &
       RHOQ_t,                                      &
       nu_C, Ri, Pr,                                &
       MOMZ, MOMX, MOMY, RHOT, DENS, QTRC, N2,      &
       SFLX_MW, SFLX_MU, SFLX_MV, SFLX_SH, SFLX_Q,  &
       GSQRT, J13G, J23G, J33G, MAPF, dt            )
       use scale_precision
       use scale_grid_index
       use scale_tracer
       implicit none

       real(RP), intent(out)   :: qflx_sgs_momz(KA,IA,JA,3)
       real(RP), intent(out)   :: qflx_sgs_momx(KA,IA,JA,3)
       real(RP), intent(out)   :: qflx_sgs_momy(KA,IA,JA,3)
       real(RP), intent(out)   :: qflx_sgs_rhot(KA,IA,JA,3)
       real(RP), intent(out)   :: qflx_sgs_rhoq(KA,IA,JA,3,QA)

       real(RP), intent(inout) :: RHOQ_t       (KA,IA,JA,QA) ! tendency of rho * QTRC

       real(RP), intent(out)   :: nu_C         (KA,IA,JA)    ! eddy viscosity (center)
       real(RP), intent(out)   :: Ri           (KA,IA,JA)    ! Richardson number
       real(RP), intent(out)   :: Pr           (KA,IA,JA)    ! Prantle number

       real(RP), intent(in)    :: MOMZ         (KA,IA,JA)
       real(RP), intent(in)    :: MOMX         (KA,IA,JA)
       real(RP), intent(in)    :: MOMY         (KA,IA,JA)
       real(RP), intent(in)    :: RHOT         (KA,IA,JA)
       real(RP), intent(in)    :: DENS         (KA,IA,JA)
       real(RP), intent(in)    :: QTRC         (KA,IA,JA,QA)
       real(RP), intent(in)    :: N2           (KA,IA,JA)

       real(RP), intent(in)    :: SFLX_MW      (IA,JA)
       real(RP), intent(in)    :: SFLX_MU      (IA,JA)
       real(RP), intent(in)    :: SFLX_MV      (IA,JA)
       real(RP), intent(in)    :: SFLX_SH      (IA,JA)
       real(RP), intent(in)    :: SFLX_Q       (IA,JA,QA)

       real(RP), intent(in)    :: GSQRT        (KA,IA,JA,7)
       real(RP), intent(in)    :: J13G         (KA,IA,JA,7)
       real(RP), intent(in)    :: J23G         (KA,IA,JA,7)
       real(RP), intent(in)    :: J33G
       real(RP), intent(in)    :: MAPF         (IA,JA,2,4)
       real(DP), intent(in)    :: dt
     end subroutine tb

     subroutine su( &
          CDZ, CDX, CDY, CZ )
       use scale_precision
       use scale_grid_index
       use scale_tracer
       implicit none

       real(RP), intent(in) :: CDZ(KA)
       real(RP), intent(in) :: CDX(IA)
       real(RP), intent(in) :: CDY(JA)
       real(RP), intent(in) :: CZ (KA,IA,JA)
     end subroutine su
  end interface

  procedure(tb), pointer :: atmos_phy_tb       => null()

  procedure(su), pointer :: atmos_phy_tb_setup => null()

  public :: atmos_phy_tb_config
  public :: atmos_phy_tb
  public :: atmos_phy_tb_setup

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  integer, public :: i_tke = -1

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_tb_config( TB_TYPE )
    use scale_process, only: &
       prc_mpistop
    use scale_atmos_phy_tb_smg, only: &
       atmos_phy_tb_smg_config, &
       atmos_phy_tb_smg_setup, &
       atmos_phy_tb_smg
    use scale_atmos_phy_tb_d1980, only: &
       atmos_phy_tb_d1980_config, &
       atmos_phy_tb_d1980_setup, &
       atmos_phy_tb_d1980
    use scale_atmos_phy_tb_dns, only: &
       atmos_phy_tb_dns_config, &
       atmos_phy_tb_dns_setup, &
       atmos_phy_tb_dns
    use scale_atmos_phy_tb_mynn, only: &
       atmos_phy_tb_mynn_config, &
       atmos_phy_tb_mynn_setup, &
       atmos_phy_tb_mynn
    use scale_atmos_phy_tb_hybrid, only: &
       atmos_phy_tb_hybrid_config, &
       atmos_phy_tb_hybrid_setup, &
       atmos_phy_tb_hybrid
    implicit none

    character(len=*), intent(in) :: tb_type
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*) '*** => ', trim(tb_type), ' is selected.'

    select case( tb_type )
    case( 'SMAGORINSKY' )

       call atmos_phy_tb_smg_config( tb_type, & ! [IN]
                                     i_tke    ) ! [OUT]

       atmos_phy_tb       => atmos_phy_tb_smg
       atmos_phy_tb_setup => atmos_phy_tb_smg_setup

    case( 'D1980' )

       call atmos_phy_tb_d1980_config( tb_type, & ! [IN]
                                       i_tke    ) ! [OUT]

       atmos_phy_tb       => atmos_phy_tb_d1980
       atmos_phy_tb_setup => atmos_phy_tb_d1980_setup

    case( 'DNS' )

       call atmos_phy_tb_dns_config( tb_type, & ! [IN]
                                     i_tke    ) ! [OUT]

       atmos_phy_tb       => atmos_phy_tb_dns
       atmos_phy_tb_setup => atmos_phy_tb_dns_setup

    case( 'MYNN' )

       call atmos_phy_tb_mynn_config( tb_type, & ! [IN]
                                      i_tke    ) ! [OUT]

       atmos_phy_tb       => atmos_phy_tb_mynn
       atmos_phy_tb_setup => atmos_phy_tb_mynn_setup

    case('HYBRID')

       call atmos_phy_tb_hybrid_config( tb_type, & ! [IN]
                                        i_tke    ) ! [OUT]

       atmos_phy_tb       => atmos_phy_tb_hybrid
       atmos_phy_tb_setup => atmos_phy_tb_hybrid_setup

    case('OFF')

       ! do nothing

    case default

       write(*,*) 'xxx ATMOS_PHY_TB_TYPE is invalid: ', tb_type
       call prc_mpistop

    end select

    return
  end subroutine atmos_phy_tb_config

end module scale_atmos_phy_tb