mod_atmos_phy_rd_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module mod_atmos_phy_rd_vars
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_debug
  use scale_atmos_grid_cartesc_index
  use scale_tracer
  use scale_cpl_sfc_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_rd_vars_setup
  public :: atmos_phy_rd_vars_finalize
  public :: atmos_phy_rd_vars_fillhalo
  public :: atmos_phy_rd_vars_restart_read
  public :: atmos_phy_rd_vars_restart_write
 
  public :: atmos_phy_rd_vars_restart_create
  public :: atmos_phy_rd_vars_restart_open
  public :: atmos_phy_rd_vars_restart_def_var
  public :: atmos_phy_rd_vars_restart_enddef
  public :: atmos_phy_rd_vars_restart_close
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  logical,               public :: atmos_phy_rd_restart_output                 = .false.                
 
  character(len=H_LONG),  public :: atmos_phy_rd_restart_in_basename           = ''
  logical,                public :: atmos_phy_rd_restart_in_aggregate
  logical,                public :: atmos_phy_rd_restart_in_postfix_timelabel  = .false.                
  character(len=H_LONG),  public :: atmos_phy_rd_restart_out_basename          = ''
  logical,                public :: atmos_phy_rd_restart_out_aggregate
  logical,                public :: atmos_phy_rd_restart_out_postfix_timelabel = .true.                 
  character(len=H_MID),   public :: atmos_phy_rd_restart_out_title             = 'ATMOS_PHY_RD restart'
  character(len=H_SHORT), public :: atmos_phy_rd_restart_out_dtype             = 'DEFAULT'
 
  real(rp), public, allocatable :: atmos_phy_rd_rhoh(:,:,:)   ! diavatic heating rate [J/m3/s]
 
  ! surface
  real(rp), public, allocatable :: atmos_phy_rd_sflx_lw_up  (:,:) ! upward   longwave  flux [J/m2/s]
  real(rp), public, allocatable :: atmos_phy_rd_sflx_lw_dn  (:,:) ! downward longwave  flux [J/m2/s]
  real(rp), public, allocatable :: atmos_phy_rd_sflx_sw_up  (:,:) ! upward   shortwave flux [J/m2/s]
  real(rp), public, allocatable :: atmos_phy_rd_sflx_sw_dn  (:,:) ! downward shortwave flux [J/m2/s]
 
  ! TOM (top of the model)
  real(rp), public, allocatable :: atmos_phy_rd_tomflx_lw_up(:,:) ! upward   longwave  flux [J/m2/s]
  real(rp), public, allocatable :: atmos_phy_rd_tomflx_lw_dn(:,:) ! downward longwave  flux [J/m2/s]
  real(rp), public, allocatable :: atmos_phy_rd_tomflx_sw_up(:,:) ! upward   shortwave flux [J/m2/s]
  real(rp), public, allocatable :: atmos_phy_rd_tomflx_sw_dn(:,:) ! downward shortwave flux [J/m2/s]
 
  real(rp), public, allocatable :: atmos_phy_rd_sflx_down   (:,:,:,:) ! surface downward flux (LW/SW,direct/diffuse) [J/m2/s]
 
  real(rp), public, allocatable :: atmos_phy_rd_solins      (:,:) ! solar insolation flux   [J/m2/s]
  real(rp), public, allocatable :: atmos_phy_rd_cossza      (:,:) ! cos(solar zenith angle) (0-1)
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
 
  ! restart variables
  integer,                private, parameter :: vmax              =  4
  integer,                private, parameter :: i_sflx_lw_up      =  1
  integer,                private, parameter :: i_sflx_lw_dn      =  2
  integer,                private, parameter :: i_sflx_sw_up      =  3
  integer,                private, parameter :: i_sflx_sw_dn      =  4
 
  character(len=H_SHORT), private            :: var_name(vmax)
  character(len=H_MID),   private            :: var_desc(vmax)
  character(len=H_MID),   private            :: var_stdn(vmax)
  character(len=H_SHORT), private            :: var_unit(vmax)
  integer,                private            :: var_id(vmax)
  integer,                private            :: restart_fid = -1  ! file ID
 
  data var_name / 'SFLX_LW_up', &
                  'SFLX_LW_dn', &
                  'SFLX_SW_up', &
                  'SFLX_SW_dn'  /
  data var_desc / 'surface upward   longwave  flux', &
                  'surface downward longwave  flux', &
                  'surface upward   shortwave flux', &
                  'surface downward shortwave flux'  /
  data var_stdn / 'surface_upwelling_longwave_flux_in_air',   &
                  'surface_downwelling_longwave_flux_in_air', &
                  'surface_upwelling_shortwave_flux_in_air',  &
                  'surface_downwelling_shortwave_flux_in_air' /
  data var_unit / 'W/m2', &
                  'W/m2', &
                  'W/m2', &
                  'W/m2'  /
 
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_rd_vars_setup
    use scale_prc, only: &
       prc_abort
    use scale_const, only: &
       undef => const_undef
    implicit none
 
    namelist / param_atmos_phy_rd_vars / &
       atmos_phy_rd_restart_in_basename,           &
       atmos_phy_rd_restart_in_aggregate,          &
       atmos_phy_rd_restart_in_postfix_timelabel,  &
       atmos_phy_rd_restart_output,                &
       atmos_phy_rd_restart_out_basename,          &
       atmos_phy_rd_restart_out_aggregate,         &
       atmos_phy_rd_restart_out_postfix_timelabel, &
       atmos_phy_rd_restart_out_title,             &
       atmos_phy_rd_restart_out_dtype
 
    integer :: ierr
    integer :: iv
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_PHY_RD_vars_setup",*) 'Setup'
 
    allocate( atmos_phy_rd_rhoh(ka,ia,ja) )
    atmos_phy_rd_rhoh(:,:,:) = undef
    !$acc enter data create(ATMOS_PHY_RD_RHOH)
 
    allocate( atmos_phy_rd_sflx_lw_up(ia,ja) )
    allocate( atmos_phy_rd_sflx_lw_dn(ia,ja) )
    allocate( atmos_phy_rd_sflx_sw_up(ia,ja) )
    allocate( atmos_phy_rd_sflx_sw_dn(ia,ja) )
    atmos_phy_rd_sflx_lw_up(:,:) = undef
    atmos_phy_rd_sflx_lw_dn(:,:) = undef
    atmos_phy_rd_sflx_sw_up(:,:) = undef
    atmos_phy_rd_sflx_sw_dn(:,:) = undef
    !$acc enter data create(ATMOS_PHY_RD_SFLX_LW_up,ATMOS_PHY_RD_SFLX_LW_dn,ATMOS_PHY_RD_SFLX_SW_up,ATMOS_PHY_RD_SFLX_SW_dn)
 
    allocate( atmos_phy_rd_tomflx_lw_up(ia,ja) )
    allocate( atmos_phy_rd_tomflx_lw_dn(ia,ja) )
    allocate( atmos_phy_rd_tomflx_sw_up(ia,ja) )
    allocate( atmos_phy_rd_tomflx_sw_dn(ia,ja) )
    atmos_phy_rd_tomflx_lw_up(:,:) = undef
    atmos_phy_rd_tomflx_lw_dn(:,:) = undef
    atmos_phy_rd_tomflx_sw_up(:,:) = undef
    atmos_phy_rd_tomflx_sw_dn(:,:) = undef
    !$acc enter data create(ATMOS_PHY_RD_TOMFLX_LW_up,ATMOS_PHY_RD_TOMFLX_LW_dn,ATMOS_PHY_RD_TOMFLX_SW_up,ATMOS_PHY_RD_TOMFLX_SW_dn)
 
    allocate( atmos_phy_rd_sflx_down(ia,ja,n_rad_dir,n_rad_rgn) )
    atmos_phy_rd_sflx_down(:,:,:,:) = undef
    !$acc enter data create(ATMOS_PHY_RD_SFLX_down)
 
    allocate( atmos_phy_rd_solins(ia,ja) )
    allocate( atmos_phy_rd_cossza(ia,ja) )
    atmos_phy_rd_solins(:,:) = undef
    atmos_phy_rd_cossza(:,:) = undef
    !$acc enter data create(ATMOS_PHY_RD_solins,ATMOS_PHY_RD_cosSZA)
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_rd_vars,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("ATMOS_PHY_RD_vars_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("ATMOS_PHY_RD_vars_setup",*) 'Not appropriate names in namelist PARAM_ATMOS_PHY_RD_VARS. Check!'
       call prc_abort
    endif
    log_nml(param_atmos_phy_rd_vars)
 
    log_newline
    log_info("ATMOS_PHY_RD_vars_setup",*) '[ATMOS_PHY_RD] prognostic/diagnostic variables'
    log_info_cont('(1x,A,A24,A,A48,A,A12,A)') &
               '      |', 'VARNAME                 ','|', &
               'DESCRIPTION                                     ', '[', 'UNIT        ', ']'
    do iv = 1, vmax
       log_info_cont('(1x,A,I3,A,A24,A,A48,A,A12,A)') &
                  'NO.',iv,'|',var_name(iv),'|',var_desc(iv),'[',var_unit(iv),']'
    enddo
 
    log_newline
    if ( atmos_phy_rd_restart_in_basename /= '' ) then
       log_info("ATMOS_PHY_RD_vars_setup",*) 'Restart input?  : YES, file = ', trim(atmos_phy_rd_restart_in_basename)
       log_info("ATMOS_PHY_RD_vars_setup",*) 'Add timelabel?  : ', atmos_phy_rd_restart_in_postfix_timelabel
    else
       log_info("ATMOS_PHY_RD_vars_setup",*) 'Restart input?  : NO'
    endif
    if (       atmos_phy_rd_restart_output             &
         .AND. atmos_phy_rd_restart_out_basename /= '' ) then
       log_info("ATMOS_PHY_RD_vars_setup",*) 'Restart output? : YES, file = ', trim(atmos_phy_rd_restart_out_basename)
       log_info("ATMOS_PHY_RD_vars_setup",*) 'Add timelabel?  : ', atmos_phy_rd_restart_out_postfix_timelabel
    else
       log_info("ATMOS_PHY_RD_vars_setup",*) 'Restart output? : NO'
       atmos_phy_rd_restart_output = .false.
    endif
 
    return
  end subroutine atmos_phy_rd_vars_setup
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_rd_vars_finalize
    implicit none
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_PHY_RD_vars_finalize",*) 'Finalize'
 
    !$acc exit data delete(ATMOS_PHY_RD_RHOH)
    deallocate( atmos_phy_rd_rhoh )
 
    !$acc exit data delete(ATMOS_PHY_RD_SFLX_LW_up,ATMOS_PHY_RD_SFLX_LW_dn,ATMOS_PHY_RD_SFLX_SW_up,ATMOS_PHY_RD_SFLX_SW_dn)
    deallocate( atmos_phy_rd_sflx_lw_up )
    deallocate( atmos_phy_rd_sflx_lw_dn )
    deallocate( atmos_phy_rd_sflx_sw_up )
    deallocate( atmos_phy_rd_sflx_sw_dn )
 
    !$acc exit data delete(ATMOS_PHY_RD_TOMFLX_LW_up,ATMOS_PHY_RD_TOMFLX_LW_dn,ATMOS_PHY_RD_TOMFLX_SW_up,ATMOS_PHY_RD_TOMFLX_SW_dn)
    deallocate( atmos_phy_rd_tomflx_lw_up )
    deallocate( atmos_phy_rd_tomflx_lw_dn )
    deallocate( atmos_phy_rd_tomflx_sw_up )
    deallocate( atmos_phy_rd_tomflx_sw_dn )
 
    !$acc exit data delete(ATMOS_PHY_RD_SFLX_down)
    deallocate( atmos_phy_rd_sflx_down )
 
    !$acc exit data delete(ATMOS_PHY_RD_solins,ATMOS_PHY_RD_cosSZA)
    deallocate( atmos_phy_rd_solins )
    deallocate( atmos_phy_rd_cossza )
 
    return
  end subroutine atmos_phy_rd_vars_finalize
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_rd_vars_fillhalo
    use scale_comm_cartesc, only: &
       comm_vars8, &
       comm_wait
    implicit none
 
    integer :: n ,idir, irgn
    !---------------------------------------------------------------------------
 
    call comm_vars8( atmos_phy_rd_sflx_lw_up(:,:),  1 )
    call comm_vars8( atmos_phy_rd_sflx_lw_dn(:,:),  2 )
    call comm_vars8( atmos_phy_rd_sflx_sw_up(:,:),  3 )
    call comm_vars8( atmos_phy_rd_sflx_sw_dn(:,:),  4 )
    call comm_vars8( atmos_phy_rd_tomflx_lw_up(:,:),  5 )
    call comm_vars8( atmos_phy_rd_tomflx_lw_dn(:,:),  6 )
    call comm_vars8( atmos_phy_rd_tomflx_sw_up(:,:),  7 )
    call comm_vars8( atmos_phy_rd_tomflx_sw_dn(:,:),  8 )
 
    n = 8
    do irgn = i_r_ir, i_r_vis
    do idir = i_r_direct, i_r_diffuse
       n = n + 1
       call comm_vars8( atmos_phy_rd_sflx_down(:,:,idir,irgn), n )
    enddo
    enddo
 
    call comm_wait ( atmos_phy_rd_sflx_lw_up(:,:),  1 )
    call comm_wait ( atmos_phy_rd_sflx_lw_dn(:,:),  2 )
    call comm_wait ( atmos_phy_rd_sflx_sw_up(:,:),  3 )
    call comm_wait ( atmos_phy_rd_sflx_sw_dn(:,:),  4 )
    call comm_wait ( atmos_phy_rd_tomflx_lw_up(:,:),  5 )
    call comm_wait ( atmos_phy_rd_tomflx_lw_dn(:,:),  6 )
    call comm_wait ( atmos_phy_rd_tomflx_sw_up(:,:),  7 )
    call comm_wait ( atmos_phy_rd_tomflx_sw_dn(:,:),  8 )
 
    n = 8
    do irgn = i_r_ir, i_r_vis
    do idir = i_r_direct, i_r_diffuse
       n = n + 1
       call comm_wait ( atmos_phy_rd_sflx_down(:,:,idir,irgn), n )
    enddo
    enddo
 
    return
  end subroutine atmos_phy_rd_vars_fillhalo
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_rd_vars_restart_open
    use scale_time, only: &
       time_gettimelabel
    use scale_file_cartesc, only: &
       file_cartesc_open
    implicit none
 
    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_PHY_RD_vars_restart_open",*) 'Open restart file (ATMOS_PHY_RD) '
 
    if ( atmos_phy_rd_restart_in_basename /= '' ) then
 
       if ( atmos_phy_rd_restart_in_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_rd_restart_in_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_rd_restart_in_basename)
       endif
 
       log_info("ATMOS_PHY_RD_vars_restart_open",*) 'basename: ', trim(basename)
 
       call file_cartesc_open( basename, restart_fid, aggregate=atmos_phy_rd_restart_in_aggregate )
    else
       log_info("ATMOS_PHY_RD_vars_restart_open",*) 'restart file for ATMOS_PHY_RD is not specified.'
    endif
 
    return
  end subroutine atmos_phy_rd_vars_restart_open
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_rd_vars_restart_read
    use scale_file, only: &
       file_get_aggregate
    use scale_file_cartesc, only: &
       file_cartesc_read, &
       file_cartesc_flush
    implicit none
    !---------------------------------------------------------------------------
 
    if ( restart_fid /= -1 ) then
       log_newline
       log_info("ATMOS_PHY_RD_vars_restart_read",*) 'Read from restart file (ATMOS_PHY_RD) '
 
       call file_cartesc_read( restart_fid, var_name(i_sflx_lw_up),      'XY', & ! [IN]
                               atmos_phy_rd_sflx_lw_up(:,:)                    ) ! [OUT]
       call file_cartesc_read( restart_fid, var_name(i_sflx_lw_dn),      'XY', & ! [IN]
                               atmos_phy_rd_sflx_lw_dn(:,:)                    ) ! [OUT]
       call file_cartesc_read( restart_fid, var_name(i_sflx_sw_up),      'XY', & ! [IN]
                               atmos_phy_rd_sflx_sw_up(:,:)                    ) ! [OUT]
       call file_cartesc_read( restart_fid, var_name(i_sflx_sw_dn),      'XY', & ! [IN]
                               atmos_phy_rd_sflx_sw_dn(:,:)                    ) ! [OUT]
 
       if ( file_get_aggregate(restart_fid) ) then
          call file_cartesc_flush( restart_fid ) ! X/Y halos have been read from file
          !$acc update device(ATMOS_PHY_RD_SFLX_LW_up,ATMOS_PHY_RD_SFLX_LW_dn,ATMOS_PHY_RD_SFLX_SW_up,ATMOS_PHY_RD_SFLX_SW_dn)
       else
          call atmos_phy_rd_vars_fillhalo
       end if
 
       call atmos_phy_rd_vars_check
 
    else
       log_info("ATMOS_PHY_RD_vars_restart_read",*) 'invalid restart file ID for ATMOS_PHY_RD.'
    endif
 
    return
  end subroutine atmos_phy_rd_vars_restart_read
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_rd_vars_restart_create
    use scale_time, only: &
       time_gettimelabel
    use scale_file_cartesc, only: &
       file_cartesc_create
    implicit none
 
    character(len=19)     :: timelabel
    character(len=H_LONG) :: basename
    !---------------------------------------------------------------------------
 
    if ( atmos_phy_rd_restart_out_basename /= '' ) then
 
       log_newline
       log_info("ATMOS_PHY_RD_vars_restart_create",*) 'Create restart file (ATMOS_PHY_AE) '
 
       if ( atmos_phy_rd_restart_out_postfix_timelabel ) then
          call time_gettimelabel( timelabel )
          basename = trim(atmos_phy_rd_restart_out_basename)//'_'//trim(timelabel)
       else
          basename = trim(atmos_phy_rd_restart_out_basename)
       endif
 
       log_info("ATMOS_PHY_RD_vars_restart_create",*) 'basename: ', trim(basename)
 
       call file_cartesc_create( &
            basename, atmos_phy_rd_restart_out_title, atmos_phy_rd_restart_out_dtype, & ! [IN]
            restart_fid,                                                              & ! [OUT]
            aggregate=atmos_phy_rd_restart_out_aggregate                              ) ! [IN]
 
    endif
 
    return
  end subroutine atmos_phy_rd_vars_restart_create
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_rd_vars_restart_enddef
    use scale_file_cartesc, only: &
       file_cartesc_enddef
    implicit none
 
    if ( restart_fid /= -1 ) then
       call file_cartesc_enddef( restart_fid ) ! [IN]
    endif
 
    return
  end subroutine atmos_phy_rd_vars_restart_enddef
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_rd_vars_restart_close
    use scale_file_cartesc, only: &
       file_cartesc_close
    implicit none
    !---------------------------------------------------------------------------
 
    if ( restart_fid /= -1 ) then
       log_newline
       log_info("ATMOS_PHY_RD_vars_restart_close",*) 'Close restart file (ATMOS_PHY_RD) '
 
       call file_cartesc_close( restart_fid ) ! [IN]
 
       restart_fid = -1
    endif
 
    return
  end subroutine atmos_phy_rd_vars_restart_close
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_rd_vars_restart_def_var
    use scale_file_cartesc, only: &
       file_cartesc_def_var
    implicit none
 
    integer :: i
    !---------------------------------------------------------------------------
 
    if ( restart_fid /= -1 ) then
 
       do i = 1, vmax
          call file_cartesc_def_var( restart_fid,                           & ! [IN]
                                     var_name(i), var_desc(i), var_unit(i), & ! [IN]
                                     'XY', atmos_phy_rd_restart_out_dtype,  & ! [IN]
                                     var_id(i),                             & ! [OUT]
                                     standard_name=var_stdn(i)              ) ! [IN]
       end do
    endif
 
    return
  end subroutine atmos_phy_rd_vars_restart_def_var
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_rd_vars_restart_write
    use scale_file_cartesc, only: &
       file_cartesc_write_var
    implicit none
    !---------------------------------------------------------------------------
 
    if ( restart_fid /= -1 ) then
 
       call atmos_phy_rd_vars_fillhalo
 
       call atmos_phy_rd_vars_check
 
       call file_cartesc_write_var( restart_fid, var_id(i_sflx_lw_up),               & ! [IN]
                                    atmos_phy_rd_sflx_lw_up(:,:),                    & ! [IN]
                                    var_name(i_sflx_lw_up),      'XY'                ) ! [IN]
       call file_cartesc_write_var( restart_fid, var_id(i_sflx_lw_dn),               & ! [IN]
                                    atmos_phy_rd_sflx_lw_dn(:,:),                    & ! [IN]
                                    var_name(i_sflx_lw_dn),      'XY'                ) ! [IN]
       call file_cartesc_write_var( restart_fid, var_id(i_sflx_sw_up),               & ! [IN]
                                    atmos_phy_rd_sflx_sw_up(:,:),                    & ! [IN]
                                    var_name(i_sflx_sw_up),      'XY'                ) ! [IN]
       call file_cartesc_write_var( restart_fid, var_id(i_sflx_sw_dn),               & ! [IN]
                                    atmos_phy_rd_sflx_sw_dn(:,:),                    & ! [IN]
                                    var_name(i_sflx_sw_dn),      'XY'                ) ! [IN]
 
    endif
 
    return
  end subroutine atmos_phy_rd_vars_restart_write
 
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_rd_vars_check
    use scale_statistics, only: &
       statistics_total
    use scale_atmos_grid_cartesc_real, only: &
       atmos_grid_cartesc_real_area,   &
       atmos_grid_cartesc_real_totarea
    implicit none
    !---------------------------------------------------------------------------
 
    call valcheck( ia, is, ie, ja, js, je, &
                   atmos_phy_rd_sflx_lw_up(:,:),             & ! (in)
                   0.0_rp, 1.0e4_rp, var_name(i_sflx_lw_up), & ! (in)
                   __file__, __line__                        ) ! (in)
    call valcheck( ia, is, ie, ja, js, je, &
                   atmos_phy_rd_sflx_lw_dn(:,:),             & ! (in)
                   0.0_rp, 1.0e4_rp, var_name(i_sflx_lw_dn), & ! (in)
                   __file__, __line__                        ) ! (in)
    call valcheck( ia, is, ie, ja, js, je, &
                   atmos_phy_rd_sflx_sw_up(:,:),             & ! (in)
                   0.0_rp, 1.0e4_rp, var_name(i_sflx_sw_up), & ! (in)
                   __file__, __line__                        ) ! (in)
    call valcheck( ia, is, ie, ja, js, je, &
                   atmos_phy_rd_sflx_sw_dn(:,:),             & ! (in)
                   0.0_rp, 1.0e4_rp, var_name(i_sflx_sw_dn), & ! (in)
                   __file__, __line__                        ) ! (in)
 
    call statistics_total( ia, is, ie, ja, js, je,                          & ! [IN]
                           atmos_phy_rd_sflx_lw_up(:,:),                    & ! [IN]
                           var_name(i_sflx_lw_up),                          & ! [IN]
                           atmos_grid_cartesc_real_area(:,:),               & ! [IN]
                           atmos_grid_cartesc_real_totarea                  ) ! [IN]
    call statistics_total( ia, is, ie, ja, js, je,                          & ! [IN]
                           atmos_phy_rd_sflx_lw_dn(:,:),                    & ! [IN]
                           var_name(i_sflx_lw_dn),                          & ! [IN]
                           atmos_grid_cartesc_real_area(:,:),               & ! [IN]
                           atmos_grid_cartesc_real_totarea                  ) ! [IN]
    call statistics_total( ia, is, ie, ja, js, je,                          & ! [IN]
                           atmos_phy_rd_sflx_sw_up(:,:),                    & ! [IN]
                           var_name(i_sflx_sw_up),                          & ! [IN]
                           atmos_grid_cartesc_real_area(:,:),               & ! [IN]
                           atmos_grid_cartesc_real_totarea                  ) ! [IN]
    call statistics_total( ia, is, ie, ja, js, je,                          & ! [IN]
                           atmos_phy_rd_sflx_sw_dn(:,:),                    & ! [IN]
                           var_name(i_sflx_sw_dn),                          & ! [IN]
                           atmos_grid_cartesc_real_area(:,:),               & ! [IN]
                           atmos_grid_cartesc_real_totarea                  ) ! [IN]
 
    return
  end subroutine atmos_phy_rd_vars_check
 
end module mod_atmos_phy_rd_vars