mod_atmos_dyn_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module mod_atmos_dyn_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_debug
  use scale_atmos_grid_cartesc_index
  use scale_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_dyn_vars_setup
  public :: atmos_dyn_vars_finalize
  public :: atmos_dyn_vars_fillhalo
  public :: atmos_dyn_vars_restart_read
  public :: atmos_dyn_vars_restart_write
 
  public :: atmos_dyn_vars_restart_create
  public :: atmos_dyn_vars_restart_open
  public :: atmos_dyn_vars_restart_def_var
  public :: atmos_dyn_vars_restart_enddef
  public :: atmos_dyn_vars_restart_close
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,               public :: atmos_dyn_restart_output                 = .false.             
 
  character(len=H_LONG),  public :: atmos_dyn_restart_in_basename           = ''
  logical,                public :: atmos_dyn_restart_in_aggregate
  logical,                public :: atmos_dyn_restart_in_postfix_timelabel  = .false.             
  character(len=H_LONG),  public :: atmos_dyn_restart_out_basename          = ''
  logical,                public :: atmos_dyn_restart_out_aggregate
  logical,                public :: atmos_dyn_restart_out_postfix_timelabel = .true.              
  character(len=H_MID),   public :: atmos_dyn_restart_out_title             = 'ATMOS_DYN restart'
  character(len=H_SHORT), public :: atmos_dyn_restart_out_dtype             = 'DEFAULT'
 
  ! prognostic variables
  real(rp), public, allocatable :: prog(:,:,:,:)
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer,                private, parameter :: vmax = 100
  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)
  integer,                private            :: var_id(vmax)
  integer,                private            :: restart_fid = -1  ! file ID
 
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_setup
    use scale_prc, only: &
       prc_abort
    use scale_const, only: &
       undef => const_undef
    use mod_atmos_admin, only: &
       atmos_dyn_type
    use scale_atmos_dyn_tstep_short, only: &
       atmos_dyn_tstep_short_regist
    implicit none
 
    namelist / param_atmos_dyn_vars / &
       atmos_dyn_restart_in_basename,           &
       atmos_dyn_restart_in_aggregate,          &
       atmos_dyn_restart_in_postfix_timelabel,  &
       atmos_dyn_restart_output,                &
       atmos_dyn_restart_out_basename,          &
       atmos_dyn_restart_out_aggregate,         &
       atmos_dyn_restart_out_postfix_timelabel, &
       atmos_dyn_restart_out_title,             &
       atmos_dyn_restart_out_dtype
 
    integer :: ierr
    integer :: iv
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_DYN_vars_setup",*) 'Setup'
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_dyn_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("ATMOS_DYN_vars_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("ATMOS_DYN_vars_setup",*) 'Not appropriate names in namelist PARAM_ATMOS_DYN_VARS. Check!'
       call prc_abort
    endif
    log_nml(param_atmos_dyn_vars)
 
    call atmos_dyn_tstep_short_regist( atmos_dyn_type, & ! [IN]
                                       va,             & ! [OUT]
                                       var_name,       & ! [OUT]
                                       var_desc,       & ! [OUT]
                                       var_unit        ) ! [OUT]
 
    if ( va > 0 ) then ! additional prognostic variables
 
       if ( va > vmax ) then
          log_error("ATMOS_DYN_vars_setup",*) 'number of the prognostic variables is exceed the limit', va, ' > ', vmax
          call prc_abort
       endif
       allocate( prog(ka,ia,ja,va) )
       prog(:,:,:,:) = undef
 
       log_newline
       log_info("ATMOS_DYN_vars_setup",*) '[ATMOS_DYN] prognostic/diagnostic variables'
       log_info_cont('(1x,A,A24,A,A48,A,A12,A)') &
                  '      |', 'VARNAME                 ','|', &
                  'DESCRIPTION                                     ', '[', 'UNIT        ', ']'
       do iv = 1, va
          log_info_cont('(1x,A,I3,A,A24,A,A48,A,A12,A)') &
                     'NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
       enddo
 
       log_newline
       if ( atmos_dyn_restart_in_basename /= '' ) then
          log_info("ATMOS_DYN_vars_setup",*) 'Restart input?  : YES, file = ', trim(atmos_dyn_restart_in_basename)
          log_info("ATMOS_DYN_vars_setup",*) 'Add timelabel?  : ', atmos_dyn_restart_in_postfix_timelabel
       else
          log_info("ATMOS_DYN_vars_setup",*) 'Restart input?  : NO'
       endif
       if (       atmos_dyn_restart_output             &
            .AND. atmos_dyn_restart_out_basename /= '' ) then
          log_info("ATMOS_DYN_vars_setup",*) 'Restart output? : YES, file = ', trim(atmos_dyn_restart_out_basename)
          log_info("ATMOS_DYN_vars_setup",*) 'Add timelabel?  : ', atmos_dyn_restart_out_postfix_timelabel
       else
          log_info("ATMOS_DYN_vars_setup",*) 'Restart output? : NO'
          atmos_dyn_restart_output = .false.
       endif
 
    else ! no additional prognostic variables
 
       allocate( prog(ka,ia,ja,1) ) ! for safety
       prog(:,:,:,:) = undef
       atmos_dyn_restart_output = .false.
 
    endif
 
    !$acc enter data create(PROG)
 
    return
  end subroutine atmos_dyn_vars_setup
 
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_finalize
    implicit none
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_DYN_vars_finalize",*) 'Finalize'
 
    if ( allocated( prog ) ) then
       !$acc exit data delete(PROG)
       deallocate( prog )
    end if
 
    return
  end subroutine atmos_dyn_vars_finalize
 
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_fillhalo
    use scale_comm_cartesc, only: &
       comm_vars8, &
       comm_wait
    implicit none
 
    integer :: i, j, iv
    !---------------------------------------------------------------------------
 
    do iv = 1, va
       !acc kernels
       do j  = js, je
       do i  = is, ie
          prog(   1:ks-1,i,j,iv) = prog(ks,i,j,iv)
          prog(ke+1:ka,  i,j,iv) = prog(ke,i,j,iv)
       enddo
       enddo
       !acc end kernels
 
       call comm_vars8( prog(:,:,:,iv), iv )
    enddo
 
    do iv = 1, va
       call comm_wait ( prog(:,:,:,iv), iv )
    enddo
 
    return
  end subroutine atmos_dyn_vars_fillhalo
 
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_restart_open
    use scale_time, only: &
       time_gettimelabel
    use scale_file_cartesc, only: &
       file_cartesc_open
    implicit none
 
    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------
 
    if ( va < 1 ) return
 
    log_newline
    log_info("ATMOS_DYN_vars_restart_open",*) 'Open restart file (ATMOS_DYN) '
 
    if ( atmos_dyn_restart_in_basename /= '' ) then
 
       if ( atmos_dyn_restart_in_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_dyn_restart_in_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_dyn_restart_in_basename)
       endif
 
       log_info("ATMOS_DYN_vars_restart_open",*) 'basename: ', trim(basename)
 
       call file_cartesc_open( basename, restart_fid, aggregate=atmos_dyn_restart_in_aggregate )
    else
       log_info("ATMOS_DYN_vars_restart_open",*) 'restart file for ATMOS_DYN is not specified.'
    endif
 
    return
  end subroutine atmos_dyn_vars_restart_open
 
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_restart_read
    use scale_prc, only: &
       prc_abort
    use scale_file, only: &
       file_get_aggregate
    use scale_file_cartesc, only: &
       file_cartesc_read, &
       file_cartesc_flush
    implicit none
 
    integer  :: i, j, iv
    !---------------------------------------------------------------------------
 
    if ( restart_fid /= -1 ) then
       log_newline
       log_info("ATMOS_DYN_vars_restart_read",*) 'Read from restart file (ATMOS_DYN) '
 
       do iv = 1, va
          call file_cartesc_read( restart_fid, var_name(iv), 'ZXY', & ! [IN]
                                  prog(:,:,:,iv)                    ) ! [OUT]
       enddo
 
       if ( file_get_aggregate(restart_fid) ) then
          call file_cartesc_flush( restart_fid )
          !$acc update device(PROG)
          ! X/Y halos have been read from file
 
          ! fill K halos
          !acc kernels copy(PROG)
          do iv = 1, va
             do j  = 1, ja
             do i  = 1, ia
                prog(   1:ks-1,i,j,iv) = prog(ks,i,j,iv)
                prog(ke+1:ka,  i,j,iv) = prog(ke,i,j,iv)
             enddo
             enddo
          enddo
          !acc end kernels
       else
          call atmos_dyn_vars_fillhalo
       end if
 
       call atmos_dyn_vars_check
 
    else
       if ( va > 0 ) then
          log_error("ATMOS_DYN_vars_restart_read",*) 'invalid restart file ID for ATMOS_DYN.'
          call prc_abort
       end if
    endif
 
    return
  end subroutine atmos_dyn_vars_restart_read
 
  subroutine atmos_dyn_vars_restart_create
    use scale_time, only: &
       time_gettimelabel
    use scale_file_cartesc, only: &
       file_cartesc_create
    implicit none
 
    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------
 
    if ( va < 1 ) return
 
    if ( atmos_dyn_restart_out_basename /= '' ) then
 
       log_newline
       log_info("ATMOS_DYN_vars_restart_create",*) 'Create restart file (ATMOS_DYN) '
 
       if ( atmos_dyn_restart_out_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_dyn_restart_out_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_dyn_restart_out_basename)
       endif
 
       log_info("ATMOS_DYN_vars_restart_create",*) 'basename: ', trim(basename)
 
       call file_cartesc_create( &
            basename, atmos_dyn_restart_out_title, atmos_dyn_restart_out_dtype, & ! [IN]
            restart_fid,                                                        & ! [OUT]
            aggregate=atmos_dyn_restart_out_aggregate                           ) ! [IN]
 
    endif
 
    return
  end subroutine atmos_dyn_vars_restart_create
 
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_restart_enddef
    use scale_file_cartesc, only: &
       file_cartesc_enddef
    implicit none
 
    if ( restart_fid /= -1 .and. va > 0 ) then
       call file_cartesc_enddef( restart_fid ) ! [IN]
    endif
 
    return
  end subroutine atmos_dyn_vars_restart_enddef
 
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_restart_close
    use scale_file_cartesc, only: &
       file_cartesc_close
    implicit none
    !---------------------------------------------------------------------------
 
    if ( restart_fid /= -1 ) then
       log_newline
       log_info("ATMOS_DYN_vars_restart_close",*) 'Close restart file (ATMOS_DYN) '
 
       call file_cartesc_close( restart_fid ) ! [IN]
 
       restart_fid = -1
    endif
 
    return
  end subroutine atmos_dyn_vars_restart_close
 
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_restart_def_var
    use scale_file_cartesc, only: &
       file_cartesc_def_var
    implicit none
 
    integer iv
    !---------------------------------------------------------------------------
 
    if ( restart_fid /= -1 ) then
 
       do iv = 1, va
          call file_cartesc_def_var( restart_fid, var_name(iv), var_desc(iv), var_unit(iv), 'ZXY', atmos_dyn_restart_out_dtype, &
                                     var_id(iv) )
       enddo
 
    endif
 
    return
  end subroutine atmos_dyn_vars_restart_def_var
 
  !-----------------------------------------------------------------------------
  subroutine atmos_dyn_vars_restart_write
    use scale_file_cartesc, only: &
       file_cartesc_write_var
    implicit none
 
    integer  :: iv
    !---------------------------------------------------------------------------
 
    if ( restart_fid /= -1 ) then
 
       call atmos_dyn_vars_fillhalo
 
       call atmos_dyn_vars_check
 
       !$acc update host(PROG)
       do iv = 1, va
          call file_cartesc_write_var( restart_fid, var_id(iv), prog(:,:,:,iv), var_name(iv), 'ZXY' ) ! [IN]
       enddo
 
    endif
 
    return
  end subroutine atmos_dyn_vars_restart_write
 
  subroutine atmos_dyn_vars_check
    use scale_statistics, only: &
       statistics_total
    use scale_atmos_grid_cartesc_real, only: &
       atmos_grid_cartesc_real_vol, &
       atmos_grid_cartesc_real_totvol
    implicit none
    integer :: iv
 
    do iv = 1, va
       call valcheck( ka, ks, ke, ia, is, ie, ja, js, je, &
                      prog(:,:,:,iv),                      & ! (in)
                      -1.0e20_rp, 1.0e20_rp, var_name(iv), & ! (in)
                      __file__, __line__                   ) ! (in)
       call statistics_total( ka, ks, ke, ia, is, ie, ja, js, je, &
                              prog(:,:,:,iv), var_name(iv),       & ! (in)
                              atmos_grid_cartesc_real_vol(:,:,:), & ! (in)
                              atmos_grid_cartesc_real_totvol      ) ! (in)
    enddo
 
    return
  end subroutine atmos_dyn_vars_check
 
end module mod_atmos_dyn_vars