scale_atmos_dyn_tinteg_tracer.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "inc_openmp.h"
module scale_atmos_dyn_tinteg_tracer
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_dyn_tinteg_tracer_setup

  abstract interface
     subroutine tinteg( &
          QTRC, & ! (out)
          qtrc0, rhoq_t, &! (in)
          dens0, dens, & ! (in)
          mflx_hi, num_diff, & ! (in)
          gsqrt, mapf, & ! (in)
          cdz, rcdz, rcdx, rcdy, & ! (in)
          dtl, & ! (in)
          flag_fct_tracer, & ! (in)
          flag_fct_along_stream ) ! (in)
       use scale_precision
       use scale_grid_index
       use scale_index
       real(RP), intent(inout) :: qtrc    (ka,ia,ja)
       real(RP), intent(in)    :: qtrc0   (ka,ia,ja)
       real(RP), intent(in)    :: rhoq_t  (ka,ia,ja)
       real(RP), intent(in)    :: dens0   (ka,ia,ja)
       real(RP), intent(in)    :: dens    (ka,ia,ja)
       real(RP), intent(in)    :: mflx_hi (ka,ia,ja,3)
       real(RP), intent(in)    :: num_diff(ka,ia,ja,3)
       real(RP), intent(in)    :: gsqrt   (ka,ia,ja,7)
       real(RP), intent(in)    :: mapf    (ia,ja)
       real(RP), intent(in)    :: cdz(ka)
       real(RP), intent(in)    :: rcdz(ka)
       real(RP), intent(in)    :: rcdx(ia)
       real(RP), intent(in)    :: rcdy(ja)
       real(RP), intent(in)    :: dtl
       logical,  intent(in)    :: flag_fct_tracer
       logical,  intent(in)    :: flag_fct_along_stream
     end subroutine tinteg
  end interface
  procedure(tinteg), pointer :: atmos_dyn_tinteg_tracer => null()
  public :: atmos_dyn_tinteg_tracer

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_tinteg_tracer_setup( &
       ATMOS_DYN_Tinteg_tracer_TYPE )

    use scale_precision
    use scale_grid_index
    use scale_index
    use scale_process, only: &
       prc_mpistop
    use scale_atmos_dyn_tinteg_tracer_euler, only: &
       atmos_dyn_tinteg_tracer_euler_setup, &
       atmos_dyn_tinteg_tracer_euler
    use scale_atmos_dyn_tinteg_tracer_rk3, only: &
       atmos_dyn_tinteg_tracer_rk3_setup, &
       atmos_dyn_tinteg_tracer_rk3
    implicit none
    character(len=*), intent(in)  :: ATMOS_DYN_Tinteg_tracer_TYPE
    !---------------------------------------------------------------------------

    select case ( atmos_dyn_tinteg_tracer_type )
    case ( 'EULER' )
       call atmos_dyn_tinteg_tracer_euler_setup( &
            atmos_dyn_tinteg_tracer_type )
       atmos_dyn_tinteg_tracer => atmos_dyn_tinteg_tracer_euler
    case ( 'RK3WS2002' )
       call atmos_dyn_tinteg_tracer_rk3_setup( &
            atmos_dyn_tinteg_tracer_type )
       atmos_dyn_tinteg_tracer => atmos_dyn_tinteg_tracer_rk3
    case ( 'OFF', 'NONE' )
       ! do nothing
    case default
       write(*,*) 'xxx ATMOS_DYN_TINTEG_TRACER_TYPE is invalid: ', atmos_dyn_tinteg_tracer_type
       call prc_mpistop
    end select

    return
  end subroutine atmos_dyn_tinteg_tracer_setup

end module scale_atmos_dyn_tinteg_tracer