scale_urban_grid.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
module scale_urban_grid
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_urban_grid_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: urban_grid_setup

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  real(RP), public, allocatable :: grid_ucz  (:)
  real(RP), public, allocatable :: grid_ufz  (:)
  real(RP), public, allocatable :: grid_ucdz (:)

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  private :: urban_grid_read
  private :: urban_grid_generate

  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  real(RP), private :: udz(200)

  character(len=H_LONG), private :: urban_grid_in_basename  = ''
  character(len=H_LONG), private :: urban_grid_out_basename = ''

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine urban_grid_setup
    use scale_process, only: &
       prc_mpistop
    implicit none

    namelist / param_urban_grid / &
       urban_grid_in_basename,  &
       urban_grid_out_basename, &
       udz

    integer :: ierr
    integer :: k
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[GRID] / Categ[URBAN GRID] / Origin[SCALElib]'

    udz(:) = 0.0_rp

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_urban_grid,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       if( io_l ) write(io_fid_log,*) '*** Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       write(*,*) 'xxx Not appropriate names in namelist PARAM_URBAN_GRID. Check!'
       call prc_mpistop
    endif
    if( io_nml ) write(io_fid_nml,nml=param_urban_grid)

    allocate( grid_ucz(uks  :uke) )
    allocate( grid_ufz(uks-1:uke) )
    allocate( grid_ucdz(uks  :uke) )

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Urban grid information ***'

    if ( urban_grid_in_basename /= '' ) then
       call urban_grid_read
    else
       if( io_l ) write(io_fid_log,*) '*** Not found input grid file. Grid position is calculated.'

       call urban_grid_generate
    endif

    if ( uke == uks ) then
       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Single layer. LDZ = ', udz(1)
    else
       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,'(1x,A)') &
       '|====== Vertical Coordinate ======|'
       if( io_l ) write(io_fid_log,'(1x,A)') &
       '|   k       z      zh      dz   k |'
       if( io_l ) write(io_fid_log,'(1x,A)') &
       '|         [m]     [m]     [m]     |'
       k = uks-1
       if( io_l ) write(io_fid_log,'(1x,A,F8.3,A,I4,A)') &
       '|            ',grid_ufz(k),'        ',k,' | Atmosphere interface'
       do k = uks, uke-1
       if( io_l ) write(io_fid_log,'(1x,A,I4,F8.3,A,F8.3,A)') &
       '|',k,grid_ucz(k),'        ',grid_ucdz(k),'     | '
       if( io_l ) write(io_fid_log,'(1x,A,F8.3,A,I4,A)') &
       '|            ',grid_ufz(k),'       |',k,' | '
       enddo
       k = uke
       if( io_l ) write(io_fid_log,'(1x,A,I4,F8.3,A,F8.3,A)') &
       '|',k,grid_ucz(k),'        ',grid_ucdz(k),'     | '
       if( io_l ) write(io_fid_log,'(1x,A,F8.3,A,I4,A)') &
       '|            ',grid_ufz(k),'        ',k,' | bedrock'
       if( io_l ) write(io_fid_log,'(1x,A)') &
       '|=================================|'
    endif

    return
  end subroutine urban_grid_setup

  !-----------------------------------------------------------------------------
  subroutine urban_grid_read
    use gtool_file, only: &
       fileread
    use scale_process, only: &
       prc_myrank
    implicit none

    character(len=H_LONG) :: bname
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Input urban grid file ***'

    write(bname,'(A,A,F15.3)') trim(urban_grid_in_basename)

    call fileread( grid_ucz(:),  bname, 'UCZ',  1, prc_myrank )
    call fileread( grid_ucdz(:), bname, 'UCDZ', 1, prc_myrank )
    call fileread( grid_ufz(:),  bname, 'UFZ',  1, prc_myrank )

    return
  end subroutine urban_grid_read

  !-----------------------------------------------------------------------------
  subroutine urban_grid_generate
    implicit none

    integer :: k
    !---------------------------------------------------------------------------

    do k = uks, uke
       grid_ucdz(k) = udz(k)
    enddo

    grid_ufz(uks-1) = 0.0_rp

    do k = uks, uke
       grid_ucz(k) = grid_ucdz(k) / 2.0_rp + grid_ufz(k-1)
       grid_ufz(k) = grid_ucdz(k)          + grid_ufz(k-1)
    enddo

    return
  end subroutine urban_grid_generate

end module scale_urban_grid