scale_atmos_dyn_tstep_short.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "inc_openmp.h"
module scale_atmos_dyn_tstep_short
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_dyn_tstep_short_regist

  abstract interface

     subroutine short_setup
     end subroutine short_setup

     subroutine short( DENS_new, MOMZ_new, MOMX_new, MOMY_new, RHOT_new, & ! (out)
                       prog_new,                                         & ! (out)
                       mflx_hi,  tflx_hi,                                & ! (out)
                       dens0,    momz0,    momx0,    momy0,    rhot0,    & ! (in)
                       dens,     momz,     momx,     momy,     rhot,     & ! (in)
                       dens_t,   momz_t,   momx_t,   momy_t,   rhot_t,   & ! (in)
                       prog0, prog,                                      & ! (in)
                       dpres0, rt2p, corioli,                            & ! (in)
                       num_diff, divdmp_coef, ddiv,                      & ! (in)
                       flag_fct_momentum, flag_fct_t,                    & ! (in)
                       flag_fct_along_stream,                            & ! (in)
                       cdz, fdz, fdx, fdy,                               & ! (in)
                       rcdz, rcdx, rcdy, rfdz, rfdx, rfdy,               & ! (in)
                       phi, gsqrt, j13g, j23g, j33g, mapf,               & ! (in)
                       ref_dens, ref_rhot,                               & ! (in)
                       bnd_w, bnd_e, bnd_s, bnd_n,                       & ! (in)
                       dtrk, dt                                          ) ! (in)
       use scale_precision
       use scale_grid_index
       use scale_index
       real(RP), intent(out) :: dens_new(ka,ia,ja)   ! prognostic variables
       real(RP), intent(out) :: momz_new(ka,ia,ja)   !
       real(RP), intent(out) :: momx_new(ka,ia,ja)   !
       real(RP), intent(out) :: momy_new(ka,ia,ja)   !
       real(RP), intent(out) :: rhot_new(ka,ia,ja)   !
       real(RP), intent(out) :: prog_new(ka,ia,ja,va)  !

       real(RP), intent(inout) :: mflx_hi(ka,ia,ja,3) ! mass flux
       real(RP), intent(out)   :: tflx_hi(ka,ia,ja,3) ! internal energy flux

       real(RP), intent(in),target :: dens0(ka,ia,ja) ! prognostic variables at previous dynamical time step
       real(RP), intent(in),target :: momz0(ka,ia,ja) !
       real(RP), intent(in),target :: momx0(ka,ia,ja) !
       real(RP), intent(in),target :: momy0(ka,ia,ja) !
       real(RP), intent(in),target :: rhot0(ka,ia,ja) !

       real(RP), intent(in)  :: dens(ka,ia,ja)      ! prognostic variables at previous RK step
       real(RP), intent(in)  :: momz(ka,ia,ja)      !
       real(RP), intent(in)  :: momx(ka,ia,ja)      !
       real(RP), intent(in)  :: momy(ka,ia,ja)      !
       real(RP), intent(in)  :: rhot(ka,ia,ja)      !

       real(RP), intent(in)  :: dens_t(ka,ia,ja)    ! tendency
       real(RP), intent(in)  :: momz_t(ka,ia,ja)    !
       real(RP), intent(in)  :: momx_t(ka,ia,ja)    !
       real(RP), intent(in)  :: momy_t(ka,ia,ja)    !
       real(RP), intent(in)  :: rhot_t(ka,ia,ja)    !

       real(RP), intent(in)  :: prog0(ka,ia,ja,va)
       real(RP), intent(in)  :: prog (ka,ia,ja,va)

       real(RP), intent(in)  :: dpres0  (ka,ia,ja)
       real(RP), intent(in)  :: rt2p    (ka,ia,ja)
       real(RP), intent(in)  :: corioli (1, ia,ja)
       real(RP), intent(in)  :: num_diff(ka,ia,ja,5,3)
       real(RP), intent(in)  :: divdmp_coef
       real(RP), intent(in)  :: ddiv(ka,ia,ja)

       logical,  intent(in)  :: flag_fct_momentum
       logical,  intent(in)  :: flag_fct_t
       logical,  intent(in)  :: flag_fct_along_stream

       real(RP), intent(in)  :: cdz (ka)
       real(RP), intent(in)  :: fdz (ka-1)
       real(RP), intent(in)  :: fdx (ia-1)
       real(RP), intent(in)  :: fdy (ja-1)
       real(RP), intent(in)  :: rcdz(ka)
       real(RP), intent(in)  :: rcdx(ia)
       real(RP), intent(in)  :: rcdy(ja)
       real(RP), intent(in)  :: rfdz(ka-1)
       real(RP), intent(in)  :: rfdx(ia-1)
       real(RP), intent(in)  :: rfdy(ja-1)

       real(RP), intent(in)  :: phi     (ka,ia,ja)
       real(RP), intent(in)  :: gsqrt   (ka,ia,ja,7)
       real(RP), intent(in)  :: j13g    (ka,ia,ja,7)
       real(RP), intent(in)  :: j23g    (ka,ia,ja,7)
       real(RP), intent(in)  :: j33g
       real(RP), intent(in)  :: mapf    (ia,ja,2,4)
       real(RP), intent(in)  :: ref_dens(ka,ia,ja)
       real(RP), intent(in)  :: ref_rhot(ka,ia,ja)

       logical,  intent(in)  :: bnd_w
       logical,  intent(in)  :: bnd_e
       logical,  intent(in)  :: bnd_s
       logical,  intent(in)  :: bnd_n

       real(RP), intent(in)  :: dtrk
       real(RP), intent(in)  :: dt
     end subroutine short

  end interface

  procedure(short_setup), pointer :: atmos_dyn_tstep_short_setup => null()
  public :: atmos_dyn_tstep_short_setup
  procedure(short), pointer :: atmos_dyn_tstep_short => null()
  public :: atmos_dyn_tstep_short

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_tstep_short_regist( &
       ATMOS_DYN_TYPE, &
       VA_out, &
       VAR_NAME, VAR_DESC, VAR_UNIT )
    use scale_precision
    use scale_grid_index
    use scale_index
    use scale_process, only: &
       prc_mpistop
#define EXTM(pre, name, post) pre ## name ## post
#define NAME(pre, name, post) EXTM(pre, name, post)
#ifdef DYNAMICS
    use name(scale_atmos_dyn_tstep_, dynamics,), only: &
       name(atmos_dyn_rk_tstep_short_, dynamics, _regist), &
       name(atmos_dyn_rk_tstep_short_, dynamics, _setup), &
       name(atmos_dyn_rk_tstep_short_, dynamics,)
#else
    use scale_atmos_dyn_tstep_short_fvm_heve, only: &
       atmos_dyn_tstep_short_fvm_heve_regist, &
       atmos_dyn_tstep_short_fvm_heve_setup, &
       atmos_dyn_tstep_short_fvm_heve
    use scale_atmos_dyn_tstep_short_fvm_hevi, only: &
       atmos_dyn_tstep_short_fvm_hevi_regist, &
       atmos_dyn_tstep_short_fvm_hevi_setup, &
       atmos_dyn_tstep_short_fvm_hevi
    use scale_atmos_dyn_tstep_short_fvm_hivi, only: &
       atmos_dyn_tstep_short_fvm_hivi_regist, &
       atmos_dyn_tstep_short_fvm_hivi_setup, &
       atmos_dyn_tstep_short_fvm_hivi
#endif
    implicit none

    character(len=*),       intent(in)  :: ATMOS_DYN_TYPE
    integer,                intent(out) :: VA_out
    character(len=H_SHORT), intent(out) :: VAR_NAME(:)
    character(len=H_MID),   intent(out) :: VAR_DESC(:)
    character(len=H_SHORT), intent(out) :: VAR_UNIT(:)
    !---------------------------------------------------------------------------

#ifdef DYNAMICS
    name(atmos_dyn_tstep_, dynamics, _regist)( &
            atmos_dyn_type )
    atmos_dyn_tstep_short_ => name(atmos_dyn_tstep_short_, dynamics,)
    atmos_dyn_tstep_short_setup => name(atmos_dyn_tstep_short_, dynamics, _setup)
#else
    select case ( atmos_dyn_type )
    case ( 'FVM-HEVE', 'HEVE' )

       call atmos_dyn_tstep_short_fvm_heve_regist( atmos_dyn_type,              & ! [IN]
                                                   va_out,                      & ! [OUT]
                                                   var_name, var_desc, var_unit ) ! [OUT]

       atmos_dyn_tstep_short_setup => atmos_dyn_tstep_short_fvm_heve_setup
       atmos_dyn_tstep_short       => atmos_dyn_tstep_short_fvm_heve

    case ( 'FVM-HEVI', 'HEVI' )

       call atmos_dyn_tstep_short_fvm_hevi_regist( atmos_dyn_type,              & ! [IN]
                                                   va_out,                      & ! [OUT]
                                                   var_name, var_desc, var_unit ) ! [OUT]

       atmos_dyn_tstep_short_setup => atmos_dyn_tstep_short_fvm_hevi_setup
       atmos_dyn_tstep_short       => atmos_dyn_tstep_short_fvm_hevi

    case ( 'FVM-HIVI', 'HIVI' )

       if( io_l ) write(io_fid_log,*) 'xxx HIVI is temtatively disabled'
       call prc_mpistop

       call atmos_dyn_tstep_short_fvm_hivi_regist( atmos_dyn_type,              & ! [IN]
                                                   va_out,                      & ! [OUT]
                                                   var_name, var_desc, var_unit ) ! [OUT]

       atmos_dyn_tstep_short_setup => atmos_dyn_tstep_short_fvm_hivi_setup
       atmos_dyn_tstep_short       => atmos_dyn_tstep_short_fvm_hivi

    case ( 'OFF', 'NONE' )

       va_out      = 0
       var_name(:) = ""
       var_desc(:) = ""
       var_unit(:) = ""

    case default
       write(*,*) 'xxx ATMOS_DYN_TYPE is invalid: ', atmos_dyn_type
       call prc_mpistop
    end select
#endif

    return
  end subroutine atmos_dyn_tstep_short_regist

end module scale_atmos_dyn_tstep_short