scale_land_sfc.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
module scale_land_sfc
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_grid_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: land_sfc_setup

  abstract interface
     subroutine lndsfc( &
           LST_t,  &
           ZMFLX,  &
           XMFLX,  &
           YMFLX,  &
           SHFLX,  &
           LHFLX,  &
           GHFLX,  &
           U10,    &
           V10,    &
           T2,     &
           Q2,     &
           TMPA,   &
           PRSA,   &
           WA,     &
           UA,     &
           VA,     &
           RHOA,   &
           QVA,    &
           Z1,     &
           PBL,    &
           PRSS,   &
           LWD,    &
           SWD,    &
           TG,     &
           LST,    &
           QVEF,   &
           ALB_LW, &
           ALB_SW, &
           DZG,    &
           TCS,    &
           Z0M,    &
           Z0H,    &
           Z0E,    &
           dt      )
       use scale_precision
       use scale_grid_index
       implicit none

       real(RP), intent(out) :: lst_t(ia,ja) ! tendency of LST
       real(RP), intent(out) :: zmflx(ia,ja) ! z-momentum flux at the surface [kg/m2/s]
       real(RP), intent(out) :: xmflx(ia,ja) ! x-momentum flux at the surface [kg/m2/s]
       real(RP), intent(out) :: ymflx(ia,ja) ! y-momentum flux at the surface [kg/m2/s]
       real(RP), intent(out) :: shflx(ia,ja) ! sensible heat flux at the surface [J/m2/s]
       real(RP), intent(out) :: lhflx(ia,ja) ! latent heat flux at the surface [J/m2/s]
       real(RP), intent(out) :: ghflx(ia,ja) ! ground heat flux at the surface [J/m2/s]
       real(RP), intent(out) :: u10  (ia,ja) ! velocity u at 10m [m/s]
       real(RP), intent(out) :: v10  (ia,ja) ! velocity v at 10m [m/s]
       real(RP), intent(out) :: t2   (ia,ja) ! temperature at 2m [K]
       real(RP), intent(out) :: q2   (ia,ja) ! water vapor at 2m [kg/kg]

       real(RP), intent(in) :: tmpa(ia,ja) ! temperature at the lowest atmospheric layer [K]
       real(RP), intent(in) :: prsa(ia,ja) ! pressure at the lowest atmospheric layer [Pa]
       real(RP), intent(in) :: wa  (ia,ja) ! velocity w at the lowest atmospheric layer [m/s]
       real(RP), intent(in) :: ua  (ia,ja) ! velocity u at the lowest atmospheric layer [m/s]
       real(RP), intent(in) :: va  (ia,ja) ! velocity v at the lowest atmospheric layer [m/s]
       real(RP), intent(in) :: rhoa(ia,ja) ! density at the lowest atmospheric layer [kg/m3]
       real(RP), intent(in) :: qva (ia,ja) ! ratio of water vapor mass to total mass at the lowest atmospheric layer [kg/kg]
       real(RP), intent(in) :: z1  (ia,ja) ! cell center height at the lowest atmospheric layer [m]
       real(RP), intent(in) :: pbl (ia,ja) ! the top of atmospheric mixing layer [m]
       real(RP), intent(in) :: prss(ia,ja) ! pressure at the surface [Pa]
       real(RP), intent(in) :: lwd (ia,ja) ! downward long-wave radiation flux at the surface (upward positive) [J/m2/s]
       real(RP), intent(in) :: swd (ia,ja) ! downward short-wave radiation flux at the surface (upward positive) [J/m2/s]

       real(RP), intent(in) :: tg    (ia,ja) ! soil temperature [K]
       real(RP), intent(in) :: lst   (ia,ja) ! land surface temperature [K]
       real(RP), intent(in) :: qvef  (ia,ja) ! efficiency of evaporation [0-1]
       real(RP), intent(in) :: alb_lw(ia,ja) ! surface albedo for LW [0-1]
       real(RP), intent(in) :: alb_sw(ia,ja) ! surface albedo for SW [0-1]
       real(RP), intent(in) :: dzg   (ia,ja) ! soil depth [m]
       real(RP), intent(in) :: tcs   (ia,ja) ! thermal conductivity for soil [J/m/K/s]
       real(RP), intent(in) :: z0m   (ia,ja) ! roughness length for momemtum [m]
       real(RP), intent(in) :: z0h   (ia,ja) ! roughness length for heat [m]
       real(RP), intent(in) :: z0e   (ia,ja) ! roughness length for vapor [m]
       real(DP), intent(in) :: dt            ! delta time
     end subroutine lndsfc
  end interface
  procedure(lndsfc), pointer :: land_sfc => null()
  public :: land_sfc

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains

  subroutine land_sfc_setup( LAND_TYPE )
    use scale_process, only: &
       prc_mpistop
    use scale_land_sfc_slab, only: &
       land_sfc_slab_setup, &
       land_sfc_slab
    implicit none

    character(len=*), intent(in) :: LAND_TYPE
    !---------------------------------------------------------------------------

    select case( land_type )
    case ( 'CONST' )
       call land_sfc_slab_setup( land_type )
       land_sfc => land_sfc_slab
    case ( 'SLAB' )
       call land_sfc_slab_setup( land_type )
       land_sfc => land_sfc_slab
    end select

    return
  end subroutine land_sfc_setup

end module scale_land_sfc