mod_atmos_phy_tb_vars.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "inc_openmp.h"
module mod_atmos_phy_tb_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_tb_vars_setup
  public :: atmos_phy_tb_vars_fillhalo
  public :: atmos_phy_tb_vars_restart_read
  public :: atmos_phy_tb_vars_restart_write

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,               public :: atmos_phy_tb_restart_output       = .false.                

  character(len=H_LONG), public :: atmos_phy_tb_restart_in_basename  = ''
  character(len=H_LONG), public :: atmos_phy_tb_restart_out_basename = ''
  character(len=H_MID),  public :: atmos_phy_tb_restart_out_title    = 'ATMOS_PHY_TB restart'
  character(len=H_MID),  public :: atmos_phy_tb_restart_out_dtype    = 'DEFAULT'

  real(RP), public, allocatable :: atmos_phy_tb_momz_t(:,:,:)   ! tendency MOMZ [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_tb_momx_t(:,:,:)   ! tendency MOMX [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_tb_momy_t(:,:,:)   ! tendency MOMY [kg/m2/s2]
  real(RP), public, allocatable :: atmos_phy_tb_rhot_t(:,:,:)   ! tendency RHOT [K*kg/m3/s]
  real(RP), public, allocatable :: atmos_phy_tb_rhoq_t(:,:,:,:) ! tendency rho*QTRC [kg/kg/s]
  real(RP), public, allocatable :: atmos_phy_tb_tke_t(:,:,:)    ! tendency TKE @m2/s3]

  real(RP), public, allocatable :: atmos_phy_tb_tke(:,:,:) ! turburent kinetic energy [m2/s2]
  real(RP), public, allocatable :: atmos_phy_tb_nu (:,:,:) ! eddy viscosity           [m2/s]

  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,                private, parameter :: vmax = 2
  integer,                private, parameter :: i_tke = 1
  integer,                private, parameter :: i_nu  = 2

  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)

  data var_name / 'TKE', &
                  'NU'   /
  data var_desc / 'turburent kinetic energy', &
                  'eddy viscosity'            /
  data var_unit / 'm2/s2', &
                  'm2/s'   /

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_tb_vars_setup
    use scale_process, only: &
       prc_mpistop
    use scale_const, only: &
       undef => const_undef
    implicit none
    real(RP) :: ATMOS_PHY_TB_TKE_INIT = 1.0e-10_rp

    namelist / param_atmos_phy_tb_vars / &
       atmos_phy_tb_restart_in_basename,  &
       atmos_phy_tb_restart_output,       &
       atmos_phy_tb_restart_out_basename, &
       atmos_phy_tb_restart_out_title,    &
       atmos_phy_tb_restart_out_dtype,    &
       atmos_phy_tb_tke_init

    integer :: ierr
    integer :: iv
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[VARS] / Categ[ATMOS PHY_TB] / Origin[SCALE-RM]'

    allocate( atmos_phy_tb_momz_t(ka,ia,ja)    )
    allocate( atmos_phy_tb_momx_t(ka,ia,ja)    )
    allocate( atmos_phy_tb_momy_t(ka,ia,ja)    )
    allocate( atmos_phy_tb_rhot_t(ka,ia,ja)    )
    allocate( atmos_phy_tb_rhoq_t(ka,ia,ja,qa) )
    allocate( atmos_phy_tb_tke_t(ka,ia,ja)     )

    allocate( atmos_phy_tb_tke(ka,ia,ja) )
    allocate( atmos_phy_tb_nu(ka,ia,ja) )

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_tb_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       if( io_l ) write(io_fid_log,*) '*** Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       write(*,*) 'xxx Not appropriate names in namelist PARAM_ATMOS_PHY_TB_VARS. Check!'
       call prc_mpistop
    endif
    if( io_lnml ) write(io_fid_log,nml=param_atmos_phy_tb_vars)

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** [ATMOS_PHY_TB] prognostic/diagnostic variables'
    if( io_l ) write(io_fid_log,'(1x,A,A15,A,A32,3(A))') &
               '***       |','VARNAME        ','|', 'DESCRIPTION                     ','[', 'UNIT            ',']'
    do iv = 1, vmax
       if( io_l ) write(io_fid_log,'(1x,A,i3,A,A15,A,A32,3(A))') &
                  '*** NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
    enddo

    if( io_l ) write(io_fid_log,*)
    if ( atmos_phy_tb_restart_in_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** Restart input?  : ', trim(atmos_phy_tb_restart_in_basename)
    else
       if( io_l ) write(io_fid_log,*) '*** Restart input?  : NO'
    endif
    if (       atmos_phy_tb_restart_output             &
         .AND. atmos_phy_tb_restart_out_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** Restart output? : ', trim(atmos_phy_tb_restart_out_basename)
    else
       if( io_l ) write(io_fid_log,*) '*** Restart output? : NO'
       atmos_phy_tb_restart_output = .false.
    endif

    atmos_phy_tb_momz_t(:,:,:)   = undef
    atmos_phy_tb_momx_t(:,:,:)   = undef
    atmos_phy_tb_momy_t(:,:,:)   = undef
    atmos_phy_tb_rhot_t(:,:,:)   = undef
    atmos_phy_tb_rhoq_t(:,:,:,:) = undef
    atmos_phy_tb_tke_t(:,:,:)   = undef

    atmos_phy_tb_tke(:,:,:) = atmos_phy_tb_tke_init
    atmos_phy_tb_nu(:,:,:) = undef

    return
  end subroutine atmos_phy_tb_vars_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_tb_vars_fillhalo
    use scale_comm, only: &
       comm_vars8, &
       comm_wait
    implicit none

    integer :: i, j
    !---------------------------------------------------------------------------

    do j  = js, je
    do i  = is, ie
       atmos_phy_tb_tke(   1:ks-1,i,j) = atmos_phy_tb_tke(ks,i,j)
       atmos_phy_tb_nu(   1:ks-1,i,j) = atmos_phy_tb_nu(ks,i,j)
       atmos_phy_tb_tke(ke+1:ka,  i,j) = atmos_phy_tb_tke(ke,i,j)
       atmos_phy_tb_nu(ke+1:ka,  i,j) = atmos_phy_tb_nu(ke,i,j)
    enddo
    enddo

    call comm_vars8( atmos_phy_tb_tke(:,:,:), 1 )
    call comm_vars8( atmos_phy_tb_nu(:,:,:), 2 )
    call comm_wait ( atmos_phy_tb_tke(:,:,:), 1 )
    call comm_wait ( atmos_phy_tb_nu(:,:,:), 2 )

    return
  end subroutine atmos_phy_tb_vars_fillhalo

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_tb_vars_restart_read
    use scale_fileio, only: &
       fileio_read
    use scale_rm_statistics, only: &
       stat_total
    implicit none

    real(RP) :: total
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '*** Input restart file (ATMOS_PHY_TB) ***'

    if ( atmos_phy_tb_restart_in_basename /= '' ) then
       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(atmos_phy_tb_restart_in_basename)

       call fileio_read( atmos_phy_tb_tke(:,:,:),                                     & ! [OUT]
                         atmos_phy_tb_restart_in_basename, var_name(1), 'ZXY', step=1 ) ! [IN]
!       call FILEIO_read( ATMOS_PHY_TB_NU (:,:,:),                                     & ! [OUT]
!                         ATMOS_PHY_TB_RESTART_IN_BASENAME, VAR_NAME(2), 'ZXY', step=1 ) ! [IN]
!
!       call ATMOS_PHY_TB_vars_fillhalo
!
       call stat_total( total, atmos_phy_tb_tke(:,:,:), var_name(1) )
!       call STAT_total( total, ATMOS_PHY_TB_NU (:,:,:), VAR_NAME(2) )
    else
       if( io_l ) write(io_fid_log,*) '*** restart file for ATMOS_PHY_TB is not specified.'
    endif

    return
  end subroutine atmos_phy_tb_vars_restart_read

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_tb_vars_restart_write
    use scale_time, only: &
       time_gettimelabel
    use scale_fileio, only: &
       fileio_write
    implicit none

    character(len=20)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------

    if ( atmos_phy_tb_restart_out_basename /= '' ) then

       call time_gettimelabel( timelabel )
       write(basename,'(A,A,A)') trim(atmos_phy_tb_restart_out_basename), '_', trim(timelabel)

       if( io_l ) write(io_fid_log,*)
       if( io_l ) write(io_fid_log,*) '*** Output restart file (ATMOS_PHY_TB) ***'
       if( io_l ) write(io_fid_log,*) '*** basename: ', trim(basename)

       call fileio_write( atmos_phy_tb_tke(:,:,:), basename,            atmos_phy_tb_restart_out_title, & ! [IN]
                          var_name(1), var_desc(1), var_unit(1), 'ZXY', atmos_phy_tb_restart_out_dtype  ) ! [IN]
!       call FILEIO_write( ATMOS_PHY_TB_NU (:,:,:), basename,            ATMOS_PHY_TB_RESTART_OUT_TITLE, & ! [IN]
!                          VAR_NAME(2), VAR_DESC(2), VAR_UNIT(2), 'ZXY', ATMOS_PHY_TB_RESTART_OUT_DTYPE  ) ! [IN]

    endif

    return
  end subroutine atmos_phy_tb_vars_restart_write

end module mod_atmos_phy_tb_vars