mod_atmos_phy_bl_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module mod_atmos_phy_bl_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_debug
  use scale_atmos_grid_cartesc_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_bl_vars_setup
  public :: atmos_phy_bl_vars_finalize
  public :: atmos_phy_bl_vars_fillhalo
  public :: atmos_phy_bl_vars_restart_read
  public :: atmos_phy_bl_vars_restart_write
 
  public :: atmos_phy_bl_vars_restart_create
  public :: atmos_phy_bl_vars_restart_open
  public :: atmos_phy_bl_vars_restart_def_var
  public :: atmos_phy_bl_vars_restart_enddef
  public :: atmos_phy_bl_vars_restart_close
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  integer,  public              :: qs, qe
 
  logical,               public :: atmos_phy_bl_restart_output                 = .false.                
 
  character(len=H_LONG),  public :: atmos_phy_bl_restart_in_basename           = ''
  logical,                public :: atmos_phy_bl_restart_in_aggregate
  logical,                public :: atmos_phy_bl_restart_in_postfix_timelabel  = .false.                
  character(len=H_LONG),  public :: atmos_phy_bl_restart_out_basename          = ''
  logical,                public :: atmos_phy_bl_restart_out_aggregate
  logical,                public :: atmos_phy_bl_restart_out_postfix_timelabel = .true.                 
  character(len=H_MID),   public :: atmos_phy_bl_restart_out_title             = 'ATMOS_PHY_BL restart'
  character(len=H_SHORT), public :: atmos_phy_bl_restart_out_dtype             = 'DEFAULT'
 
  logical,                public :: atmos_phy_bl_mix_tracers                   = .true.
 
  real(rp), public, allocatable :: atmos_phy_bl_rhou_t(:,:,:)   ! tendency RHOU [kg/m2/s2]
  real(rp), public, allocatable :: atmos_phy_bl_rhov_t(:,:,:)   ! tendency RHOV [kg/m2/s2]
  real(rp), public, allocatable :: atmos_phy_bl_rhot_t(:,:,:)   ! tendency RHOT [K*kg/m3/s]
 
  real(rp), public, allocatable, target :: atmos_phy_bl_rhoq_t(:,:,:,:) ! tendency rho*QTRC [kg/kg/s]
 
  real(rp), public, allocatable :: atmos_phy_bl_zi       (:,:)  ! depth of the PBL
  real(rp), public, allocatable :: atmos_phy_bl_sflx_buoy(:,:)  ! surface flux of buoyancy
 
  real(rp), public, allocatable :: atmos_phy_bl_ql    (:,:,:)   ! liquid water content in partial condensation
  real(rp), public, allocatable :: atmos_phy_bl_cldfrac(:,:,:)  ! cloud fraction in partial condensation
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,                private, parameter :: vmax = 1
  integer,                private, parameter :: i_zi = 1
 
  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)
  integer,                private            :: var_id(vmax)
  integer,                private            :: restart_fid = -1  ! file ID
 
  data var_name / 'PBL_Zi' /
 
  data var_desc / 'depth of the boundary layer' /
 
  data var_unit / 'm' /
 
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_vars_setup
    use scale_prc, only: &
       prc_abort
    use scale_const, only: &
       undef => const_undef
    implicit none
 
    namelist / param_atmos_phy_bl_vars / &
       atmos_phy_bl_restart_in_basename,           &
       atmos_phy_bl_restart_in_aggregate,          &
       atmos_phy_bl_restart_in_postfix_timelabel,  &
       atmos_phy_bl_restart_output,                &
       atmos_phy_bl_restart_out_basename,          &
       atmos_phy_bl_restart_out_aggregate,         &
       atmos_phy_bl_restart_out_postfix_timelabel, &
       atmos_phy_bl_restart_out_title,             &
       atmos_phy_bl_restart_out_dtype,             &
       atmos_phy_bl_mix_tracers
 
    integer :: ierr
    integer :: iv
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_PHY_BL_vars_setup",*) 'Setup'
 
    allocate( atmos_phy_bl_rhou_t(ka,ia,ja)    )
    allocate( atmos_phy_bl_rhov_t(ka,ia,ja)    )
    allocate( atmos_phy_bl_rhot_t(ka,ia,ja)    )
    allocate( atmos_phy_bl_rhoq_t(ka,ia,ja,qa) )
    atmos_phy_bl_rhou_t(:,:,:)   = undef
    atmos_phy_bl_rhov_t(:,:,:)   = undef
    atmos_phy_bl_rhot_t(:,:,:)   = undef
    atmos_phy_bl_rhoq_t(:,:,:,:) = undef
    !$acc enter data create(ATMOS_PHY_BL_RHOU_t,ATMOS_PHY_BL_RHOV_t,ATMOS_PHY_BL_RHOT_t,ATMOS_PHY_BL_RHOQ_t)
 
    allocate( atmos_phy_bl_zi(ia,ja) )
    atmos_phy_bl_zi(:,:) = undef
    !$acc enter data create(ATMOS_PHY_BL_Zi)
 
    allocate( atmos_phy_bl_sflx_buoy(ia,ja) )
    atmos_phy_bl_sflx_buoy(:,:) = undef
    !$acc enter data create(ATMOS_PHY_BL_SFLX_BUOY)
 
    allocate( atmos_phy_bl_ql(ka,ia,ja) )
    allocate( atmos_phy_bl_cldfrac(ka,ia,ja) )
    atmos_phy_bl_ql(:,:,:) = undef
    atmos_phy_bl_cldfrac(:,:,:) = undef
    !$acc enter data create(ATMOS_PHY_BL_QL,ATMOS_PHY_BL_cldfrac)
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_bl_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("ATMOS_PHY_BL_vars_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("ATMOS_PHY_BL_vars_setup",*) 'Not appropriate names in namelist PARAM_ATMOS_PHY_BL_VARS. Check!'
       call prc_abort
    endif
    log_nml(param_atmos_phy_bl_vars)
 
    log_newline
    log_info("ATMOS_PHY_BL_vars_setup",*) '[ATMOS_PHY_BL] prognostic/diagnostic variables'
    log_info_cont('(1x,A,A24,A,A48,A,A12,A)') &
               '      |', 'VARNAME                 ','|', &
               'DESCRIPTION                                     ', '[', 'UNIT        ', ']'
    do iv = 1, vmax
       log_info_cont('(1x,A,I3,A,A24,A,A48,A,A12,A)') &
                  'NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
    enddo
 
    log_newline
    if ( atmos_phy_bl_restart_in_basename /= '' ) then
       log_info("ATMOS_PHY_BL_vars_setup",*) 'Restart input?  : YES, file = ', trim(atmos_phy_bl_restart_in_basename)
       log_info("ATMOS_PHY_BL_vars_setup",*) 'Add timelabel?  : ', atmos_phy_bl_restart_in_postfix_timelabel
    else
       log_info("ATMOS_PHY_BL_vars_setup",*) 'Restart input?  : NO'
    endif
    if (       atmos_phy_bl_restart_output             &
         .AND. atmos_phy_bl_restart_out_basename /= '' ) then
       log_info("ATMOS_PHY_BL_vars_setup",*) 'Restart output? : YES, file = ', trim(atmos_phy_bl_restart_out_basename)
       log_info("ATMOS_PHY_BL_vars_setup",*) 'Add timelabel?  : ', atmos_phy_bl_restart_out_postfix_timelabel
    else
       log_info("ATMOS_PHY_BL_vars_setup",*) 'Restart output? : NO'
       atmos_phy_bl_restart_output = .false.
    endif
 
    return
  end subroutine atmos_phy_bl_vars_setup
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_vars_finalize
    implicit none
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_PHY_BL_vars_finalize",*) 'Finalize'
 
    !$acc exit data delete(ATMOS_PHY_BL_RHOU_t,ATMOS_PHY_BL_RHOV_t,ATMOS_PHY_BL_RHOT_t,ATMOS_PHY_BL_RHOQ_t)
    deallocate( atmos_phy_bl_rhou_t )
    deallocate( atmos_phy_bl_rhov_t )
    deallocate( atmos_phy_bl_rhot_t )
    deallocate( atmos_phy_bl_rhoq_t )
 
    !$acc exit data delete(ATMOS_PHY_BL_Zi)
    deallocate( atmos_phy_bl_zi )
 
    !$acc exit data delete(ATMOS_PHY_BL_SFLX_BUOY)
    deallocate( atmos_phy_bl_sflx_buoy )
 
    !$acc exit data delete(ATMOS_PHY_BL_QL,ATMOS_PHY_BL_cldfrac)
    deallocate( atmos_phy_bl_ql      )
    deallocate( atmos_phy_bl_cldfrac )
 
    return
  end subroutine atmos_phy_bl_vars_finalize
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_vars_fillhalo
    use scale_comm_cartesc, only: &
       comm_vars8, &
       comm_wait
    implicit none
    !---------------------------------------------------------------------------
 
    call comm_vars8( atmos_phy_bl_zi(:,:), 1 )
    call comm_wait ( atmos_phy_bl_zi(:,:), 1 )
 
    return
  end subroutine atmos_phy_bl_vars_fillhalo
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_vars_restart_open
    use scale_time, only: &
       time_gettimelabel
    use scale_file_cartesc, only: &
       file_cartesc_open
    implicit none
 
    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_PHY_BL_vars_restart_open",*) 'Open restart file (ATMOS_PHY_BL) '
 
    if ( atmos_phy_bl_restart_in_basename /= '' ) then
 
       if ( atmos_phy_bl_restart_in_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_bl_restart_in_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_bl_restart_in_basename)
       endif
 
       log_info("ATMOS_PHY_BL_vars_restart_open",*) 'basename: ', trim(basename)
 
       call file_cartesc_open( basename, restart_fid, aggregate=atmos_phy_bl_restart_in_aggregate )
    else
       log_info("ATMOS_PHY_BL_vars_restart_open",*) 'restart file for ATMOS_PHY_BL is not specified.'
    endif
 
    return
  end subroutine atmos_phy_bl_vars_restart_open
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_vars_restart_read
    use scale_file, only: &
       file_get_aggregate
    use scale_file_cartesc, only: &
       file_cartesc_read, &
       file_cartesc_flush
    implicit none
 
    integer  :: i, j
    !---------------------------------------------------------------------------
 
    if ( restart_fid /= -1 ) then
       log_newline
       log_info("ATMOS_PHY_BL_vars_restart_read",*) 'Read from restart file (ATMOS_PHY_BL) '
 
       call file_cartesc_read( restart_fid, var_name(1), 'XY', & ! [IN]
                               atmos_phy_bl_zi(:,:)            ) ! [OUT]
 
       if ( file_get_aggregate(restart_fid) ) then
          call file_cartesc_flush( restart_fid ) ! X/Y halos have been read from file
          !$acc update device(ATMOS_PHY_BL_Zi)
       else
          call atmos_phy_bl_vars_fillhalo
       end if
 
       call atmos_phy_bl_vars_check
 
    else
       log_info("ATMOS_PHY_BL_vars_restart_read",*) 'invalid restart file ID for ATMOS_PHY_BL.'
    endif
 
    return
  end subroutine atmos_phy_bl_vars_restart_read
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_vars_restart_create
    use scale_time, only: &
       time_gettimelabel
    use scale_file_cartesc, only: &
       file_cartesc_create
    implicit none
 
    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------
 
    if ( atmos_phy_bl_restart_out_basename /= '' ) then
 
       log_newline
       log_info("ATMOS_PHY_BL_vars_restart_create",*) 'Create restart file (ATMOS_PHY_AE) '
 
       if ( atmos_phy_bl_restart_out_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_bl_restart_out_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_bl_restart_out_basename)
       endif
 
       log_info("ATMOS_PHY_BL_vars_restart_create",*) 'basename: ', trim(basename)
 
    call file_cartesc_create( &
         basename, atmos_phy_bl_restart_out_title, atmos_phy_bl_restart_out_dtype, & ! [IN]
         restart_fid,                                                              & ! [OUT]
         aggregate=atmos_phy_bl_restart_out_aggregate                              ) ! [IN]
    endif
 
    return
  end subroutine atmos_phy_bl_vars_restart_create
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_vars_restart_enddef
    use scale_file_cartesc, only: &
       file_cartesc_enddef
    implicit none
 
    if ( restart_fid /= -1 ) then
       call file_cartesc_enddef( restart_fid ) ! [IN]
    endif
 
    return
  end subroutine atmos_phy_bl_vars_restart_enddef
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_vars_restart_close
    use scale_file_cartesc, only: &
       file_cartesc_close
    implicit none
    !---------------------------------------------------------------------------
 
    if ( restart_fid /= -1 ) then
       log_newline
       log_info("ATMOS_PHY_BL_vars_restart_close",*) 'Close restart file (ATMOS_PHY_BL) '
 
       call file_cartesc_close( restart_fid ) ! [IN]
 
       restart_fid = -1
    endif
 
    return
  end subroutine atmos_phy_bl_vars_restart_close
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_vars_restart_def_var
    use scale_file_cartesc, only: &
       file_cartesc_def_var
    implicit none
    integer :: iv
    !---------------------------------------------------------------------------
 
    if ( restart_fid /= -1 ) then
 
       do iv = 1, vmax
          call file_cartesc_def_var( restart_fid,        & ! [IN]
               var_name(iv), var_desc(iv), var_unit(iv), & ! [IN]
               'XY', atmos_phy_bl_restart_out_dtype,     & ! [IN]
               var_id(iv)                                ) ! [OUT]
       end do
 
    endif
 
    return
  end subroutine atmos_phy_bl_vars_restart_def_var
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_bl_vars_restart_write
    use scale_file_cartesc, only: &
       file_cartesc_write_var
    implicit none
 
    !---------------------------------------------------------------------------
 
    if ( restart_fid /= -1 ) then
 
       call atmos_phy_bl_vars_fillhalo
 
       call atmos_phy_bl_vars_check
 
       call file_cartesc_write_var( restart_fid, var_id(1), atmos_phy_bl_zi(:,:), &
                                    var_name(1), 'XY' ) ! [IN]
 
    endif
 
    return
  end subroutine atmos_phy_bl_vars_restart_write
 
  subroutine atmos_phy_bl_vars_check
    use scale_statistics, only: &
       statistics_total
    use scale_atmos_grid_cartesc_real, only: &
       atmos_grid_cartesc_real_area, &
       atmos_grid_cartesc_real_totarea
    implicit none
 
    call valcheck( ia, is, ie, ja, js, je, &
                   atmos_phy_bl_zi(:,:),          & ! (in)
                   0.0_rp, 1.0e5_rp, var_name(1), & ! (in)
                   __file__, __line__             ) ! (in)
 
    call statistics_total( ia, is, ie, ja, js, je, &
                           atmos_phy_bl_zi(:,:), var_name(1), &
                           atmos_grid_cartesc_real_area(:,:), & ! (in)
                           atmos_grid_cartesc_real_totarea    ) ! (in)
 
    return
  end subroutine atmos_phy_bl_vars_check
  
end module mod_atmos_phy_bl_vars