scale_atmos_phy_ch_rn222.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_atmos_phy_ch_rn222
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_ch_rn222_setup
  public :: atmos_phy_ch_rn222_tendency
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  integer, private, parameter :: QA_CH = 1
 
  integer,                public :: atmos_phy_ch_rn222_ntracers = qa_ch
 
  character(len=H_SHORT), public :: atmos_phy_ch_rn222_name(qa_ch) = (/ "RN222" /)
  character(len=H_MID)  , public :: atmos_phy_ch_rn222_desc(qa_ch) = (/ "Ratio of Rn222 to total mass" /)
  character(len=H_SHORT), public :: atmos_phy_ch_rn222_unit(qa_ch) = (/ "Bq/kg" /)
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,  private, parameter :: i_ch_rn222 = 1
 
  real(rp), private :: atmos_phy_ch_rn222_decay_ratio ! Decay constant [/s]
 
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ch_rn222_setup
    use scale_prc, only: &
       prc_abort
    implicit none
 
    real(rp) :: atmos_phy_ch_rn222_half_life = 3.30048e+5_rp
 
    namelist / param_atmos_phy_ch_rn222 / &
       atmos_phy_ch_rn222_half_life
 
    integer :: ierr
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_PHY_CH_rn222_setup",*) 'Setup'
    log_info("ATMOS_PHY_CH_rn222_setup",*) 'rn222 process'
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_ch_rn222,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("ATMOS_PHY_CH_rn222_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("ATMOS_PHY_CH_rn222_setup",*) 'Not appropriate names in namelist PARAM_ATMOS_PHY_CH_RN222. Check!'
       call prc_abort
    endif
    log_nml(param_atmos_phy_ch_rn222)
 
    atmos_phy_ch_rn222_decay_ratio = log(2.0_rp) / atmos_phy_ch_rn222_half_life
 
    log_newline
    log_info("ATMOS_PHY_CH_rn222_setup",*) 'Characteristics of Rn222'
    log_info_cont('(A,E16.6)')             'Half life   [s]   : ', atmos_phy_ch_rn222_half_life
    log_info_cont('(A,E16.6)')             'Decay ratio [1/s] : ', atmos_phy_ch_rn222_decay_ratio
 
    return
  end subroutine atmos_phy_ch_rn222_setup
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_ch_rn222_tendency( &
       KA, KS, KE, &
       IA, IS, IE, &
       JA, JS, JE, &
       QA_CH,      &
       DENS,       &
       QTRC,       &
       RHOQ_t      )
    implicit none
 
    integer,  intent(in)    :: ka, ks, ke
    integer,  intent(in)    :: ia, is, ie
    integer,  intent(in)    :: ja, js, je
    integer,  intent(in)    :: qa_ch
    real(rp), intent(in)    :: dens  (ka,ia,ja)
    real(rp), intent(in)    :: qtrc  (ka,ia,ja,qa_ch)
    real(rp), intent(inout) :: rhoq_t(ka,ia,ja,qa_ch)
 
    integer  :: k, i, j
    !---------------------------------------------------------------------------
 
    log_progress(*) 'atmosphere / physics / chemistry / Rn222'
 
    !--- Decay based on half life
    do j  = js, je
    do i  = is, ie
    do k  = ks, ke
       rhoq_t(k,i,j,i_ch_rn222) = rhoq_t(k,i,j,i_ch_rn222) &
                                - dens(k,i,j) * qtrc(k,i,j,1) * atmos_phy_ch_rn222_decay_ratio ! [Bq/m3/s]
    enddo
    enddo
    enddo
 
    return
  end subroutine atmos_phy_ch_rn222_tendency
 
end module scale_atmos_phy_ch_rn222