scale_coriolis.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_coriolis
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: coriolis_setup
  public :: coriolis_finalize
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  real(rp), public, allocatable :: coriolis_f(:,:)
 
 
  character(len=H_SHORT), public :: coriolis_type = 'PLANE'
  real(rp),               public :: coriolis_f0   = 0.0_rp
  real(rp),               public :: coriolis_beta = 0.0_rp
  real(rp),               public :: coriolis_y0
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine coriolis_setup( &
       IA, JA, &
       LAT,                &
       CY, DOMAIN_CENTER_Y )
    use scale_prc, only: &
       prc_abort
    use scale_const, only: &
       ohm => const_ohm
    implicit none
    integer, intent(in) :: ia, ja
 
    real(rp), intent(in) :: lat(ia,ja)
    real(rp), intent(in) :: cy (ja)
    real(rp), intent(in) :: domain_center_y
 
    namelist / param_coriolis / &
       coriolis_type, &
       coriolis_f0,   &
       coriolis_beta, &
       coriolis_y0
 
    integer :: i, j
 
    integer :: ierr
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("CORIOLIS_setup",*) 'Setup'
 
    coriolis_y0 = domain_center_y
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_coriolis,iostat=ierr)
 
    if( ierr < 0 ) then !--- missing
       log_info("CORIOLIS_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("CORIOLIS_setup",*) 'Not appropriate names in namelist PARAM_CORIOLIS. Check!'
       call prc_abort
    endif
    log_nml(param_coriolis)
 
 
    allocate( coriolis_f(ia,ja) )
 
    ! coriolis parameter
    select case ( coriolis_type )
    case ( 'PLANE' )
       !omp parallel do collapse(2)
       do j = 1, ja
       do i = 1, ia
          coriolis_f(i,j) = coriolis_f0 + coriolis_beta * ( cy(j) - coriolis_y0 )
       end do
       end do
    case ( 'SPHERE' )
       !omp parallel do collapse(2)
       do j = 1, ja
       do i = 1, ia
          coriolis_f(i,j) = 2.0_rp * ohm * sin( lat(i,j) )
       end do
       end do
    case default
       log_error("CORIOLIS_setup",*) 'Coriolis type is invalid: ', trim(coriolis_type)
       log_error_cont(*) 'The type must be PLANE or SPHERE'
       call prc_abort
    end select
 
    !$acc enter data copyin(CORIOLIS_f)
 
    return
  end subroutine coriolis_setup
 
  !-----------------------------------------------------------------------------
  subroutine coriolis_finalize
    implicit none
    !---------------------------------------------------------------------------
 
    !$acc exit data delete(CORIOLIS_f)
    deallocate( coriolis_f )
 
    return
  end subroutine coriolis_finalize
 
end module scale_coriolis