scale_ocean_phy_tc.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_ocean_phy_tc
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: ocean_phy_tc_seaice_setup
  public :: ocean_phy_tc_seaice
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  real(rp), public :: ocean_phy_thermalcond_max    =   10.0_rp ! maximum thermal conductivity / depth [J/m2/s/K]
  real(rp), public :: ocean_phy_thermalcond_seaice =    2.0_rp ! thermal conductivity of sea ice      [J/m/s/K]
 
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine ocean_phy_tc_seaice_setup
    use scale_prc, only: &
       prc_abort
    implicit none
 
    namelist / param_ocean_phy_tc_seaice / &
       ocean_phy_thermalcond_max,   &
       ocean_phy_thermalcond_seaice
 
    integer :: ierr
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("OCEAN_PHY_TC_seaice_setup",*) 'Setup'
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_ocean_phy_tc_seaice,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("OCEAN_PHY_TC_seaice_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("OCEAN_PHY_TC_seaice_setup",*) 'Not appropriate names in namelist PARAM_OCEAN_PHY_TC_seaice. Check!'
       call prc_abort
    endif
    log_nml(param_ocean_phy_tc_seaice)
 
    return
  end subroutine ocean_phy_tc_seaice_setup
 
  !-----------------------------------------------------------------------------
  subroutine ocean_phy_tc_seaice( &
       OIA, OIS, OIE, &
       OJA, OJS, OJE, &
       ICE_MASS,      &
       ICE_FRAC,      &
       mask,          &
       TC_dz          )
    use scale_const, only: &
       eps => const_eps
    use scale_ocean_phy_ice_simple, only: &
       ocean_phy_ice_density
    implicit none
 
    integer,  intent(in)  :: oia, ois, oie
    integer,  intent(in)  :: oja, ojs, oje
    real(rp), intent(in)  :: ice_mass(oia,oja) ! sea ice amount               [kg/m2]
    real(rp), intent(in)  :: ice_frac(oia,oja) ! sea ice area fraction        [1]
    logical,  intent(in)  :: mask    (oia,oja)
    real(rp), intent(out) :: tc_dz   (oia,oja) ! thermal conductivity / depth [J/m2/s/K]
 
    real(rp) :: ice_depth
    integer  :: i, j
    !---------------------------------------------------------------------------
    !$acc data copyin(ICE_MASS,ICE_FRAC,mask) copyout(TC_dz)
 
    !$acc kernels
    !$omp parallel do private(ice_depth)
    do j = ojs, oje
    do i = ois, oie
       if ( mask(i,j) ) then
          ice_depth  = ice_mass(i,j) / ocean_phy_ice_density / max(ice_frac(i,j),eps)
 
          tc_dz(i,j) = ocean_phy_thermalcond_seaice / max(ice_depth*0.5_rp,eps) ! at the middle point of the layer
 
          tc_dz(i,j) = min( tc_dz(i,j), ocean_phy_thermalcond_max )
       end if
    enddo
    enddo
    !$acc end kernels
 
    !$acc end data
    return
  end subroutine ocean_phy_tc_seaice
 
end module scale_ocean_phy_tc