mod_atmos_admin.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
module mod_atmos_admin
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_admin_setup
  public :: atmos_admin_getscheme

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,                public :: atmos_do          = .true. ! main switch for the model

  character(len=H_SHORT), public :: atmos_dyn_type    = 'NONE'
  character(len=H_SHORT), public :: atmos_phy_mp_type = 'NONE'
  character(len=H_SHORT), public :: atmos_phy_ae_type = 'NONE'
  character(len=H_SHORT), public :: atmos_phy_ch_type = 'NONE'
  character(len=H_SHORT), public :: atmos_phy_rd_type = 'NONE'
  character(len=H_SHORT), public :: atmos_phy_sf_type = 'NONE'
  character(len=H_SHORT), public :: atmos_phy_tb_type = 'NONE'
  character(len=H_SHORT), public :: atmos_phy_cp_type = 'NONE'

  logical,                public :: atmos_use_average = .false.

  logical,                public :: atmos_sw_dyn
  logical,                public :: atmos_sw_phy_mp
  logical,                public :: atmos_sw_phy_ae
  logical,                public :: atmos_sw_phy_ch
  logical,                public :: atmos_sw_phy_rd
  logical,                public :: atmos_sw_phy_sf
  logical,                public :: atmos_sw_phy_tb
  logical,                public :: atmos_sw_phy_cp

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_admin_setup
    use scale_process, only: &
       prc_mpistop
    implicit none

    namelist / param_atmos / &
       atmos_do,          &
       atmos_dyn_type,    &
       atmos_phy_mp_type, &
       atmos_phy_ae_type, &
       atmos_phy_ch_type, &
       atmos_phy_rd_type, &
       atmos_phy_sf_type, &
       atmos_phy_tb_type, &
       atmos_phy_cp_type, &
       atmos_use_average

    integer :: ierr
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[ADMIN] / Categ[ATMOS] / Origin[SCALE-RM]'

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       if( io_l ) write(io_fid_log,*) '*** Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       write(*,*) 'xxx Not appropriate names in namelist PARAM_ATMOS. Check!'
       call prc_mpistop
    endif
    if( io_nml ) write(io_fid_nml,nml=param_atmos)

    !-----< module component check >-----

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Atmosphere model components ***'

    if ( atmos_do ) then
       if( io_l ) write(io_fid_log,*) '*** Atmosphere model       : ON'
    else
       if( io_l ) write(io_fid_log,*) '*** Atmosphere model       : OFF'
    endif

    if( io_l ) write(io_fid_log,*) '*** Dynamics...'

    if    ( atmos_dyn_type == 'OFF' ) then
       if( io_l ) write(io_fid_log,*) '*** + Dynamical core       : OFF'
       if( io_l ) write(io_fid_log,*) '*** + Advection            : OFF'
       atmos_sw_dyn = .false.
    elseif( atmos_dyn_type == 'NONE' ) then
       ! The advection is disbled
       ! The tendencies calculated by physical processed are added
       if( io_l ) write(io_fid_log,*) '*** + Dynamical core       : ON, ', trim(atmos_dyn_type)
       if( io_l ) write(io_fid_log,*) '*** + Advection            : OFF'
       atmos_sw_dyn = .true.
    else ! default
       if( io_l ) write(io_fid_log,*) '*** + Dynamical core       : ON, ', trim(atmos_dyn_type)
       if( io_l ) write(io_fid_log,*) '*** + Advection            : ON'
       atmos_sw_dyn = .true.
    endif

    if( io_l ) write(io_fid_log,*) '*** Physics...'

    if ( atmos_phy_mp_type /= 'OFF' .AND. atmos_phy_mp_type /= 'NONE' ) then
       if( io_l ) write(io_fid_log,*) '*** + Cloud Microphysics   : ON, ', trim(atmos_phy_mp_type)
       atmos_sw_phy_mp = .true.
    else
       if( io_l ) write(io_fid_log,*) '*** + Cloud Microphysics   : OFF'
       atmos_sw_phy_mp = .false.
    endif

    if ( atmos_phy_ae_type /= 'OFF' .AND. atmos_phy_ae_type /= 'NONE' ) then
       if( io_l ) write(io_fid_log,*) '*** + Aerosol Microphysics : ON, ', trim(atmos_phy_ae_type)
       atmos_sw_phy_ae = .true.
    else
       if( io_l ) write(io_fid_log,*) '*** + Aerosol Microphysics : OFF'
       atmos_sw_phy_ae = .false.
    endif

    if ( atmos_phy_ch_type /= 'OFF' .AND. atmos_phy_ch_type /= 'NONE' ) then
       if( io_l ) write(io_fid_log,*) '*** + Chemistry            : ON, ', trim(atmos_phy_ch_type)
       atmos_sw_phy_ch = .true.
    else
       if( io_l ) write(io_fid_log,*) '*** + Chemistry            : OFF'
       atmos_sw_phy_ch = .false.
    endif

    if ( atmos_phy_rd_type /= 'OFF' .AND. atmos_phy_rd_type /= 'NONE' ) then
       if( io_l ) write(io_fid_log,*) '*** + Radiative transfer   : ON, ', trim(atmos_phy_rd_type)
       atmos_sw_phy_rd = .true.
    else
       if( io_l ) write(io_fid_log,*) '*** + Radiative transfer   : OFF'
       atmos_sw_phy_rd = .false.
    endif

    if ( atmos_phy_sf_type /= 'OFF' .AND. atmos_phy_sf_type /= 'NONE' ) then
       if( io_l ) write(io_fid_log,*) '*** + Surface Flux         : ON, ', trim(atmos_phy_sf_type)
       atmos_sw_phy_sf = .true.
    else
       if( io_l ) write(io_fid_log,*) '*** + Surface Flux         : OFF'
       atmos_sw_phy_sf = .false.
    endif

    if ( atmos_phy_tb_type /= 'OFF' .AND. atmos_phy_tb_type /= 'NONE' ) then
       if( io_l ) write(io_fid_log,*) '*** + Sub-grid Turbulence  : ON, ', trim(atmos_phy_tb_type)
       atmos_sw_phy_tb = .true.
    else
       if( io_l ) write(io_fid_log,*) '*** + Sub-grid Turbulence  : OFF'
       atmos_sw_phy_tb = .false.
    endif

    if ( atmos_phy_cp_type /= 'OFF' .AND. atmos_phy_cp_type /= 'NONE' ) then
       if( io_l ) write(io_fid_log,*) '*** + Convection Param.    : ON, ', trim(atmos_phy_cp_type)
       atmos_sw_phy_cp = .true.
    else
       if( io_l ) write(io_fid_log,*) '*** + Convection Param.    : OFF'
       atmos_sw_phy_cp = .false.
    endif

    if ( atmos_use_average ) then
       if( io_l ) write(io_fid_log,*) '*** + Use time-averaging value for physics? : YES'
    else
       if( io_l ) write(io_fid_log,*) '*** + Use time-averaging value for physics? : NO'
    endif

    return
  end subroutine atmos_admin_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_admin_getscheme( &
       component_name, &
       scheme_name     )
    use scale_process, only: &
       prc_mpistop
    implicit none

    character(len=*),       intent(in)  :: component_name
    character(len=H_SHORT), intent(out) :: scheme_name
    !---------------------------------------------------------------------------

    select case(component_name)
    case("DYN")
       scheme_name = atmos_dyn_type
    case("PHY_MP")
       scheme_name = atmos_phy_mp_type
    case("PHY_AE")
       scheme_name = atmos_phy_ae_type
    case("PHY_CH")
       scheme_name = atmos_phy_ch_type
    case("PHY_RD")
       scheme_name = atmos_phy_rd_type
    case("PHY_SF")
       scheme_name = atmos_phy_sf_type
    case("PHY_TB")
       scheme_name = atmos_phy_tb_type
    case("PHY_CP")
       scheme_name = atmos_phy_cp_type
    case default
       write(*,*) 'xxx Unsupported component_name. Check!', trim(component_name)
       call prc_mpistop
    end select

    return
  end subroutine atmos_admin_getscheme

end module mod_atmos_admin