scale_atmos_dyn_tinteg_short.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "inc_openmp.h"
module scale_atmos_dyn_tinteg_short
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_dyn_tinteg_short_setup

  abstract interface
     subroutine short( &
          DENS, MOMZ, MOMX, MOMY, RHOT, PROG,       & ! (inout)
          mflx_hi, tflx_hi,                         & ! (inout)
          dens_t, momz_t, momx_t, momy_t, rhot_t,   & ! (in)
          rtot, cvtot, corioli,                     & ! (in)
          num_diff, wdamp_coef, divdmp_coef, ddiv,  & ! (in)
          flag_fct_momentum, flag_fct_t,            & ! (in)
          flag_fct_along_stream,                    & ! (in)
          cdz, fdz, fdx, fdy,                       & ! (in)
          rcdz, rcdx, rcdy, rfdz, rfdx, rfdy,       & ! (in)
          phi, gsqrt, j13g, j23g, j33g, mapf,       & ! (in)
          ref_pres, ref_dens,                       & ! (in)
          bnd_w, bnd_e, bnd_s, bnd_n,               & ! (in)
          dt                                        ) ! (in)
       use scale_precision
       use scale_grid_index
       use scale_index
       real(RP), intent(inout) :: DENS(KA,IA,JA)
       real(RP), intent(inout) :: MOMZ(KA,IA,JA)
       real(RP), intent(inout) :: MOMX(KA,IA,JA)
       real(RP), intent(inout) :: MOMY(KA,IA,JA)
       real(RP), intent(inout) :: RHOT(KA,IA,JA)
       real(RP), intent(inout) :: PROG(KA,IA,JA,VA)

       real(RP), intent(inout) :: mflx_hi(KA,IA,JA,3)
       real(RP), intent(inout) :: tflx_hi(KA,IA,JA,3)

       real(RP), intent(in)    :: DENS_t(KA,IA,JA)
       real(RP), intent(in)    :: MOMZ_t(KA,IA,JA)
       real(RP), intent(in)    :: MOMX_t(KA,IA,JA)
       real(RP), intent(in)    :: MOMY_t(KA,IA,JA)
       real(RP), intent(in)    :: RHOT_t(KA,IA,JA)

       real(RP), intent(in)    :: Rtot(KA,IA,JA)
       real(RP), intent(in)    :: CVtot(KA,IA,JA)
       real(RP), intent(in)    :: CORIOLI(IA,JA)

       real(RP), intent(in)    :: num_diff(KA,IA,JA,5,3)
       real(RP), intent(in)    :: wdamp_coef(KA)
       real(RP), intent(in)    :: divdmp_coef
       real(RP), intent(in)    :: DDIV(KA,IA,JA)

       logical,  intent(in)    :: FLAG_FCT_MOMENTUM
       logical,  intent(in)    :: FLAG_FCT_T
       logical,  intent(in)    :: FLAG_FCT_ALONG_STREAM

       real(RP), intent(in)    :: CDZ (KA)
       real(RP), intent(in)    :: FDZ (KA-1)
       real(RP), intent(in)    :: FDX (IA-1)
       real(RP), intent(in)    :: FDY (JA-1)
       real(RP), intent(in)    :: RCDZ(KA)
       real(RP), intent(in)    :: RCDX(IA)
       real(RP), intent(in)    :: RCDY(JA)
       real(RP), intent(in)    :: RFDZ(KA-1)
       real(RP), intent(in)    :: RFDX(IA-1)
       real(RP), intent(in)    :: RFDY(JA-1)

       real(RP), intent(in)    :: PHI  (KA,IA,JA)
       real(RP), intent(in)    :: GSQRT(KA,IA,JA,7)
       real(RP), intent(in)    :: J13G (KA,IA,JA,7)
       real(RP), intent(in)    :: J23G (KA,IA,JA,7)
       real(RP), intent(in)    :: J33G
       real(RP), intent(in)    :: MAPF (IA,JA,2,4)

       real(RP), intent(in)    :: REF_pres(KA,IA,JA)
       real(RP), intent(in)    :: REF_dens(KA,IA,JA)

       logical,  intent(in)    :: BND_W
       logical,  intent(in)    :: BND_E
       logical,  intent(in)    :: BND_S
       logical,  intent(in)    :: BND_N

       real(RP), intent(in)    :: dt
     end subroutine short
  end interface
  procedure(short), pointer :: atmos_dyn_tinteg_short => null()
  public :: atmos_dyn_tinteg_short

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_tinteg_short_setup( &
       ATMOS_DYN_Tinteg_short_TYPE )

    use scale_precision
    use scale_grid_index
    use scale_index
    use scale_process, only: &
       prc_mpistop
    use scale_atmos_dyn_tinteg_short_rk3, only: &
       atmos_dyn_tinteg_short_rk3_setup, &
       atmos_dyn_tinteg_short_rk3
    use scale_atmos_dyn_tinteg_short_rk4, only: &
       atmos_dyn_tinteg_short_rk4_setup, &
       atmos_dyn_tinteg_short_rk4
    implicit none

    character(len=*), intent(in)  :: atmos_dyn_tinteg_short_type
    !---------------------------------------------------------------------------

    select case( atmos_dyn_tinteg_short_type )
    case( 'RK3', 'RK3WS2002' )
       call atmos_dyn_tinteg_short_rk3_setup( &
            atmos_dyn_tinteg_short_type )
       atmos_dyn_tinteg_short => atmos_dyn_tinteg_short_rk3
    case( 'RK4' )
       call atmos_dyn_tinteg_short_rk4_setup( &
            atmos_dyn_tinteg_short_type )
       atmos_dyn_tinteg_short => atmos_dyn_tinteg_short_rk4
    case( 'OFF', 'NONE' )
       ! do nothing
    case default
       write(*,*) 'xxx ATMOS_DYN_TINTEG_SHORT_TYPE is invalid: ', atmos_dyn_tinteg_short_type
       call prc_mpistop
    end select

    return
  end subroutine atmos_dyn_tinteg_short_setup

end module scale_atmos_dyn_tinteg_short