scale_land_grid_cartesC.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_land_grid_cartesc
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_atmos_grid_cartesc_index
  use scale_land_grid_cartesc_index
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: land_grid_cartesc_setup
  public :: land_grid_cartesc_finalize
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  real(rp), public, allocatable :: land_grid_cartesc_cz (:)
  real(rp), public, allocatable :: land_grid_cartesc_fz (:)
  real(rp), public, allocatable :: land_grid_cartesc_cdz(:)
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  private :: land_grid_cartesc_read
  private :: land_grid_cartesc_generate
 
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  real(rp), private :: ldz(100)
 
  character(len=H_LONG) :: land_grid_cartesc_in_basename  = ''
  logical               :: land_grid_cartesc_in_aggregate
 
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine land_grid_cartesc_setup
    use scale_prc, only: &
       prc_abort
    use scale_file, only: &
       file_aggregate
    implicit none
 
    namelist / param_land_grid_cartesc / &
       land_grid_cartesc_in_basename,  &
       land_grid_cartesc_in_aggregate, &
       ldz
 
    integer :: ierr
    integer :: k
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("LAND_GRID_CARTESC_setup",*) 'Setup'
 
    if ( lkmax < 1 ) then
       log_info("LAND_GRID_CARTESC_setup",*) 'Skip because LKMAX < 1'
       return
    end if
 
    ldz(:) = 0.0_rp
 
    land_grid_cartesc_in_aggregate = file_aggregate
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_land_grid_cartesc,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("LAND_GRID_CARTESC_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("LAND_GRID_CARTESC_setup",*) 'Not appropriate names in namelist PARAM_LAND_GRID_CARTESC. Check!'
       call prc_abort
    endif
    log_nml(param_land_grid_cartesc)
 
    allocate( land_grid_cartesc_cz(lks  :lke) )
    allocate( land_grid_cartesc_fz(lks-1:lke) )
    allocate( land_grid_cartesc_cdz(lks  :lke) )
    !$acc enter data create(LAND_GRID_CARTESC_CZ, LAND_GRID_CARTESC_FZ, LAND_GRID_CARTESC_CDZ) async
 
    log_newline
    log_info("LAND_GRID_CARTESC_setup",*) 'Land grid information '
 
    if ( land_grid_cartesc_in_basename /= '' ) then
       call land_grid_cartesc_read
    else
       log_info("LAND_GRID_CARTESC_setup",*) 'Not found input grid file. Grid position is calculated.'
 
       call land_grid_cartesc_generate
    endif
 
    if ( lke == lks ) then
       log_newline
       log_info("LAND_GRID_CARTESC_setup",*) 'Single layer. LDZ = ', ldz(1)
    else
       log_newline
       log_info_cont('(1x,A)') 'Vertical Coordinate'
       log_info_cont('(1x,A)')                  '|   k       z      zh      dz   k |'
       log_info_cont('(1x,A)')                  '|         [m]     [m]     [m]     |'
       k = lks-1
       log_info_cont('(1x,A,F8.3,A,I4,A)')      '|            ',land_grid_cartesc_fz(k),'        ',k,' | Atmosphere interface'
       do k = lks, lke-1
       log_info_cont('(1x,A,I4,F8.3,A,F8.3,A)') '|',k,land_grid_cartesc_cz(k),'        ',land_grid_cartesc_cdz(k),'     | '
       log_info_cont('(1x,A,F8.3,A,I4,A)')      '|            ',land_grid_cartesc_fz(k),'       |',k,' | '
       enddo
       k = lke
       log_info_cont('(1x,A,I4,F8.3,A,F8.3,A)') '|',k,land_grid_cartesc_cz(k),'        ',land_grid_cartesc_cdz(k),'     | '
       log_info_cont('(1x,A,F8.3,A,I4,A)')      '|            ',land_grid_cartesc_fz(k),'        ',k,' | bedrock'
       log_info_cont('(1x,A)')                  '|=================================|'
    endif
 
    !$acc wait
 
    return
  end subroutine land_grid_cartesc_setup
 
  !-----------------------------------------------------------------------------
  subroutine land_grid_cartesc_finalize
    implicit none
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("LAND_GRID_CARTESC_finalize",*) 'Finalize'
 
    !$acc exit data delete(LAND_GRID_CARTESC_CZ, LAND_GRID_CARTESC_FZ, LAND_GRID_CARTESC_CDZ)
    deallocate( land_grid_cartesc_cz  )
    deallocate( land_grid_cartesc_fz  )
    deallocate( land_grid_cartesc_cdz )
 
    return
  end subroutine land_grid_cartesc_finalize
 
  !-----------------------------------------------------------------------------
  subroutine land_grid_cartesc_read
    use scale_file, only: &
       file_open, &
       file_read
    use scale_prc, only: &
       prc_myrank
    implicit none
 
    integer :: fid
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("LAND_GRID_CARTESC_read",*) 'Input land grid file '
 
    call file_open( land_grid_cartesc_in_basename, fid, rankid=prc_myrank, aggregate=land_grid_cartesc_in_aggregate )
 
    call file_read( fid, 'LCZ',  land_grid_cartesc_cz(:) )
    call file_read( fid, 'LCDZ', land_grid_cartesc_cdz(:) )
    call file_read( fid, 'LFZ',  land_grid_cartesc_fz(:) )
    !$acc update device(LAND_GRID_CARTESC_CZ, LAND_GRID_CARTESC_CDZ, LAND_GRID_CARTESC_FZ)
 
    return
  end subroutine land_grid_cartesc_read
 
  !-----------------------------------------------------------------------------
  subroutine land_grid_cartesc_generate
    implicit none
 
    integer :: k
    !---------------------------------------------------------------------------
 
    do k = lks, lke
       land_grid_cartesc_cdz(k) = ldz(k)
    enddo
    !$acc update device(LAND_GRID_CARTESC_CDZ) async
 
    land_grid_cartesc_fz(lks-1) = 0.0_rp
 
    do k = lks, lke
       land_grid_cartesc_cz(k) = land_grid_cartesc_cdz(k) / 2.0_rp + land_grid_cartesc_fz(k-1)
       land_grid_cartesc_fz(k) = land_grid_cartesc_cdz(k)          + land_grid_cartesc_fz(k-1)
    enddo
    !$acc update device(LAND_GRID_CARTESC_CZ, LAND_GRID_CARTESC_FZ) async
    
    !$acc wait
 
    return
  end subroutine land_grid_cartesc_generate
 
end module scale_land_grid_cartesc