scale_atmos_phy_tb_hybrid Module Reference

module ATMOSPHERE / Physics Turbulence More...

Functions/Subroutines
subroutine, public	atmos_phy_tb_hybrid_setup (TB_TYPE, CDZ, CDX, CDY, CZ)
subroutine, public	atmos_phy_tb_hybrid (qflx_sgs_momz, qflx_sgs_momx, qflx_sgs_momy, qflx_sgs_rhot, qflx_sgs_rhoq, tke, tke_t, Nu, Ri, Pr, N2, MOMZ, MOMX, MOMY, RHOT, DENS, QTRC, SFLX_MW, SFLX_MU, SFLX_MV, SFLX_SH, SFLX_QV, GSQRT, J13G, J23G, J33G, MAPF, dt)

Variables
procedure(tb), pointer	sgs_tb => NULL()

Detailed Description

module ATMOSPHERE / Physics Turbulence

Description

Boundary layer turbulence model

Author

Team SCALE

History

• 2014-09-18 (S.Nishizawa) [new]

NAMELIST

• PARAM_ATMOS_PHY_TB_HYBRID

  name	type	default value	comment
  ATMOS_PHY_TB_HYBRID_SGS_DX	real(RP)	100.0_RP	horizontal resolution for SGS model
  ATMOS_PHY_TB_HYBRID_PBL_DX	real(RP)	500.0_RP	horizontal resolution for PBL model
  ATMOS_PHY_TB_HYBRID_SGS_TYPE	character(len=H_SHORT)	'SMAGORINSKY'	scheme type for SGS
  ATMOS_PHY_TB_HYBRID_PBL_TYPE	character(len=H_SHORT)	'MYNN'	scheme type for turbulent parametarization
  ATMOS_PHY_TB_HYBRID_TKE_TYPE	character(len=H_SHORT)	'PBL'	SGS, PBL, or MIXED

  
  

History Output

No history output

Function/Subroutine Documentation

atmos_phy_tb_hybrid_setup()

subroutine, public scale_atmos_phy_tb_hybrid::atmos_phy_tb_hybrid_setup	(	character(len=*), intent(in)	TB_TYPE,
		real(rp), dimension(ka), intent(in)	CDZ,
		real(rp), dimension(ia), intent(in)	CDX,
		real(rp), dimension(ja), intent(in)	CDY,
		real(rp), dimension (ka,ia,ja), intent(in)	CZ
	)

Definition at line 115 of file scale_atmos_phy_tb_hybrid.F90.

References scale_atmos_phy_tb_mynn::atmos_phy_tb_mynn(), scale_atmos_phy_tb_mynn::atmos_phy_tb_mynn_setup(), scale_atmos_phy_tb_smg::atmos_phy_tb_smg(), scale_atmos_phy_tb_smg::atmos_phy_tb_smg_setup(), scale_grid_index::ia, scale_stdio::io_fid_conf, scale_stdio::io_fid_log, scale_stdio::io_l, scale_stdio::io_lnml, scale_grid_index::ja, scale_process::prc_mpistop(), and sgs_tb.

Referenced by scale_atmos_phy_tb::atmos_phy_tb_setup().

    use scale_process, only: &
       prc_mpistop
    use scale_atmos_phy_tb_smg, only: &
       atmos_phy_tb_smg_setup, &
       atmos_phy_tb_smg
    use scale_atmos_phy_tb_mynn, only: &
       atmos_phy_tb_mynn_setup, &
       atmos_phy_tb_mynn
    implicit none

    character(len=*), intent(in) :: tb_type

    real(RP), intent(in) :: cdz(ka)
    real(RP), intent(in) :: cdx(ia)
    real(RP), intent(in) :: cdy(ja)
    real(RP), intent(in) :: cz (ka,ia,ja)

    real(RP) :: atmos_phy_tb_hybrid_sgs_dx = 100.0_rp                      
    real(RP) :: atmos_phy_tb_hybrid_pbl_dx = 500.0_rp                      
    character(len=H_SHORT) :: atmos_phy_tb_hybrid_sgs_type = 'SMAGORINSKY'
    character(len=H_SHORT) :: atmos_phy_tb_hybrid_pbl_type = 'MYNN'

    character(len=H_SHORT) :: atmos_phy_tb_hybrid_tke_type = 'PBL'

    namelist / param_atmos_phy_tb_hybrid / &
         atmos_phy_tb_hybrid_sgs_dx, &
         atmos_phy_tb_hybrid_pbl_dx, &
         atmos_phy_tb_hybrid_sgs_type, &
         atmos_phy_tb_hybrid_pbl_type, &
         atmos_phy_tb_hybrid_tke_type


    real(RP) :: dxy

    integer :: i, j
    integer :: ierr
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[TURBULENCE] / Categ[ATMOS PHYSICS] / Origin[SCALElib]'
    if( io_l ) write(io_fid_log,*) '+++ SGS-parameterization hybrid Model'

    if ( tb_type /= 'HYBRID' ) then
       write(*,*) 'xxx ATMOS_PHY_TB_TYPE is not HYBRID. Check!'
       call prc_mpistop
    endif


    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_tb_hybrid,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       if( io_l ) write(io_fid_log,*) '*** Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       write(*,*) 'xxx Not appropriate names in namelist PARAM_ATMOS_PHY_TB_HYBRID. Check!'
       call prc_mpistop
    endif
    if( io_lnml ) write(io_fid_log,nml=param_atmos_phy_tb_hybrid)

    select case ( atmos_phy_tb_hybrid_sgs_type )
    case ('SMAGORINSKY')
       call atmos_phy_tb_smg_setup( &
            atmos_phy_tb_hybrid_sgs_type, &
            cdz, cdx, cdy, &
            cz             )
       sgs_tb => atmos_phy_tb_smg
    case default
       write(*,*) 'xxx ATMOS_PHY_TB_HYBRID_SGS_TYPE is invalid'
       call prc_mpistop
    end select

    select case ( atmos_phy_tb_hybrid_pbl_type )
    case ('MYNN')
       call atmos_phy_tb_mynn_setup( &
            atmos_phy_tb_hybrid_pbl_type, &
            cdz, cdx, cdy, &
            cz             )
       pbl_tb => atmos_phy_tb_mynn
    case default
       write(*,*) 'xxx ATMOS_PHY_TB_HYBRID_PBL_TYPE is invalid'
       call prc_mpistop
    end select

    allocate( frac_sgs(ia,ja) )
    allocate( frac_pbl(ia,ja) )
    allocate( frac_sgs_tke(ia,ja) )
    allocate( frac_pbl_tke(ia,ja) )

    do j = 1, ja
    do i = 1, ia
       dxy = sqrt( ( cdx(i)**2 + cdy(j)**2 )*0.5_rp )
       frac_pbl(i,j) = &
               min( 1.0_rp, &
               max( 0.0_rp, &
                    ( dxy - atmos_phy_tb_hybrid_sgs_dx ) &
                  / ( atmos_phy_tb_hybrid_pbl_dx - atmos_phy_tb_hybrid_sgs_dx ) ) )
       frac_sgs(i,j) = 1.0_rp - frac_pbl(i,j)
    end do
    end do

    select case ( atmos_phy_tb_hybrid_tke_type )
    case ('SGS')
       frac_pbl_tke(:,:) = 0.0_rp
       frac_sgs_tke(:,:) = 1.0_rp
    case ('PBL')
       frac_pbl_tke(:,:) = 1.0_rp
       frac_sgs_tke(:,:) = 0.0_rp
    case ('MIXED')
       frac_pbl_tke(:,:) = frac_pbl(:,:)
       frac_sgs_tke(:,:) = frac_sgs(:,:)
    case default
       write(*,*) 'xxx ATMOS_PHY_TB_HYBRID_TKE_TYPE is invalid'
       call prc_mpistop
    end select

    return

Here is the call graph for this function:

Here is the caller graph for this function:

atmos_phy_tb_hybrid()

subroutine, public scale_atmos_phy_tb_hybrid::atmos_phy_tb_hybrid	(	real(rp), dimension(ka,ia,ja,3), intent(out)	qflx_sgs_momz,
		real(rp), dimension(ka,ia,ja,3), intent(out)	qflx_sgs_momx,
		real(rp), dimension(ka,ia,ja,3), intent(out)	qflx_sgs_momy,
		real(rp), dimension(ka,ia,ja,3), intent(out)	qflx_sgs_rhot,
		real(rp), dimension(ka,ia,ja,3,qa), intent(out)	qflx_sgs_rhoq,
		real(rp), dimension (ka,ia,ja), intent(inout)	tke,
		real(rp), dimension(ka,ia,ja), intent(out)	tke_t,
		real(rp), dimension(ka,ia,ja), intent(out)	Nu,
		real(rp), dimension(ka,ia,ja), intent(out)	Ri,
		real(rp), dimension(ka,ia,ja), intent(out)	Pr,
		real(rp), dimension(ka,ia,ja), intent(out)	N2,
		real(rp), dimension(ka,ia,ja), intent(in)	MOMZ,
		real(rp), dimension(ka,ia,ja), intent(in)	MOMX,
		real(rp), dimension(ka,ia,ja), intent(in)	MOMY,
		real(rp), dimension(ka,ia,ja), intent(in)	RHOT,
		real(rp), dimension(ka,ia,ja), intent(in)	DENS,
		real(rp), dimension(ka,ia,ja,qa), intent(in)	QTRC,
		real(rp), dimension(ia,ja), intent(in)	SFLX_MW,
		real(rp), dimension(ia,ja), intent(in)	SFLX_MU,
		real(rp), dimension(ia,ja), intent(in)	SFLX_MV,
		real(rp), dimension(ia,ja), intent(in)	SFLX_SH,
		real(rp), dimension(ia,ja), intent(in)	SFLX_QV,
		real(rp), dimension (ka,ia,ja,7), intent(in)	GSQRT,
		real(rp), dimension (ka,ia,ja,7), intent(in)	J13G,
		real(rp), dimension (ka,ia,ja,7), intent(in)	J23G,
		real(rp), intent(in)	J33G,
		real(rp), dimension (ia,ja,2,4), intent(in)	MAPF,
		real(dp), intent(in)	dt
	)

Parameters

[in]	gsqrt	vertical metrics {G}^1/2
[in]	j13g	(1,3) element of Jacobian matrix
[in]	j23g	(1,3) element of Jacobian matrix
[in]	j33g	(3,3) element of Jacobian matrix
[in]	mapf	map factor

Definition at line 242 of file scale_atmos_phy_tb_hybrid.F90.

References scale_const::const_grav, scale_grid_index::ia, scale_grid_index::ja, scale_grid_index::ke, scale_grid_index::ks, scale_tracer::qa, sgs_tb, scale_grid_index::xdir, scale_grid_index::ydir, and scale_grid_index::zdir.

Referenced by scale_atmos_phy_tb::atmos_phy_tb_setup().

    use scale_precision
    use scale_grid_index
    use scale_tracer
    use scale_const, only: &
       grav => const_grav
    implicit none

    real(RP), intent(out) :: qflx_sgs_momz(ka,ia,ja,3)
    real(RP), intent(out) :: qflx_sgs_momx(ka,ia,ja,3)
    real(RP), intent(out) :: qflx_sgs_momy(ka,ia,ja,3)
    real(RP), intent(out) :: qflx_sgs_rhot(ka,ia,ja,3)
    real(RP), intent(out) :: qflx_sgs_rhoq(ka,ia,ja,3,qa)

    real(RP), intent(inout) :: tke (ka,ia,ja) ! TKE
    real(RP), intent(out) :: tke_t(ka,ia,ja) ! tendency TKE
    real(RP), intent(out) :: nu(ka,ia,ja) ! eddy viscosity (center)
    real(RP), intent(out) :: pr(ka,ia,ja) ! Plandtle number
    real(RP), intent(out) :: ri(ka,ia,ja) ! Richardson number
    real(RP), intent(out) :: n2(ka,ia,ja) ! squared Brunt-Vaisala frequency

    real(RP), intent(in)  :: momz(ka,ia,ja)
    real(RP), intent(in)  :: momx(ka,ia,ja)
    real(RP), intent(in)  :: momy(ka,ia,ja)
    real(RP), intent(in)  :: rhot(ka,ia,ja)
    real(RP), intent(in)  :: dens(ka,ia,ja)
    real(RP), intent(in)  :: qtrc(ka,ia,ja,qa)

    real(RP), intent(in)  :: sflx_mw(ia,ja)
    real(RP), intent(in)  :: sflx_mu(ia,ja)
    real(RP), intent(in)  :: sflx_mv(ia,ja)
    real(RP), intent(in)  :: sflx_sh(ia,ja)
    real(RP), intent(in)  :: sflx_qv(ia,ja)

    real(RP), intent(in)  :: gsqrt   (ka,ia,ja,7)
    real(RP), intent(in)  :: j13g    (ka,ia,ja,7)
    real(RP), intent(in)  :: j23g    (ka,ia,ja,7)
    real(RP), intent(in)  :: j33g
    real(RP), intent(in)  :: mapf    (ia,ja,2,4)
    real(DP), intent(in)  :: dt

    real(RP) :: w_qflx_sgs_momz(ka,ia,ja,3,2)
    real(RP) :: w_qflx_sgs_momx(ka,ia,ja,3,2)
    real(RP) :: w_qflx_sgs_momy(ka,ia,ja,3,2)
    real(RP) :: w_qflx_sgs_rhot(ka,ia,ja,3,2)
    real(RP) :: w_qflx_sgs_rhoq(ka,ia,ja,3,qa,2)

    real(RP) :: w_tke(ka,ia,ja,2)
    real(RP) :: w_tke_t(ka,ia,ja,2)
    real(RP) :: w_nu(ka,ia,ja,2)
    real(RP) :: w_ri(ka,ia,ja,2)
    real(RP) :: w_pr(ka,ia,ja,2)
    real(RP) :: w_n2(ka,ia,ja,2)

    integer :: k, i, j, iq

    do j = 1, ja
    do i = 1, ia
    do k = ks, ke
       w_tke(k,i,j,1) = tke(k,i,j)
       w_tke(k,i,j,2) = tke(k,i,j)
    end do
    end do
    end do

    call sgs_tb( &
         w_qflx_sgs_momz(:,:,:,:,1), w_qflx_sgs_momx(:,:,:,:,1), & ! (out)
         w_qflx_sgs_momy(:,:,:,:,1), w_qflx_sgs_rhot(:,:,:,:,1), & ! (out
         w_qflx_sgs_rhoq(:,:,:,:,:,1),                           & ! (out)
         w_tke(:,:,:,1),                                         & ! (inout)
         w_tke_t(:,:,:,1),                                       & ! (out)
         w_nu(:,:,:,1), w_ri(:,:,:,1), w_pr(:,:,:,1), w_n2(:,:,:,1), & ! (out)
         momz, momx, momy, rhot, dens, qtrc,                     & ! (in)
         sflx_mw, sflx_mu, sflx_mv, sflx_sh, sflx_qv,            & ! (in)
         gsqrt, j13g, j23g, j33g, mapf, dt                       ) ! (in)

    call pbl_tb( &
         w_qflx_sgs_momz(:,:,:,:,2), w_qflx_sgs_momx(:,:,:,:,2), & ! (out)
         w_qflx_sgs_momy(:,:,:,:,2), w_qflx_sgs_rhot(:,:,:,:,2), & ! (out
         w_qflx_sgs_rhoq(:,:,:,:,:,2),                           & ! (out)
         w_tke(:,:,:,2),                                         & ! (inout)
         w_tke_t(:,:,:,2),                                       & ! (out)
         w_nu(:,:,:,2), w_ri(:,:,:,2), w_pr(:,:,:,2), w_n2(:,:,:,2), & ! (out)
         momz, momx, momy, rhot, dens, qtrc,                     & ! (in)
         sflx_mw, sflx_mu, sflx_mv, sflx_sh, sflx_qv,            & ! (in)
         gsqrt, j13g, j23g, j33g, mapf, dt                       ) ! (in)

    do j = 1, ja
    do i = 1, ia
    do k = ks, ke
       qflx_sgs_momz(k,i,j,zdir) = w_qflx_sgs_momz(k,i,j,zdir,1) * frac_sgs(i,j) &
                                 + w_qflx_sgs_momz(k,i,j,zdir,2) * frac_pbl(i,j)
       qflx_sgs_momz(k,i,j,xdir) = w_qflx_sgs_momz(k,i,j,xdir,1)
       qflx_sgs_momz(k,i,j,ydir) = w_qflx_sgs_momz(k,i,j,ydir,1)
    end do
    end do
    end do

    do j = 1, ja
    do i = 1, ia
    do k = ks, ke
       qflx_sgs_momx(k,i,j,zdir) = w_qflx_sgs_momx(k,i,j,zdir,1) * frac_sgs(i,j) &
                                 + w_qflx_sgs_momx(k,i,j,zdir,2) * frac_pbl(i,j)
       qflx_sgs_momx(k,i,j,xdir) = w_qflx_sgs_momx(k,i,j,xdir,1)
       qflx_sgs_momx(k,i,j,ydir) = w_qflx_sgs_momx(k,i,j,ydir,1)
    end do
    end do
    end do

    do j = 1, ja
    do i = 1, ia
    do k = ks, ke
       qflx_sgs_momy(k,i,j,zdir) = w_qflx_sgs_momy(k,i,j,zdir,1) * frac_sgs(i,j) &
                                 + w_qflx_sgs_momy(k,i,j,zdir,2) * frac_pbl(i,j)
       qflx_sgs_momy(k,i,j,xdir) = w_qflx_sgs_momy(k,i,j,xdir,1)
       qflx_sgs_momy(k,i,j,ydir) = w_qflx_sgs_momy(k,i,j,ydir,1)
    end do
    end do
    end do

    do j = 1, ja
    do i = 1, ia
    do k = ks, ke
       qflx_sgs_rhot(k,i,j,zdir) = w_qflx_sgs_rhot(k,i,j,zdir,1) * frac_sgs(i,j) &
                                 + w_qflx_sgs_rhot(k,i,j,zdir,2) * frac_pbl(i,j)
       qflx_sgs_rhot(k,i,j,xdir) = w_qflx_sgs_rhot(k,i,j,xdir,1)
       qflx_sgs_rhot(k,i,j,ydir) = w_qflx_sgs_rhot(k,i,j,ydir,1)
    end do
    end do
    end do

    do iq = 1, qa
    do j = 1, ja
    do i = 1, ia
    do k = ks, ke
       qflx_sgs_rhoq(k,i,j,zdir,iq) = w_qflx_sgs_rhoq(k,i,j,zdir,iq,1) * frac_sgs(i,j) &
                                    + w_qflx_sgs_rhoq(k,i,j,zdir,iq,2) * frac_pbl(i,j)
       qflx_sgs_rhoq(k,i,j,xdir,iq) = w_qflx_sgs_rhoq(k,i,j,xdir,iq,1)
       qflx_sgs_rhoq(k,i,j,ydir,iq) = w_qflx_sgs_rhoq(k,i,j,ydir,iq,1)
    end do
    end do
    end do
    end do

    do j = 1, ja
    do i = 1, ia
    do k = ks, ke
       tke(k,i,j) = w_tke(k,i,j,1) * frac_sgs_tke(i,j) &
                  + w_tke(k,i,j,2) * frac_pbl_tke(i,j)
    end do
    end do
    end do

    do j = 1, ja
    do i = 1, ia
    do k = ks, ke
       tke_t(k,i,j) = w_tke_t(k,i,j,1) * frac_sgs_tke(i,j) &
                    + w_tke_t(k,i,j,2) * frac_pbl_tke(i,j)
    end do
    end do
    end do

    do j = 1, ja
    do i = 1, ia
    do k = ks, ke
       nu(k,i,j) = w_nu(k,i,j,1) * frac_sgs(i,j) &
                 + w_nu(k,i,j,2) * frac_pbl(i,j)
    end do
    end do
    end do

    do j = 1, ja
    do i = 1, ia
    do k = ks, ke
       ri(k,i,j) = w_ri(k,i,j,1) * frac_sgs(i,j) &
                 + w_ri(k,i,j,2) * frac_pbl(i,j)
    end do
    end do
    end do

    do j = 1, ja
    do i = 1, ia
    do k = ks, ke
       pr(k,i,j) = w_pr(k,i,j,1) * frac_sgs(i,j) &
                 + w_pr(k,i,j,2) * frac_pbl(i,j)
    end do
    end do
    end do

    do j = 1, ja
    do i = 1, ia
    do k = ks, ke
       n2(k,i,j) = w_n2(k,i,j,1) * frac_sgs(i,j) &
                 + w_n2(k,i,j,2) * frac_pbl(i,j)
    end do
    end do
    end do

    return

Here is the caller graph for this function:

Variable Documentation

sgs_tb

procedure(tb), pointer scale_atmos_phy_tb_hybrid::sgs_tb => NULL()

Definition at line 102 of file scale_atmos_phy_tb_hybrid.F90.

Referenced by atmos_phy_tb_hybrid(), and atmos_phy_tb_hybrid_setup().

  procedure(tb), pointer :: sgs_tb => null()