scale_ocean_phy_file.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
module scale_ocean_phy_file
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_debug
  use scale_grid_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: ocean_phy_file_setup
  public :: ocean_phy_file

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  logical, allocatable, private :: is_ocn(:,:)

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine ocean_phy_file_setup( OCEAN_TYPE )
    use scale_process, only: &
       prc_mpistop
    use scale_landuse, only: &
       landuse_fact_ocean
    implicit none

    character(len=*), intent(in) :: OCEAN_TYPE

    integer :: i, j
    integer :: ierr
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[FILE] / Categ[OCEAN PHY] / Origin[SCALElib]'

    if( ocean_type /= 'FILE' ) then
       write(*,*) 'xxx wrong OCEAN_TYPE. Check!'
       call prc_mpistop
    end if

    ! judge to run slab ocean model
    allocate( is_ocn(ia,ja) )

    do j = js, je
    do i = is, ie
       if( landuse_fact_ocean(i,j) > 0.0_rp ) then
          is_ocn(i,j) = .true.
       else
          is_ocn(i,j) = .false.
       end if
    end do
    end do

    return
  end subroutine ocean_phy_file_setup

  !-----------------------------------------------------------------------------
  subroutine ocean_phy_file( &
       OCEAN_TEMP_t,    &
       OCEAN_TEMP,      &
       OCEAN_SFLX_WH,   &
       OCEAN_SFLX_prec, &
       OCEAN_SFLX_evap, &
       dt               )
    use scale_grid_index
    use scale_time, only: &
         nowdaysec => time_nowdaysec
    use scale_process, only: &
         prc_mpistop
    use scale_external_input, only: &
         extin_update
    implicit none

    real(RP), intent(out) :: OCEAN_TEMP_t   (ia,ja)
    real(RP), intent(in)  :: OCEAN_TEMP     (ia,ja)
    real(RP), intent(in)  :: OCEAN_SFLX_WH  (ia,ja)
    real(RP), intent(in)  :: OCEAN_SFLX_prec(ia,ja)
    real(RP), intent(in)  :: OCEAN_SFLX_evap(ia,ja)
    real(DP), intent(in)  :: dt

    real(RP) :: OCEAN_TEMP_new(ia,ja)

    logical :: error

    integer :: i, j
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*) '*** Ocean step: File'

    call extin_update( &
         ocean_temp_new, & ! (out)
         'OCEAN_TEMP',   & ! (in)
         'XY',           & ! (in)
         nowdaysec,      & ! (in)
         error           ) ! (out)
    if ( error ) then
       write(*,*) 'xxx Failed to read "OCEAN_TEMP" data from file!'
       write(*,*) 'xxx set namelist EXTITEM, for example'
       write(*,*) ' &EXTITEM'
       write(*,*) '  basename   = "filename",'
       write(*,*) '  varname    = "OCEAN_TEMP",'
       write(*,*) ' /'
       call prc_mpistop
    end if

    do j = js, je
    do i = is, ie
       if( is_ocn(i,j) ) then
          ocean_temp_t(i,j) = ( ocean_temp_new(i,j) - ocean_temp(i,j) ) / dt
       else
          ocean_temp_t(i,j) = 0.0_rp
       endif
    enddo
    enddo

    return
  end subroutine ocean_phy_file

end module scale_ocean_phy_file