scale_atmos_grid_icoA_index.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_atmos_grid_icoa_index
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_grid_icoa_index_setup
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
 
  ! Identifier of triangle element (i-axis-side or j-axis side)
  integer, public, parameter :: adm_ti = 1
  integer, public, parameter :: adm_tj = 2
 
  ! Identifier of arc element (i-axis-side, ij-axis side, or j-axis side)
  integer, public, parameter :: adm_ai  = 1
  integer, public, parameter :: adm_aij = 2
  integer, public, parameter :: adm_aj  = 3
 
  ! Identifier of 1 variable
  integer, public, parameter :: adm_knone = 1
 
  ! dimension of the spacial vector
  integer, public, parameter :: adm_nxyz = 3
 
  ! number of HALOs
  integer, public, parameter :: khalo  = 1
  integer, public            :: ihalo  = 1
  integer, public            :: jhalo  = 1
 
  ! main parameter
  integer, public            :: adm_glevel           ! grid   division level
  integer, public            :: adm_vlayer           ! number of vertical layer
 
  ! region
  integer, public            :: adm_lall             ! number of regular region per process
  integer, public, parameter :: adm_lall_pl     =  2 ! number of pole    region per process
 
  ! horizontal grid
  integer, public            :: adm_gall             ! number of horizontal grid per regular region
  integer, public            :: adm_gall_in          ! number of horizontal grid (inner part)
  integer, public            :: adm_gall_1d          ! number of horizontal grid (1D)
  integer, public            :: adm_gmin             ! start index of 1D horizontal grid
  integer, public            :: adm_gmax             ! end   index of 1D horizontal grid
 
  integer, public            :: adm_iall             ! number of horizontal grid per regular region (i-axis)
  integer, public            :: adm_imin             ! start index of 1D horizontal grid
  integer, public            :: adm_imax             ! end   index of 1D horizontal grid
  integer, public            :: adm_jall             ! number of horizontal grid per regular region (j-axis)
  integer, public            :: adm_jmin             ! start index of 1D horizontal grid
  integer, public            :: adm_jmax             ! end   index of 1D horizontal grid
 
  integer, public            :: adm_vlink       = -1 ! maximum number of vertex linkage, ICO:5, PSP:6, LCP, MLCP:k
  integer, public            :: adm_gall_pl          ! number of horizontal grid for pole region
  integer, public, parameter :: adm_gslf_pl     =  1 ! index for pole point
  integer, public, parameter :: adm_gmin_pl     =  2 ! start index of grid around the pole point
  integer, public            :: adm_gmax_pl          ! end   index of grid around the pole point
 
  ! vertical grid
  integer, public            :: adm_kall             ! number of vertical grid
  integer, public            :: adm_kmin             ! start index of vertical grid
  integer, public            :: adm_kmax             ! end   index of vertical grid
 
  ! for physics grid
  integer, public             :: ks
  integer, public             :: ke
  integer, public             :: ka
  integer, public             :: imax = -1
  integer, public, parameter  :: is = 1
  integer, public             :: ie
  integer, public             :: ia
  integer, public             :: jmax = -1
  integer, public, parameter  :: js = 1
  integer, public             :: je
  integer, public             :: ja
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_grid_icoa_index_setup
    use scale_prc, only: &
       prc_abort
    use scale_prc_icoa, only: &
       prc_rgn_level, &
       prc_rgn_total, &
       prc_rgn_local, &
       prc_rgn_vlink
    implicit none
 
    integer :: grid_level = -1
    integer :: kmax       = -1
 
    namelist / param_atmos_grid_icoa_index / &
       grid_level, &
       kmax
 
    integer :: nmax
 
    integer :: ierr
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("ATMOS_GRID_ICOA_INDEX_setup",*) 'Setup'
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_grid_icoa_index,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("ATMOS_GRID_ICOA_INDEX_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("ATMOS_GRID_ICOA_INDEX_setup",*) 'Not appropriate names in namelist PARAM_ATMOS_GRID_ICOA_INDEX. Check!'
       call prc_abort
    endif
    log_nml(param_atmos_grid_icoa_index)
 
    ! Error if glevel & rlevel are not defined
    if ( grid_level < 1 ) then
       log_error("ATMOS_GRID_ICOA_INDEX_setup",*) 'GRID_LEVEL must be >= 1! ', grid_level
       call prc_abort
    endif
 
    if ( kmax < 1 ) then
       log_error("ATMOS_GRID_ICOA_INDEX_setup",*) 'KMAX must be >= 1! ', kmax
       call prc_abort
    end if
 
    adm_glevel  = grid_level
    adm_vlayer  = kmax
 
    adm_lall    = prc_rgn_local
 
    nmax        = 2**(grid_level-prc_rgn_level)
    adm_gall_1d = 1 + nmax + 1
    adm_gmin    = 1 + 1
    adm_gmax    = 1 + nmax
 
    adm_gall    = ( 1+nmax+1 ) * ( 1+nmax+1 )
    adm_gall_in = (   nmax+1 ) * (   nmax+1 )
 
    adm_imin    = 1 + 1
    adm_imax    = 1 + nmax
    adm_iall    = 1 + nmax + 1
    adm_jmin    = 1 + 1
    adm_jmax    = 1 + nmax
    adm_jall    = 1 + nmax + 1
 
    adm_vlink   = prc_rgn_vlink
    adm_gall_pl = prc_rgn_vlink + 1
    adm_gmax_pl = prc_rgn_vlink + 1
 
    if ( adm_vlayer == 1 ) then
       adm_kall = 1
       adm_kmin = 1
       adm_kmax = 1
    else
       adm_kall = 1 + kmax + 1
       adm_kmin = 1 + 1
       adm_kmax = 1 + kmax
    endif
 
    ! for physics grid
    ks = adm_kmin
    ke = adm_kmax
    ka = adm_kall
 
    imax = nmax
    ! IS = 1
    ie = nmax + 1
    ia = ie
 
    jmax = nmax
    ! JS = 1
    je = nmax + 1
    ja = je
 
    log_newline
    log_info("ATMOS_GRID_ICOA_INDEX_setup",'(1x,A)') 'Grid management information'
    log_info_cont('(1x,A,I4)' )                      'Grid divisiona level (GL)         : ', grid_level
    log_info_cont('(1x,A,I7,2(A,I4),A,I7,A)')        'Total number of grid (horizontal) : ',      &
                                                     4**(grid_level-prc_rgn_level)*prc_rgn_total, &
                                                     ' (', 2**(grid_level-prc_rgn_level),         &
                                                     ' x', 2**(grid_level-prc_rgn_level),         &
                                                     ' x', prc_rgn_total, ' ) + 2 (pole)'
    log_info_cont('(1x,A,I7)')                       'Number of vertical layer          : ', adm_kmax-adm_kmin+1
 
    return
  end subroutine atmos_grid_icoa_index_setup
 
 
end module scale_atmos_grid_icoa_index