scale_atmos_phy_ae_offline.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_atmos_phy_ae_offline
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_atmos_aerosol, only: &
      n_ae,  &
      i_a01, &
      i_a02, &
      i_a03, &
      i_a04, &
      i_a05, &
      i_a06, &
      i_a07
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_ae_offline_setup
  public :: atmos_phy_ae_offline_tendency
  public :: atmos_phy_ae_offline_effective_radius
  public :: atmos_phy_ae_offline_qtrc2qaero
  public :: atmos_phy_ae_offline_mkinit
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,  private, parameter :: num_vars_3d = 8
 
  character(len=H_SHORT) :: vars_3d(num_vars_3d)
 
  data vars_3d / 'OUTQLD01', 'OUTQLD02', 'OUTQLD03', 'OUTQLD04', 'OUTQLD05', 'OUTQLD06', 'OUTQLD07', 'UNCCN' /
 
  real(RP), private :: const_value(num_vars_3d)
 
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_offline_setup
    use scale_prc, only: &
       prc_abort
    use scale_file_external_input, only: &
       file_external_input_regist
    use scale_const, only: &
       undef => const_undef
    implicit none
 
    character(len=H_LONG)  :: atmos_phy_ae_offline_basename              = ''
    logical                :: atmos_phy_ae_offline_basename_add_num      = .false.
    integer                :: atmos_phy_ae_offline_number_of_files       = 1
    character(len=H_SHORT) :: atmos_phy_ae_offline_axistype              = 'XYZ'
    logical                :: atmos_phy_ae_offline_enable_periodic_year  = .false.
    logical                :: atmos_phy_ae_offline_enable_periodic_month = .false.
    logical                :: atmos_phy_ae_offline_enable_periodic_day   = .false.
    integer                :: atmos_phy_ae_offline_step_fixed            = 0
    real(rp)               :: atmos_phy_ae_offline_defval               ! = UNDEF
    logical                :: atmos_phy_ae_offline_check_coordinates     = .true.
    integer                :: atmos_phy_ae_offline_step_limit            = 0
 
    real(rp)               :: atmos_phy_ae_offline_const_outqld01
    real(rp)               :: atmos_phy_ae_offline_const_outqld02
    real(rp)               :: atmos_phy_ae_offline_const_outqld03
    real(rp)               :: atmos_phy_ae_offline_const_outqld04
    real(rp)               :: atmos_phy_ae_offline_const_outqld05
    real(rp)               :: atmos_phy_ae_offline_const_outqld06
    real(rp)               :: atmos_phy_ae_offline_const_outqld07
    real(rp)               :: atmos_phy_ae_offline_const_unccn
 
    namelist / param_atmos_phy_ae_offline / &
       atmos_phy_ae_offline_basename,              &
       atmos_phy_ae_offline_basename_add_num,      &
       atmos_phy_ae_offline_number_of_files,       &
       atmos_phy_ae_offline_axistype,              &
       atmos_phy_ae_offline_enable_periodic_year,  &
       atmos_phy_ae_offline_enable_periodic_month, &
       atmos_phy_ae_offline_enable_periodic_day,   &
       atmos_phy_ae_offline_step_fixed,            &
       atmos_phy_ae_offline_defval,                &
       atmos_phy_ae_offline_check_coordinates,     &
       atmos_phy_ae_offline_step_limit,            &
       atmos_phy_ae_offline_const_outqld01,        &
       atmos_phy_ae_offline_const_outqld02,        &
       atmos_phy_ae_offline_const_outqld03,        &
       atmos_phy_ae_offline_const_outqld04,        &
       atmos_phy_ae_offline_const_outqld05,        &
       atmos_phy_ae_offline_const_outqld06,        &
       atmos_phy_ae_offline_const_outqld07,        &
       atmos_phy_ae_offline_const_unccn
 
    integer :: n, ierr
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_PHY_AE_offline_setup",*) 'Setup'
    log_info("ATMOS_PHY_AE_offline_setup",*) 'Kajino(2013) scheme'
 
    atmos_phy_ae_offline_defval = undef
 
    atmos_phy_ae_offline_const_outqld01 = undef
    atmos_phy_ae_offline_const_outqld02 = undef
    atmos_phy_ae_offline_const_outqld03 = undef
    atmos_phy_ae_offline_const_outqld04 = undef
    atmos_phy_ae_offline_const_outqld05 = undef
    atmos_phy_ae_offline_const_outqld06 = undef
    atmos_phy_ae_offline_const_outqld07 = undef
    atmos_phy_ae_offline_const_unccn    = undef
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_ae_offline,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("ATMOS_PHY_AE_offline_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("ATMOS_PHY_AE_offline_setup",*) 'Not appropriate names in namelist PARAM_ATMOS_PHY_AE_offline. Check!'
       call prc_abort
    endif
    log_nml(param_atmos_phy_ae_offline)
 
    const_value(1) = atmos_phy_ae_offline_const_outqld01
    const_value(2) = atmos_phy_ae_offline_const_outqld02
    const_value(3) = atmos_phy_ae_offline_const_outqld03
    const_value(4) = atmos_phy_ae_offline_const_outqld04
    const_value(5) = atmos_phy_ae_offline_const_outqld05
    const_value(6) = atmos_phy_ae_offline_const_outqld06
    const_value(7) = atmos_phy_ae_offline_const_outqld07
    const_value(8) = atmos_phy_ae_offline_const_unccn
 
    do n = 1, num_vars_3d
 
       if ( const_value(n) < undef*0.1 ) then ! read from external file
 
          if ( atmos_phy_ae_offline_basename /= '' ) then
             call file_external_input_regist( atmos_phy_ae_offline_basename,              & ! [IN]
                                              atmos_phy_ae_offline_basename_add_num,      & ! [IN]
                                              atmos_phy_ae_offline_number_of_files,       & ! [IN]
                                              vars_3d(n),                                 & ! [IN]
                                              atmos_phy_ae_offline_axistype,              & ! [IN]
                                              atmos_phy_ae_offline_enable_periodic_year,  & ! [IN]
                                              atmos_phy_ae_offline_enable_periodic_month, & ! [IN]
                                              atmos_phy_ae_offline_enable_periodic_day,   & ! [IN]
                                              atmos_phy_ae_offline_step_fixed,            & ! [IN]
                                              atmos_phy_ae_offline_defval,                & ! [IN]
                                              check_coordinates = atmos_phy_ae_offline_check_coordinates, & ! [IN]
                                              step_limit        = atmos_phy_ae_offline_step_limit         ) ! [IN]
          endif
 
       else ! set constant value
 
          log_info("ATMOS_PHY_AE_offline_setup",*) &
            'Constant value is set for ', trim(vars_3d(n)), ', value = ', const_value(n)
 
       endif
 
    enddo
 
    return
  end subroutine atmos_phy_ae_offline_setup
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_offline_tendency( &
       KA, KS, KE, &
       IA, IS, IE, &
       JA, JS, JE, &
       time_now,   &
       CCN         )
    use scale_prc, only: &
       prc_abort
    use scale_file_external_input, only: &
       file_external_input_update
    use scale_const, only: &
       undef => const_undef
    implicit none
 
    integer,  intent(in)  :: ka, ks, ke
    integer,  intent(in)  :: ia, is, ie
    integer,  intent(in)  :: ja, js, je
    real(dp), intent(in)  :: time_now
    real(rp), intent(out) :: ccn(ka,ia,ja)
 
    logical  :: error
    integer  :: n
    !---------------------------------------------------------------------------
 
    log_progress(*) 'atmosphere / physics / aerosol / offline'
 
    n = 8 ! UNCCN
 
    if ( const_value(n) < undef*0.1 ) then ! read from external file
 
       call file_external_input_update( vars_3d(n), time_now, ccn(:,:,:), error )
       if ( error ) then
          log_error("ATMOS_PHY_AE_offline_flux",*) 'Requested data is not found! ', trim(vars_3d(n))
          call prc_abort
       endif
 
    else ! set constant value
 
       ccn(:,:,:) = const_value(n)
 
    endif
 
    return
  end subroutine atmos_phy_ae_offline_tendency
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_offline_effective_radius( &
       KA, IA, JA, &
       RH,         &
       Re          )
    implicit none
 
    integer,  intent(in)  :: ka, ia, ja
    real(rp), intent(in)  :: rh(ka,ia,ja)      ! relative humidity [%]
    real(rp), intent(out) :: re(ka,ia,ja,n_ae) ! effective radius
 
    real(rp), parameter :: ae_re(n_ae) = & ! aerosol radius [m]
         (/ 1.6e-6_rp, &  ! Soil dust
              -1.0_rp, &  ! Carbonacerous (BC/OC=0.3)
              -1.0_rp, &  ! Carbonacerous (BC/OC=0.15)
              -1.0_rp, &  ! Carbonacerous (BC/OC=0.)
             4.e-8_rp, &  ! Black carbon
              -1.0_rp, &  ! Sulfate
              -1.0_rp  /) ! Sea salt
 
    integer  :: iaero
    !---------------------------------------------------------------------------
 
    do iaero = 1, n_ae
 
       if ( ae_re(iaero) < 0.0_rp ) then ! hygroscopic particle : look-up table is based on the RH
 
          re(:,:,:,iaero) = rh(:,:,:) * 1.e-2_rp
 
       else                              ! non-hygroscopic particle : look-up table is the effective radius
 
          re(:,:,:,iaero) = ae_re(iaero) * 100.0_rp ! [m=>cm]
 
       endif
 
    enddo
 
    return
  end subroutine atmos_phy_ae_offline_effective_radius
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_offline_qtrc2qaero( &
       KA, IA, JA, &
       time_now,   &
       Qe          )
    use scale_prc, only: &
       prc_abort
    use scale_file_external_input, only: &
       file_external_input_update
    use scale_const, only: &
       undef => const_undef
    implicit none
 
    integer,  intent(in)  :: ka, ia, ja
    real(dp), intent(in)  :: time_now
    real(rp), intent(out) :: qe(ka,ia,ja,n_ae) ! aerosol mixing ratio [kg/kg]
 
    logical  :: error, error_sum
    integer  :: n, iaero
    !---------------------------------------------------------------------------
 
    error_sum = .false.
 
    do n = 1, num_vars_3d-1
       iaero = n
 
       if ( const_value(n) < undef*0.1 ) then ! read from external file
 
          call file_external_input_update( vars_3d(n), time_now, qe(:,:,:,iaero), error )
          error_sum = ( error .OR. error_sum )
 
       else ! set constant value
 
          qe(:,:,:,iaero) = const_value(n)
 
       endif
 
    enddo
 
    if ( error_sum ) then
       log_error("ATMOS_PHY_AE_offline_flux",*) 'Requested data is not found!'
       call prc_abort
    endif
 
    return
  end subroutine atmos_phy_ae_offline_qtrc2qaero
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ae_offline_mkinit( &
       KA, KS, KE, &
       IA, IS, IE, &
       JA, JS, JE, &
       ccn_init,   &
       CCN         )
    use scale_const, only: &
       undef => const_undef
    implicit none
 
    integer,  intent(in)  :: ka, ks, ke
    integer,  intent(in)  :: ia, is, ie
    integer,  intent(in)  :: ja, js, je
    real(rp), intent(in)  :: ccn_init
    real(rp), intent(out) :: ccn(ka,ia,ja)
 
    integer  :: n
    !---------------------------------------------------------------------------
 
    call atmos_phy_ae_offline_setup
 
    n = 8 ! UNCCN
 
    if ( const_value(n) < undef*0.1 ) then ! read from external file
 
       ccn(:,:,:) = ccn_init
 
    else ! set constant value
 
       ccn(:,:,:) = const_value(n)
 
    endif
 
    return
  end subroutine atmos_phy_ae_offline_mkinit
 
end module scale_atmos_phy_ae_offline